ArcTanDegrees

ArcTanDegrees[z]

複素数の逆正接を度を単位として与える．

詳細

ArcTanDegreesは，その他の逆三角関数および三角関数とともに，高等学校の幾何の授業で学ばれ，多くの科学分野で使われている．
結果はすべて度を単位として与えられる．
実数については，結果は常にからまでの範囲になる．
ArcTanDegrees[z]は角を度を単位として返す．直角三角形のこの角の隣辺と斜辺の比はである．

特別な引数の場合，ArcTanDegreesは，自動的に厳密値を計算する．
ArcTanDegreesは任意の数値精度で評価できる．
ArcTanDegreesは自動的にリストに縫い込まれる．
ArcTanDegrees[z]は，複素平面上のからおよびからまでに不連続な分枝切断線を持つ．
ArcTanDegreesは，Interval，CenteredInterval，Aroundの各オブジェクトに使うことができる．
記号操作・数値操作の両方に適した数学関数である．

例題

すべて開くすべて閉じる

例 (7)

結果の単位は度である：

Wolfram Language code: ArcTanDegrees[1]

以下の直角三角形の角BACを計算する：

手計算で求める：

Wolfram Language code: β = ArcTanDegrees[4 / 6]

この角度の数値：

Wolfram Language code: %//N

逆三角関数の方程式を解く：

Wolfram Language code: Solve[ArcTanDegrees[x] == 60, x]

逆三角関数の不等式を解く：

Wolfram Language code: Reduce[ArcTanDegrees[x] > 60, x]

ArcTanDegreesを以下のリストに適用する：

Wolfram Language code: ArcTanDegrees[{0, 2 - Sqrt[3], (1/Sqrt[3]), 1, Sqrt[3], 2 + Sqrt[3]}]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcTanDegrees[x], {x, -5, 5}]

0における級数展開：

Wolfram Language code: Series[ArcTanDegrees[x], {x, 0, 15}]

スコープ (40)

数値評価 (6)

数値的に評価する：

Wolfram Language code: ArcTanDegrees[0.5]

高精度で評価する：

Wolfram Language code: N[ArcTanDegrees[1 / 2], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ArcTanDegrees[0.50000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcTanDegrees[2.5 + I]

ArcTanDegreesを高精度で効率的に評価する：

Wolfram Language code: ArcTanDegrees[0.4`500]//Timing

Wolfram Language code: ArcTanDegrees[0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcTanDegrees[Interval[{-1, 3}]]

Wolfram Language code: ArcTanDegrees[CenteredInterval[1, 1 / 100]]

Wolfram Language code: ArcTanDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計的区間を計算することもできる：

Wolfram Language code: ArcTanDegrees[Around[.9, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcTanDegrees[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

MatrixFunctionを使って行列のArcTanDegrees関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcTanDegrees[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特定の値 (5)

固定点におけるArcTanDegreesの値：

Wolfram Language code: Table[ArcTanDegrees[n], {n, -1, 1}]

単純な厳密値は自動的に生成される：

Wolfram Language code: ArcTanDegrees[(1/Sqrt[3])]

無限大における値：

Wolfram Language code: ArcTanDegrees[Infinity]

Wolfram Language code: ArcTanDegrees[ComplexInfinity]

ArcTanDegreesの零点：

Wolfram Language code: ArcTanDegrees[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := ArcTanDegrees[x] - 60;

Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -2, 2}, Rule[...]]

可視化 (4)

ArcTanDegrees関数をプロットする：

Wolfram Language code: Plot[ArcTanDegrees[x], {x, -7, 7}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcTanDegrees[z ^ 2], {z, -1 / 2 - I, 1 / 2 + I}, Rule[...]]

ArcTanDegreesの実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcTanDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

ArcTanDegreesの虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcTanDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

ArcTanDegreesの極プロット：

Wolfram Language code: Table[PolarPlot[ArcTanDegrees[k ϕ], {ϕ, -π, π}, ...], {k, 1, 4}]

関数の特性 (12)

ArcTanDegreesはすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcTanDegrees[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcTanDegrees[z], z, Complexes]

ArcTanDegreesは区間からのすべての実数値に到達する：

Wolfram Language code: FunctionRange[ArcTanDegrees[x], x, y]

複素数値の範囲：

Wolfram Language code: FunctionRange[ArcTanDegrees[x], x, y, Complexes]

ArcTanDegreesは奇関数である：

Wolfram Language code: ArcTanDegrees[-x]

ArcTanDegreesは鏡面特性 $tan^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{tan, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]$ を持つ：

Wolfram Language code: FullSimplify[ArcTanDegrees[Conjugate[x]] == Conjugate[ArcTanDegrees[x]]]

ArcTanDegreesは，実数上のの解析関数である：

Wolfram Language code: FunctionAnalytic[ArcTanDegrees[x], x]

複素平面では解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[ArcTanDegrees[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[ArcTanDegrees[x], x]

ArcTanDegreesは増加関数である：

Wolfram Language code: FunctionMonotonicity[ArcTanDegrees[x], x, StrictInequalities -> True]

ArcTanDegreesは単射である：

Wolfram Language code: FunctionInjective[ArcTanDegrees[x], x]

Wolfram Language code: Plot[{ArcTanDegrees[x], 20}, {x, -5, 5}]

ArcTanDegreesは全射ではない：

Wolfram Language code: FunctionSurjective[ArcTanDegrees[x], x]

Wolfram Language code: Plot[{ArcTanDegrees[x], 150}, {x, -5, 5}]

ArcTanDegreesは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcTanDegrees[x], x]

ArcTanDegreesは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[ArcTanDegrees[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcTanDegrees[x], x]

ArcTanDegreesは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcTanDegrees[x], x]

ArcSindは x が[-10,0]のときは凸である：

Wolfram Language code: FunctionConvexity[{ArcTanDegrees[x], -10 <= x <= 0}, x]

Wolfram Language code: Plot[ArcTanDegrees[x], {x, -10, 10}]

TraditionalFormによる表示：

Wolfram Language code: ArcTanDegrees[α]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[ArcTanDegrees[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcTanDegrees[x], {x, n}], {n, 1, 4}]

Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, Rule[...]]

次導関数の式：

Wolfram Language code: D[ArcTanDegrees[x], {x, n}]

積分 (2)

ArcTanDegreesの不定積分：

Wolfram Language code: Integrate[ArcTanDegrees[x], x]

原点を中心とした区間上のArcTanDegreesの定積分は0である：

Wolfram Language code: Integrate[ArcTanDegrees[x], {x, -1, 1}]

級数展開 (5)

ArcTanDegreesのテイラー(Taylor)展開：

Wolfram Language code: Series[ArcTanDegrees[x], {x, 0, 7}]

付近のArcTanDegreesの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[ArcTanDegrees[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcTanDegrees[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcTanDegrees[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcTanDegrees[x], {x, I, 3}]//FullSimplify

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcTanDegrees[x], {x, I, 1}]

Wolfram Language code: Series[ArcTanDegrees[x], {x, 2I, 1}]

ArcTanDegreesはベキ級数に適用できる：

Wolfram Language code: ArcTanDegrees[SeriesData[x, 0, {1, 0, 1/3, 0, 2/15, 0, 17/315, 0, 62/2835}, 1, 10, 1]]

関数の恒等式と簡約 (2)

FullSimplifyを使ってArcTanDegreesを含む式を簡約する：

Wolfram Language code: FullSimplify[16 ArcTanDegrees[1 / 5] - 4 ArcTanDegrees[1 / 239]]

TrigToExpを使ってArcTanDegreesをLogを使って表す：

Wolfram Language code: TrigToExp[ArcTanDegrees[z]]

関数表現 (1)

ArcCotDegreesを使って表す：

Wolfram Language code: ArcCotDegrees[1 / x]//FullSimplify

アプリケーション (7)

逆三角関数の方程式を解く：

Wolfram Language code: Solve[ArcTanDegrees[α x + β] == 4, x]

Wolfram Language code: Solve[ArcTanDegrees[z]^2 + 3 ArcTanDegrees[z] == 2, z]

逆三角関数の方程式をパラメータで解く：

Wolfram Language code: Reduce[ArcTanDegrees[TanDegrees[z]] == w, z]

Reduceを使ってArcTanDegreesを含む不等式を解く：

Wolfram Language code: Reduce[ArcTanDegrees[x] > 60, x]

超越方程式の数値根を求める：

Wolfram Language code: FindRoot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] == -3, {z, 0, 1 / 2}]

関数をプロットして解が正しいかどうかをチェックする：

Wolfram Language code: Plot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] + 3, {z, 0, 1 / 2}]

ArcTanDegreesの実部と虚部をプロットする：

Wolfram Language code: ReImPlot[ArcTanDegrees[x], {x, -2, 2}]

ArcTanDegreesと三角関数のさまざまな組合せ：

Wolfram Language code:

{TanDegrees[ArcTanDegrees[z]], SecDegrees[ArcTanDegrees[1 / z]], CotDegrees[ArcTanDegrees[z ^ 2]], SinDegrees[ArcTanDegrees[z]]}

正接関数の加法定理：

Wolfram Language code: TanDegrees[ArcTanDegrees[x] + ArcTanDegrees[y]]//TrigExpand//Simplify

特性と関係 (5)

逆三角関数による構成：

Wolfram Language code: {TanDegrees[ArcTanDegrees[z]], ArcTanDegrees[TanDegrees[z]]}

PowerExpandを使ってArcTanDegreesの多価性を無視する：

Wolfram Language code: PowerExpand[%]

追加的な仮定を使って評価することもできる：

Wolfram Language code: Refine[ArcTanDegrees[TanDegrees[z]], 0 < z < 90]

ArcTanDegreesの分枝切断線は虚軸に沿っている：

Wolfram Language code: Plot3D[Re[ArcTanDegrees[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

ArcTanDegreesは角度を度で与えるが，ArcTanは同じ角度をラジアンで与える：

Wolfram Language code: ArcTanDegrees[1]

Wolfram Language code: ArcTan[1]

ArcTanDegreesにFunctionExpandを適用すると三角関数の式がラジアン単位で生成される：

Wolfram Language code: FunctionExpand[ArcTanDegrees[x]]

Wolfram Language code: FunctionExpand[ArcTanDegrees[x ^ 2]ArcTanDegrees[120 - x / 2]]

TrigToExpの出力にExpToTrigを適用すると三角関数がラジアン単位で生成される：

Wolfram Language code: ArcTanDegrees[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

考えられる問題 (1)

一般的にである：

Wolfram Language code: ArcTanDegrees[TanDegrees[100.]]

これは，もとの引数と倍異なる：

Wolfram Language code: (% - 100) / 180

おもしろい例題 (2)

ArcTanDegreesを含む三角関数の方程式を解く：

Wolfram Language code: Reduce[ArcTanDegrees[z] + ArcTanDegrees[z - 1] == 90, z]//Quiet

この角の度を単位とした数値：

Wolfram Language code: %//N

整数点でArcTanDegreesをプロットする：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcTanDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcTanDegrees

詳細

例題

例 (7)