WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcSec[z]

複素数 の逆正割を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcSec

ArcSec[z]

複素数 の逆正割を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 答はラジアンで求まる．
  • が実数で〜の区間の外にあるとき，答は必ず を除いた〜 の範囲にある．
  • 特別な引数の場合，ArcSecは自動的に厳密値を計算する．
  • ArcSecは任意の数値精度で評価できる．
  • ArcSecは自動的にリストに関数の並列的な適用を行う．
  • ArcSec[z]は，複素 平面上，〜の範囲で不連続な分枝切断線を持つ．
  • ArcSecはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcSecは，逆正割関数である．ArcSec[x]は，実数 について， となるような で のラジアン角を表す．
  • ArcSecは自動的にリストに縫い込まれる．特別な引数の場合，ArcSecは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcSecは任意の数値精度に評価できることがある．ArcSecを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcSecは，複素引数 について，によって定義される．ArcSec[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Sec，ArcCsc，ArcSechがある．

例題

すべて開く すべて閉じる

例  (5)

結果はラジアンで与えられる：

Wolfram Language code: ArcSec[2]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcSec[2] / Degree//FullSimplify

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSec[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSec[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSec[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSec[x], {x, 1, 3}, Assumptions -> x > 1]//Simplify

スコープ  (41)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcSec[5.0]

高精度で評価する：

Wolfram Language code: N[ArcSec[5], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcSec[5.00000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcSec[0.5 + 2.3I]

ArcSecを高精度で効率よく評価する：

Wolfram Language code: ArcSec[5`500]//Timing
Wolfram Language code: ArcSec[5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSec[Interval[{2, 5}]]
Wolfram Language code: ArcSec[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcSec[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合に統計区間を計算することもできる：

Wolfram Language code: ArcSec[Around[(2/Sqrt[3]), 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcSec[{{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

MatrixFunctionを使って行列のArcSec関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSec[#]&, {{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

特定の値  (5)

固定点におけるArcSecの値：

Wolfram Language code: Table[ArcSec[n], {n, -2, 2}]

簡単な厳密値は自動的に生成される：

Wolfram Language code: ArcSec[(2/Sqrt[3])]

無限大における値：

Wolfram Language code: ArcSec[Infinity]
Wolfram Language code: ArcSec[ComplexInfinity]

ArcSecの零点：

Wolfram Language code: ArcSec[1]

方程式 を満足する の値を求める：

Wolfram Language code: f[x_] := ArcSec[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 1, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcSec関数をプロットする：

Wolfram Language code: Plot[ArcSec[x], {x, -3, 3}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSec[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSec[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcSec[k ϕ], {ϕ, -5π, 5π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-2, 3}, {-3, 2}}]], {k, 1, 4}]

関数の特性  (10)

ArcSecは，区間からのものを除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcSec[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcSec[z], z, Complexes]

ArcSecはから の間にある：

Wolfram Language code: FunctionRange[ArcSec[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcSec[z], z, y, Complexes]

ArcSecは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcSec[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcSec[x], x]

ArcSecは特定の範囲で単調である：

Wolfram Language code: FunctionMonotonicity[ArcSec[x], x]
Wolfram Language code: FunctionMonotonicity[{ArcSec[x], x ≤ -1 }, x]
Wolfram Language code: FunctionMonotonicity[{ArcSec[x], x ≥ 1}, x]
Wolfram Language code: Plot[ArcSec[x], {x, 1, 3}]

ArcSecは単射である：

Wolfram Language code: FunctionInjective[ArcSec[x], x]
Wolfram Language code: Plot[{ArcSec[x], 1 / 2}, {x, -5, 5}]

ArcSecは全射ではない：

Wolfram Language code: FunctionSurjective[ArcSec[x], x]
Wolfram Language code: Plot[{ArcSec[x], π / 2}, {x, -5, 5}]

ArcSecは実数領域上で非負ではない：

Wolfram Language code: FunctionSign[{ArcSec[x], x ≤ -1 || x ≥ 1}, x]

[-1,1]で x について特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcSec[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSec[x], x]

ArcSecは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSec[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcSec[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcSec[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSec[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcSec[x], {x, n}]

積分  (3)

ArcSecの不定積分：

Wolfram Language code: Integrate[ArcSec[x], x]

区間上の定積分：

Wolfram Language code: Integrate[ArcSec[x], {x, 1, 2}]

その他の積分例：

Wolfram Language code: Integrate[x ArcSec[x], x]
Wolfram Language code: Integrate[z ^ k ArcSec[z], z]

級数展開  (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSec[x], {x, 2, 4}]

の周りでのArcSecの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcSec[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcSec[x], terms}, {x, 1, 3}, PlotRange -> {{1, 3}, {0, 2}}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcSec[x], {x, 1, 1}]//FullSimplify
Wolfram Language code: Series[ArcSec[x], {x, -1 / 2, 1}]

ArcSecはベキ級数に適用できる：

Wolfram Language code: ArcSec[x + x ^ 2 + O[x, Infinity] ^ 4]

関数の恒等式と簡約  (3)

ArcSecを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcSec[Sqrt[(1/1 - x^2)]], 0 ≤ x ≤ 1]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcSec[z]//TrigToExp

ExpToTrigを使って変換し直す：

Wolfram Language code: ExpToTrig[%]//FullSimplify

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcSec[x + I y]]

関数表現  (5)

ArcCosを使って表現する：

Wolfram Language code: ArcCos[(1/z)]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: InverseJacobiCD[(1/z), 0]//FullSimplify
Wolfram Language code: InverseJacobiCN[(1/z), 0]//FullSimplify

Hypergeometric2F1を使って表現する：

Wolfram Language code: (π/2) - (Hypergeometric2F1[(1/2), (1/2), (3/2), (1/x^2)]/x)//FullSimplify

ArcSecはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ArcSec[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcSecはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcSec[x], x]

アプリケーション  (3)

ArcSecの分枝切断線は実軸に沿っている：

Wolfram Language code: Plot3D[Im[ArcSec[x + I y]], {x, -2, 2}, {y, -2, 2}]

微分方程式を解く：

Wolfram Language code: DSolve[Cos[y[x]] (1 - x Cos[y[x]]) + x Log[x] Sin[y[x]] Derivative[1][y][x] == 0, y[x], x]//Quiet

計算速度を上げるためにParallelizeを使って作成した複数の複素三角関数を可視化する：

Wolfram Language code: $TrigFunctions = {Sin, Cos, Sec, Csc, Tan, Cot, ArcSin, ArcCos, ArcSec, ArcCsc, ArcTan, ArcCot};
Wolfram Language code: Parallelize@Table[Plot3D[Abs[f[x + I y]], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> Function@@@{{{x, y, z}, Re[f[x + I y]]}, {{x, y, z}, Im[f[x + I y]]}}, MeshShading -> {{Orange, None}, {None, Green}}, PlotLabel -> f, Ticks -> None, ImageSize -> 100], {f, $TrigFunctions}]

特性と関係  (5)

逆関数で構成する：

Wolfram Language code: {ArcSec[Sec[z]], Sec[ArcSec[z]]}

PowerExpandを使ってArcSecの多価性を無視する：

Wolfram Language code: PowerExpand[%]

追加的な仮定をして評価する：

Wolfram Language code: Refine[ArcSec[Sec[z]], 0 < z < Pi / 2]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcSec[z]//TrigToExp

ExpToTrigを使ってもとに戻す：

Wolfram Language code: ExpToTrig[%]

ArcSecが角度をラジアンで与えるのに対し，ArcSecDegreesは同じ角度を度で与える：

Wolfram Language code: ArcSec[2]
Wolfram Language code: ArcSecDegrees[2]

FunctionExpandを使って逆三角関数の三角関数を代数関数に変換する：

Wolfram Language code: FunctionExpand[Tan[5ArcSec[z]]]

結果を簡約する：

Wolfram Language code: Simplify[%]

Reduceを使ってArcSecを含む方程式を解く：

Wolfram Language code: Reduce[ArcSec[z] + ArcSec[z + 1] == Pi / 2, z]//Quiet
Wolfram Research (1988), ArcSec, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSec.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcSec, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSec.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcSec." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcSec.html.

APA

Wolfram Language. (1988). ArcSec. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSec.html

BibTeX

@misc{reference.wolfram_2026_arcsec, author="Wolfram Research", title="{ArcSec}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSec.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsec, organization={Wolfram Research}, title={ArcSec}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcSec.html}, note=[Accessed: 18-August-2026]}