Wolfram 语言与系统参考资料中心

ArcCos

参见
- Cos
- ArcSin
- ArcCosDegrees
- ArcCosh
- Degree
- VectorAngle
- TrigToExp
- TrigExpand
相关指南
技术笔记
- 一些数学函数
- 初等超越函数

ArcCos

ArcCos[z]

给出复数的反余弦 .

背景

ArcCos 是反余弦函数. 对实数，ArcCos[x] 表示满足的弧度值且 .
ArcCos 自动逐项作用于列表. 对某些特定变量值，ArcCos 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcCos 可以算出任意精度的数值结果. 对包含 ArcCos 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcCos 的定义为 . ArcCos[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Cos、ArcSin 和 ArcCosh.

范例

打开所有单元关闭所有单元

基本范例 (6)

结果以弧度表示：

Wolfram Language code: ArcCos[0]

除以 Degree 已得到以度为单位的结果：

Wolfram Language code: ArcCos[0] / Degree//FullSimplify

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCos[x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCos[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

在 0 处的级数展开：

Wolfram Language code: Series[ArcCos[x], {x, 0, 10}]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcCos[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCos[x], {x, 1, 3}, Assumptions -> x > 1]//Simplify

范围 (41)

数值计算 (6)

数值计算：

Wolfram Language code: ArcCos[0.4]

Wolfram Language code: ArcCos[1.5]

高精度求值：

Wolfram Language code: N[ArcCos[1 / 3], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCos[0.33333333333333333333333333333333333333333]

对复变量进行计算：

Wolfram Language code: ArcCos[2.5 + I]

在高精度条件下高效计算 ArcCos：

Wolfram Language code: ArcCos[0.4`500]//Timing

Wolfram Language code: ArcCos[0.4`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCos[Interval[{1 / 3, 1 / 2}]]

Wolfram Language code: ArcCos[CenteredInterval[1 / 2, 1 / 100]]

Wolfram Language code: ArcCos[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCos[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCos[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcCos 函数：

Wolfram Language code: MatrixFunction[ArcCos[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

特殊值 (4)

ArcCos 在固定点上的值：

Wolfram Language code: Table[ArcCos[(n /2)], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcCos[Infinity]

Wolfram Language code: ArcCos[ComplexInfinity]

ArcCos 的零点：

Wolfram Language code: ArcCos[1]

求满足方程的的值：

Wolfram Language code: f[x_] := ArcCos[x] - (π/3);

Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (3)

绘制 ArcCos 函数：

Wolfram Language code: Plot[ArcCos[x], {x, -1, 1}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCos[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCos[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcCos[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, Exclusions -> None, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

函数的属性 (10)

ArcCos 的定义域是区间内的所有实数：

Wolfram Language code: FunctionDomain[ArcCos[x], x]

复定义域是整个平面：

Wolfram Language code: FunctionDomain[ArcCos[z], z, Complexes]

ArcCos 的值域是内的所有实数：

Wolfram Language code: FunctionRange[ArcCos[x], x, y]

参数取复定义域内的值时的值域：

Wolfram Language code: FunctionRange[ArcCos[z], z, y, Complexes]

ArcCos 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCos[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCos[x], x]

ArcCos 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ArcCos[x], x]

在实定义域上是单调的：

Wolfram Language code: FunctionMonotonicity[{ArcCos[x], -1 ≤ x ≤ 1}, x]

ArcCos 是单射函数：

Wolfram Language code: FunctionInjective[ArcCos[x], x]

Wolfram Language code: Plot[{ArcCos[x], 1 / 2}, {x, -2π, 2π}]

ArcCos 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCos[x], x]

Wolfram Language code: Plot[{ArcCos[x], 3.5}, {x, -2π, 2π}]

ArcCos 在实定义域上是非负的：

Wolfram Language code: FunctionSign[{ArcCos[x], -1 ≤ x ≤ 1}, x]

ArcCos 在 (-∞,-1] 和 [1,∞) 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCos[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcCos[x], x]

ArcCos 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcCos[x], x]

TraditionalForm 格式：

Wolfram Language code: ArcCos[x]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcCos[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCos[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCos[x], {x, n}]

积分 (3)

ArcCos 的不定积分：

Wolfram Language code: Integrate[ArcCos[x], x]

ArcCos 在整个实数域上的定积分：

Wolfram Language code: Integrate[ArcCos[x], {x, -1, 1}]

更多积分：

Wolfram Language code: Integrate[ArcCos[x] ArcSin[x], x]

Wolfram Language code: Integrate[ArcCos[z]^a, z]

级数展开式 (4)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCos[x], {x, 0, 7}]

绘制 ArcCos 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcCos[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcCos[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcCos 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcCos[x], {x, 0, n}]

求分支点和分支切割的级数展开式：

Wolfram Language code: Series[ArcCos[x], {x, 1, 1}]

Wolfram Language code: Series[ArcCos[x], {x, -2, 1}]

ArcCos 可被应用于幂级数：

Wolfram Language code: ArcCos[x + (x^2/2) + (x^3/3) + O[x]^4]

函数恒等式和化简 (3)

化简含有 ArcCos 的表达式：

Wolfram Language code: FullSimplify[ArcCos[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

用 TrigToExp 通过对数和平方根来表示：

Wolfram Language code: TrigToExp@ArcCos[z]

Wolfram Language code: ExpToTrig[%]//FullSimplify

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcCos[x + I y]]

函数表示 (5)

使用 ArcSec 表示：

Wolfram Language code: ArcSec[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCN[z, 0]

Wolfram Language code: InverseJacobiDC[(1/z), 0]//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: z Hypergeometric2F1[1 / 2, 1 / 2, 3 / 2, z ^ 2]

用 MeijerG 表示：

Wolfram Language code: (π/2) - x / 2 / Sqrt[π]MeijerG[{{(1/2), (1/2)}, {}}, {{0}, {-(1/2)}}, -x^2]//FullSimplify

可用 DifferentialRoot 来表示 ArcCos：

Wolfram Language code: DifferentialRootReduce[ArcCos[x], x]

应用 (5)

绘制 ArcCos 的实部和虚部：

Wolfram Language code: Plot[{Re[ArcCos[x]], Im[ArcCos[x]]}, {x, -2, 2}, PlotStyle -> Thick]

绘出 ArcCos 的黎曼面：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Cos[u + I v]], Im[Cos[u + I v]], u}], {u, 0, 4π}, {v, -2, 2}]

求出两个向量的夹角：

Wolfram Language code: ArcCos[Normalize[{1, 1}].Normalize[{-1, 1}]]

Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {-1, 1}}]}, PlotRange -> All]

求解微分方程：

Wolfram Language code: DSolve[(b + a x) y[x] + (-1 + 2 x) Derivative[1][y][x] + 2 (-1 + x) x Derivative[2][y][x] == 0, y[x], x]

植物叶序模式的三维版本：

Wolfram Language code:

Graphics3D[Sphere[Table[FromSphericalCoordinates[N@{1, ArcCos[1 - i / 1000], Mod[i GoldenAngle, 2Pi, -Pi]}], {i, 1, 1000}], .04]]

属性和关系 (9)

与反函数合成：

Wolfram Language code: {Cos[ArcCos[z]], ArcCos[Cos[z]]}

利用 PowerExpand 去掉 ArcCos 的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假定条件下进行计算：

Wolfram Language code: Refine[ArcCos[Cos[z]], 0 < z < Pi / 2]

利用 TrigToExp 通过对数和平方根来表示 ArcCos：

Wolfram Language code: ArcCos[z]//TrigToExp

这里给出了 ArcCos 函数的分支线：

Wolfram Language code: Plot3D[Im[ArcCos[x - I y]], {x, -2, 2}, {y, -2, 2}]

ArcCos 给出以弧度为单位的角，ArcSecDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcCos[1 / 2]

Wolfram Language code: ArcCosDegrees[1 / 2]

假设实变量展开：

Wolfram Language code: ComplexExpand[ArcCos[x + I y]]

求解一个反三角函数方程：

Wolfram Language code: Reduce[ArcCos[z]^3 + 3 ArcCos[z] == 2, z]

Wolfram Language code: Reduce[ArcCos[Cos[z]] == w, z]

求解零：

Wolfram Language code: Reduce[ArcCos[α x + β] == 0, x]

拉普拉斯变换：

Wolfram Language code: LaplaceTransform[ArcCos[t], t, s]

ArcCos 自动作为各种数学函数的特例返回：

Wolfram Language code: InverseJacobiCD[z, 0]

可能存在的问题 (4)

一般地，：

Wolfram Language code: ArcCos[Cos[30.]]

Wolfram Language code: Cos[ArcCos[30.]]

在分支线上，机器精度输入可能给出错误数值答案：

Wolfram Language code: ArcCos[-2 + I((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N

Wolfram Language code: ArcCos[-2 + I((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 20]&

输出精度可能大大低于输入精度：

Wolfram Language code: ArcCos[0.99999999999999999999999999999999999991]

在传统格式中，自变量周围需圆括号：

Wolfram Language code: cos^-1x

Wolfram Language code: cos^-1(x)

巧妙范例 (2)

嵌套积分：

Wolfram Language code: NestList[Integrate[#, x]&, ArcCos[x], 4]

下面显示 ArcCos 幂函数的分支切割：

Wolfram Language code: Plot3D[Im[ArcCos[(x + I y) ^ 3]], {x, -2, 2}, {y, -2, 2}, ...]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcCos

更多信息

背景

范例

基本范例 (6)

范围 (41)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数的属性 (10)

微分 (3)

积分 (3)

级数展开式 (4)

函数恒等式和化简 (3)

函数表示 (5)

应用 (5)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (2)

文本

CMS

APA

BibTeX

BibLaTeX

ArcCos

更多信息

背景

范例

基本范例 (6)

范围 (41)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数的属性 (10)

微分 (3)

积分 (3)

级数展开式 (4)

函数恒等式和化简 (3)

函数表示 (5)

应用 (5)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX