WOLFRAM

Wolfram 语言与系统参考资料中心

ArcTanDegrees[z]

给出复数 的以度为单位的反正切值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值計算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开  
函数恒等和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

ArcTanDegrees

ArcTanDegrees[z]

给出复数 的以度为单位的反正切值.

更多信息

  • ArcTanDegrees，以及其他反三角函数和三角函数在高中几何课程中学习的内容，在许多科学学科中也有应用.
  • 所有结果均以度为单位.
  • 对于实数值 ，结果总是在 到 之间.
  • ArcTanDegrees[z] 返回直角三角形对边与邻边之比为 的角度 ，单位为度.
  • 对于某些特殊参数，ArcTanDegrees 会自动求出精确值.
  • ArcTanDegrees 可按任意数值精度求值.
  • ArcTanDegrees 自动线性作用于列表.
  • ArcTanDegrees[z] 在复平面 上有从 到 和从 到 的分支切割不连续点.
  • ArcTanDegrees 可用于 Interval、CenteredInterval 和 Around 对象.
  • 数学函数，适用于符号和数字运算.

范例

打开所有单元 关闭所有单元

基本范例  (7)

结果以度为单位：

Wolfram Language code: ArcTanDegrees[1]

计算这个直角三角形的角 BAC：

手动计算：

Wolfram Language code: β = ArcTanDegrees[4 / 6]

该角的数值：

Wolfram Language code: %//N

求解反三角方程：

Wolfram Language code: Solve[ArcTanDegrees[x] == 60, x]

求解反三角不等式：

Wolfram Language code: Reduce[ArcTanDegrees[x] > 60, x]

将 ArcTanDegrees 应用于下列列表：

Wolfram Language code: ArcTanDegrees[{0, 2 - Sqrt[3], (1/Sqrt[3]), 1, Sqrt[3], 2 + Sqrt[3]}]

在实数子集上绘图：

Wolfram Language code: Plot[ArcTanDegrees[x], {x, -5, 5}]

0 处的级数展开：

Wolfram Language code: Series[ArcTanDegrees[x], {x, 0, 15}]

范围  (40)

数值計算  (6)

进行数值运算：

Wolfram Language code: ArcTanDegrees[0.5]

高精度运算：

Wolfram Language code: N[ArcTanDegrees[1 / 2], 50]

输出的精度与输入的精度一致：

Wolfram Language code: ArcTanDegrees[0.50000000000000000000000000000000000000000]

对复参数进行运算：

Wolfram Language code: ArcTanDegrees[2.5 + I]

高精度高效运算 ArcTanDegrees：

Wolfram Language code: ArcTanDegrees[0.4`500]//Timing
Wolfram Language code: ArcTanDegrees[0.4`100000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: ArcTanDegrees[Interval[{-1, 3}]]
Wolfram Language code: ArcTanDegrees[CenteredInterval[1, 1 / 100]]
Wolfram Language code: ArcTanDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

或者使用 Around 计算平均情况统计区间：

Wolfram Language code: ArcTanDegrees[Around[.9, 0.01]]

计算数组的元素值：

Wolfram Language code: ArcTanDegrees[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

或使用 MatrixFunction 计算矩阵 ArcTanDegrees 函数：

Wolfram Language code: MatrixFunction[ArcTanDegrees[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特殊值  (5)

固定点的 ArcTanDegrees 值：

Wolfram Language code: Table[ArcTanDegrees[n], {n, -1, 1}]

简单精确的数值会自动生成：

Wolfram Language code: ArcTanDegrees[(1/Sqrt[3])]

无穷大时的值：

Wolfram Language code: ArcTanDegrees[Infinity]
Wolfram Language code: ArcTanDegrees[ComplexInfinity]

ArcTanDegrees 的零点：

Wolfram Language code: ArcTanDegrees[0]

求满足方程 的 的值：

Wolfram Language code: f[x_] := ArcTanDegrees[x] - 60;
Wolfram Language code: sol = Solve[f[x] == 0, x]

代入数值：

Wolfram Language code: xzero = x /. First[sol]

将结果可视化：

Wolfram Language code: Plot[f[x], {x, -2, 2}, Rule[...]]

可视化  (4)

绘制 ArcTanDegrees 函数：

Wolfram Language code: Plot[ArcTanDegrees[x], {x, -7, 7}]

在虚数子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcTanDegrees[z ^ 2], {z, -1 / 2 - I, 1 / 2 + I}, Rule[...]]

绘制 ArcTanDegrees 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcTanDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

绘制 ArcTanDegrees 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcTanDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

使用 ArcTanDegrees 绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcTanDegrees[k ϕ], {ϕ, -π, π}, ...], {k, 1, 4}]

函数属性  (12)

ArcTanDegrees 对所有实值有定义：

Wolfram Language code: FunctionDomain[ArcTanDegrees[x], x]

复数域：

Wolfram Language code: FunctionDomain[ArcTanDegrees[z], z, Complexes]

ArcTanDegrees 可取区间 内的所有实数值：

Wolfram Language code: FunctionRange[ArcTanDegrees[x], x, y]

复数值的取值范围：

Wolfram Language code: FunctionRange[ArcTanDegrees[x], x, y, Complexes]

ArcTanDegrees 是奇函数：

Wolfram Language code: ArcTanDegrees[-x]

ArcTanDegrees 有镜像属性 tan^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{tan, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]:

Wolfram Language code: FullSimplify[ArcTanDegrees[Conjugate[x]] == Conjugate[ArcTanDegrees[x]]]

ArcTanDegrees 是 在实数上的解析函数：

Wolfram Language code: FunctionAnalytic[ArcTanDegrees[x], x]

在复平面上，它既不是解析函数，也不是半纯函数：

Wolfram Language code: FunctionAnalytic[ArcTanDegrees[x], x, Complexes]
Wolfram Language code: FunctionMeromorphic[ArcTanDegrees[x], x]

ArcTanDegrees 是一个递增函数：

Wolfram Language code: FunctionMonotonicity[ArcTanDegrees[x], x, StrictInequalities -> True]

ArcTanDegrees 是单射函数：

Wolfram Language code: FunctionInjective[ArcTanDegrees[x], x]
Wolfram Language code: Plot[{ArcTanDegrees[x], 20}, {x, -5, 5}]

ArcTanDegrees 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcTanDegrees[x], x]
Wolfram Language code: Plot[{ArcTanDegrees[x], 150}, {x, -5, 5}]

ArcTanDegrees 既不是非负也不是非正：

Wolfram Language code: FunctionSign[ArcTanDegrees[x], x]

ArcTanDegrees 没有奇点或不连续点：

Wolfram Language code: FunctionSingularities[ArcTanDegrees[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcTanDegrees[x], x]

ArcTanDegrees 既不凸也不凹：

Wolfram Language code: FunctionConvexity[ArcTanDegrees[x], x]

ArcSind 对于区间 [-10,0] 中的 x 是凸函数：

Wolfram Language code: FunctionConvexity[{ArcTanDegrees[x], -10 <= x <= 0}, x]
Wolfram Language code: Plot[ArcTanDegrees[x], {x, -10, 10}]

TraditionalForm 格式：

Wolfram Language code: ArcTanDegrees[α]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcTanDegrees[x], x]

更高阶导数：

Wolfram Language code: Table[D[ArcTanDegrees[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, Rule[...]]

阶导数的公式：

Wolfram Language code: D[ArcTanDegrees[x], {x, n}]

积分  (2)

ArcTanDegrees 的不定积分：

Wolfram Language code: Integrate[ArcTanDegrees[x], x]

ArcTanDegrees 在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[ArcTanDegrees[x], {x, -1, 1}]

级数展开  (5)

ArcTanDegrees 的泰勒展开式：

Wolfram Language code: Series[ArcTanDegrees[x], {x, 0, 7}]

在 周围绘制 ArcTanDegrees 前三个近似：

Wolfram Language code: terms = Normal@Table[Series[ArcTanDegrees[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcTanDegrees[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

Infinity 处的渐近展开：

Wolfram Language code: Series[ArcTanDegrees[x], {x, ∞, 5}]

其中一个奇点的渐近展开：

Wolfram Language code: Series[ArcTanDegrees[x], {x, I, 3}]//FullSimplify

求分支点和分支切割处的级数展开式：

Wolfram Language code: Series[ArcTanDegrees[x], {x, I, 1}]
Wolfram Language code: Series[ArcTanDegrees[x], {x, 2I, 1}]

ArcTanDegrees 可以应用于幂级数：

Wolfram Language code: ArcTanDegrees[SeriesData[x, 0, {1, 0, 1/3, 0, 2/15, 0, 17/315, 0, 62/2835}, 1, 10, 1]]

函数恒等和化简  (2)

使用 FullSimplify 化简与 ArcTanDegrees 相关的表达式：

Wolfram Language code: FullSimplify[16 ArcTanDegrees[1 / 5] - 4 ArcTanDegrees[1 / 239]]

使用 TrigToExp 通过 Log 表达 ArcTanDegrees：

Wolfram Language code: TrigToExp[ArcTanDegrees[z]]

函数表示  (1)

使用 ArcCotDegrees 进行表示：

Wolfram Language code: ArcCotDegrees[1 / x]//FullSimplify

应用  (7)

求解反三角方程：

Wolfram Language code: Solve[ArcTanDegrees[α x + β] == 4, x]
Wolfram Language code: Solve[ArcTanDegrees[z]^2 + 3 ArcTanDegrees[z] == 2, z]

求解带参数的反三角方程：

Wolfram Language code: Reduce[ArcTanDegrees[TanDegrees[z]] == w, z]

使用 Reduce 求解关于 ArcTanDegrees 的不等式：

Wolfram Language code: Reduce[ArcTanDegrees[x] > 60, x]

通过数值求出超越方程的根：

Wolfram Language code: FindRoot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] == -3, {z, 0, 1 / 2}]

绘制函数图，检查解是否正确：

Wolfram Language code: Plot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] + 3, {z, 0, 1 / 2}]

绘制 ArcTanDegrees 的实部和虚部：

Wolfram Language code: ReImPlot[ArcTanDegrees[x], {x, -2, 2}]

ArcTanDegrees 与三角函数的不同组合：

Wolfram Language code: {TanDegrees[ArcTanDegrees[z]], SecDegrees[ArcTanDegrees[1 / z]], CotDegrees[ArcTanDegrees[z ^ 2]], SinDegrees[ArcTanDegrees[z]]}

切线函数的加法定理：

Wolfram Language code: TanDegrees[ArcTanDegrees[x] + ArcTanDegrees[y]]//TrigExpand//Simplify

属性和关系  (5)

复合反三角函数：

Wolfram Language code: {TanDegrees[ArcTanDegrees[z]], ArcTanDegrees[TanDegrees[z]]}

使用 PowerExpand 可忽略 ArcTanDegrees 的多值性：

Wolfram Language code: PowerExpand[%]

或者，根据其他假设进行运算：

Wolfram Language code: Refine[ArcTanDegrees[TanDegrees[z]], 0 < z < 90]

ArcTanDegrees 的分支切线沿虚轴运行：

Wolfram Language code: Plot3D[Re[ArcTanDegrees[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

ArcTanDegrees 给出的角度以度数为单位，而 ArcTan 给出的角度以弧度为单位：

Wolfram Language code: ArcTanDegrees[1]
Wolfram Language code: ArcTan[1]

将 FunctionExpand 应用于 ArcTanDegrees 可生成以弧度为单位的三角函数表达式：

Wolfram Language code: FunctionExpand[ArcTanDegrees[x]]
Wolfram Language code: FunctionExpand[ArcTanDegrees[x ^ 2]ArcTanDegrees[120 - x / 2]]

ExpToTrig 应用于 TrigToExp 的输出，将生成以弧度为单位的三角函数：

Wolfram Language code: ArcTanDegrees[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

可能存在的问题  (1)

一般情况下 ：

Wolfram Language code: ArcTanDegrees[TanDegrees[100.]]

这与最初的参数相差 倍：

Wolfram Language code: (% - 100) / 180

巧妙范例  (2)

求解关于 ArcTanDegrees 的三角方程：

Wolfram Language code: Reduce[ArcTanDegrees[z] + ArcTanDegrees[z - 1] == 90, z]//Quiet

该角度的数值，单位为度：

Wolfram Language code: %//N

在整数点处绘制 ArcTanDegrees：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcTanDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]
Wolfram Research (2024)，ArcTanDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcTanDegrees.html.

文本

Wolfram Research (2024)，ArcTanDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcTanDegrees.html.

CMS

Wolfram 语言. 2024. "ArcTanDegrees." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArcTanDegrees.html.

APA

Wolfram 语言. (2024). ArcTanDegrees. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcTanDegrees.html 年

BibTeX

@misc{reference.wolfram_2026_arctandegrees, author="Wolfram Research", title="{ArcTanDegrees}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ArcTanDegrees.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arctandegrees, organization={Wolfram Research}, title={ArcTanDegrees}, year={2024}, url={https://reference.wolfram.com/language/ref/ArcTanDegrees.html}, note=[Accessed: 14-August-2026]}