WOLFRAM

Wolfram 语言与系统参考资料中心

ArcCsc[z]

给出复数 的反余割 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcCsc

ArcCsc[z]

给出复数 的反余割 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 所有结果以弧度给出.
  • 对于处在 到 区间之外的实数 z，其结果总在 到 的范围之内，0 除外.
  • 对于某些特殊参数，ArcCsc 自动计算出精确值.
  • ArcCsc 可以计算到任意数值精度.
  • ArcCsc 自动逐项作用于列表的各个元素.
  • ArcCsc[z] 在复平面 上有一个分支切割，从 到 .
  • ArcCsc 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (5)

结果以弧度表示：

Wolfram Language code: ArcCsc[1]

除以 Degree 已得到以度为单位的结果：

Wolfram Language code: ArcCsc[1] / Degree//FullSimplify

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCsc[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCsc[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcCsc[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCsc[x], {x, 1, 3}, Assumptions -> x > 1]//FullSimplify

范围  (41)

数值计算  (6)

数值计算：

Wolfram Language code: ArcCsc[5.0]

高精度求值：

Wolfram Language code: N[ArcCsc[5], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCsc[5.00000000000000000000000000000000000000000]

计算复变量：

Wolfram Language code: ArcCsc[0.5 + 2.3I]

在高精度条件下高效计算 ArcCsc：

Wolfram Language code: ArcCsc[5`500]//Timing
Wolfram Language code: ArcCsc[5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCsc[Interval[{1, 5}]]
Wolfram Language code: ArcCsc[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcCsc[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCsc[Around[(2/Sqrt[3]), 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCsc[{{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcCsc 函数：

Wolfram Language code: MatrixFunction[ArcCsc[#]&, {{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

特殊值  (4)

ArcCsc 在固定点上的值：

Wolfram Language code: {ArcCsc[-Sqrt[2]], ArcCsc[-(2/Sqrt[3])], ArcCsc[(2/Sqrt[3])], ArcCsc[Sqrt[2]]}

无穷处的值：

Wolfram Language code: ArcCsc[Infinity]
Wolfram Language code: ArcCsc[ComplexInfinity]

ArcCsc 的奇点：

Wolfram Language code: ArcCsc[{1, -1, 0}]

ArcCsc 在这些点上不可微分：

Wolfram Language code: ArcCsc'[{1, -1, 0}]//Quiet

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcCsc[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 1, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ArcCsc 函数：

Wolfram Language code: Plot[ArcCsc[x], {x, -2, 2}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCsc[z]], {z, -2π - 2π I, 2π + 2π I}, IconizedObject[«PlotOptions»]]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCsc[z]], {z, -2π - 2π I, 2π + 2π I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcCsc[k ϕ], {ϕ, -4π, 4π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {{-1, 1}, {-1, 1}}]], {k, 1, 4}]

函数属性  (11)

ArcCsc 是针对除区间 外的所有实数定义的：

Wolfram Language code: FunctionDomain[ArcCsc[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcCsc[z], z, Complexes]

ArcCsc 获得区间 上除0以外的所有实数值：

Wolfram Language code: FunctionRange[ArcCsc[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcCsc[z], z, y, Complexes]

ArcCsc 是一个奇函数：

Wolfram Language code: ArcCsc[-x]

ArcCsc 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCsc[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCsc[x], x]

ArcCsc 在特定范围内是单调的：

Wolfram Language code: FunctionMonotonicity[ArcCsc[x], x]
Wolfram Language code: FunctionMonotonicity[{ArcCsc[x], x ≤ -1 }, x]
Wolfram Language code: FunctionMonotonicity[{ArcCsc[x], x ≥ 1}, x]
Wolfram Language code: Plot[ArcCsc[x], {x, -3, 3}]

ArcCsc 是单射函数：

Wolfram Language code: FunctionInjective[ArcCsc[x], x]
Wolfram Language code: Plot[{ArcCsc[x], 1 / 2}, {x, -5, 5}]

ArcCsc 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCsc[x], x]
Wolfram Language code: Plot[{ArcCsc[x], 2}, {x, -5, 5}]

ArcCsc 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcCsc[x], x]

对于 x，函数在 [-1,1] 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCsc[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCsc[x], x]

ArcCsc 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcCsc[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcCsc[x]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcCsc[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCsc[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCsc[x], {x, n}]

积分  (3)

ArcCsc 的不定积分：

Wolfram Language code: Integrate[ArcCsc[x], x]

ArcCsc 在区间 上的定积分：

Wolfram Language code: Integrate[ArcCsc[x], {x, 1, 2}]

更多积分：

Wolfram Language code: Integrate[x ArcCsc[x], x]
Wolfram Language code: Integrate[z ^ k ArcCsc[z], z]

级数展开式  (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCsc[x], {x, 2, 4}]

绘制 ArcCsc 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcCsc[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcCsc[x], terms}, {x, 1, 3}, PlotRange -> {{1, 3}, {0, 3}}]

求分支点上和分支切割的级数展开式：

Wolfram Language code: Series[ArcCsc[x], {x, 1, 1}]
Wolfram Language code: Series[ArcCsc[x], {x, -1 / 2, 1}]

ArcCsc 可被应用于幂级数：

Wolfram Language code: ArcCsc[x + x ^ 2 + O[x, Infinity] ^ 4]

函数恒等式和化简  (3)

简化涉及 ArcCsc 的表达式：

Wolfram Language code: FullSimplify[ArcCsc[Sqrt[(1/1 - x^2)]], 0 ≤ x ≤ 1]

与反函数组合：

Wolfram Language code: {ArcCsc[Csc[z]], Csc[ArcCsc[z]]}

用 PowerExpand 忽略 ArcCsc 的多值性：

Wolfram Language code: PowerExpand[%]

或者在额外假设条件下进行计算：

Wolfram Language code: Refine[ArcCsc[Csc[z]], 0 < z < Pi / 2]

通过 TrigToExp 用对数来表示：

Wolfram Language code: ArcCsc[z]//TrigToExp

用 ExpToTrig 转换回来：

Wolfram Language code: ExpToTrig[%]//FullSimplify

函数表示  (5)

使用 ArcSin 表示：

Wolfram Language code: ArcSin[(1/z)]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiDS[z, 0]
Wolfram Language code: InverseJacobiNS[z, 0]

使用 Hypergeometric2F1 表示：

Wolfram Language code: (Hypergeometric2F1[(1/2), (1/2), (3/2), (1/z^2)]/z)//FullSimplify

可用 MeijerG 来表示 ArcCsc：

Wolfram Language code: MeijerGReduce[ArcCsc[x], x]
Wolfram Language code: Activate[%]//FullSimplify

也可用 DifferentialRoot 来表示 ArcCsc：

Wolfram Language code: DifferentialRootReduce[ArcCsc[x], x]

应用  (3)

沿实轴延伸的 ArcCsc 分支线：

Wolfram Language code: Plot3D[Im[ArcCsc[x - I y]], {x, -2, 2}, {y, -2, 2}]

求解微分方程：

Wolfram Language code: DSolve[2 x Sin[(y[x]/x)] - Cot[(y[x]/x)] y[x] + x Cot[(y[x]/x)] y'[x] == 0, y[x], x]//Quiet

d 维超球中所有成对的点的平均距离 s 的分布：

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) BetaRegularized[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2]

低维分布可以用基本函数来表达：

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

绘制这些分布图：

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

属性和关系  (5)

与反函数复合：

Wolfram Language code: {ArcCsc[Csc[z]], Csc[ArcCsc[z]]}

利用 PowerExpand 去掉 ArcCsc 的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假设条件下计算：

Wolfram Language code: Refine[ArcCsc[Csc[z]], 0 < z < Pi / 2]

利用 TrigToExp 通过对数表示：

Wolfram Language code: ArcCsc[z]//TrigToExp

利用 ExpToTrig 反向变换：

Wolfram Language code: ExpToTrig[%]

ArcCsc 给出以弧度为单位的角，ArcSecDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcCsc[2]
Wolfram Language code: ArcCscDegrees[2]

利用 FunctionExpand 将反三角函数的三角函数变换成代数函数：

Wolfram Language code: FunctionExpand[Tan[5ArcCsc[z]]]

简化结果：

Wolfram Language code: Simplify[%]

利用 Reduce 求解包含 ArcCsc 的方程：

Wolfram Language code: Reduce[ArcCsc[z] + ArcCsc[z + 1] == Pi / 2, z]//Quiet
Wolfram Research (1988)，ArcCsc，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCsc.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcCsc，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCsc.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcCsc." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcCsc.html.

APA

Wolfram 语言. (1988). ArcCsc. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcCsc.html 年

BibTeX

@misc{reference.wolfram_2026_arccsc, author="Wolfram Research", title="{ArcCsc}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCsc.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccsc, organization={Wolfram Research}, title={ArcCsc}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCsc.html}, note=[Accessed: 12-August-2026]}