Wolfram言語＆システムドキュメントセンター

ArgMax

ArgMax[f,x]

f が最大となる x_max の位置を与える．

ArgMax[f,{x,y,…}]

f が最大となる{x_max,y_max,…}の位置を与える．

ArgMax[{f,cons},{x,y,…}]

制約条件 cons の下で f が最大となる位置を与える．

ArgMax[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

ArgMax[…,…,dom]

変数を領域 dom（一般にRealsあるいはIntegers）に制限する．

ArgMax

ArgMax[f,x]

f が最大となる x_max の位置を与える．

ArgMax[f,{x,y,…}]

f が最大となる{x_max,y_max,…}の位置を与える．

ArgMax[{f,cons},{x,y,…}]

制約条件 cons の下で f が最大となる位置を与える．

ArgMax[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

ArgMax[…,…,dom]

変数を領域 dom（一般にRealsあるいはIntegers）に制限する．

詳細とオプション

ArgMaxは与えられた制約条件に従って f の最大値を求める．
ArgMaxは，通常，制約条件下で可能な最大値を求めるために使われる．分野によっては，最適な戦略，最良適合，最適な構成等と呼ばれることがある．

f と cons が線形または多項式の場合，ArgMaxは常に最大値を求める．
制約条件 cons は，以下の任意の論理結合でよい．

	lhs==rhs	等式
	lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs	不等式 (LessEqual,…)
	lhsrhs, lhsrhs, lhsrhs, lhsrhs	ベクトル不等式 (VectorLessEqual,…)
	Exists[…], ForAll[…]	量化条件
	{x,y,…}∈rdom	領域指定

ArgMax[{f,cons},x∈rdom]は，事実上，ArgMax[{f,cons∧x∈rdom},x]に等しい．
x∈rdom については，Indexed[x,i]を使って別の座標に言及することができる．
次は，使用可能な領域 rdom である．

	Reals	実数スカラー変数
	Integers	整数スカラー変数
	Vectors[n,dom]	のベクトル変数
	Matrices[{m,n},dom]	の行列変数
	ℛ	幾何領域に制限されたベクトル変数

デフォルトで，すべての変数が実数であるとみなされる．
ArgMaxは入力が厳密値の場合は厳密値を返す．入力が近似値の場合は自動的にNArgMaxを呼び出す．
最大値が制約条件で定義された領域外で無限小にあるいは漸近的にしか達しなかった場合，ArgMaxは最も近い指定可能な点を返す．
いくつかの点で同じ最大値に達したとしても，その中の1つしか返されない．
ArgMaxは，制約条件が満足できない場合は{Indeterminate,Indeterminate,…}を返す．
N[ArgMax[…]]は，記号的には解けない最適化問題についてはNArgMaxを呼び出す．

例題

すべて開くすべて閉じる

例 (5)

一変数関数が最大となる点を求める：

Wolfram Language code: ArgMax[-2x ^ 2 - 3x + 5, x]

多変数関数が最大となる点を求める：

Wolfram Language code: ArgMax[1 - (x y - 3) ^ 2, {x, y}]

制約条件に従って関数が最大となる点を求める：

Wolfram Language code: ArgMax[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

関数が最大になる点をパラメータの関数として求める：

Wolfram Language code: ArgMax[a x ^ 2 + b x + c, x]

関数が最大になる点を幾何学領域上で求める：

Wolfram Language code: ArgMax[x + y, {x, y}∈Disk[]]

これをプロットする：

Wolfram Language code: Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[%]}]]

スコープ (36)

基本的な用法 (7)

制約条件のない実数上でを最大にする：

Wolfram Language code: ArgMax[Sin[x] + Cos[x], {x}]

リスト中に単一の変数が与えられていない場合，結果は最大値に達する値になる：

Wolfram Language code: ArgMax[Sin[x] + Cos[x], x]

制約条件に従ってを最大にする：

Wolfram Language code: ArgMax[{x + 2y, x ^ 2 + 2y ^ 2 ≤ 3 && x + y == 2 && x ≥ 1}, {x, y}]

制約条件は任意の論理結合を含むことがある：

Wolfram Language code: ArgMax[{x y, x ^ 2 + y ^ 2 ≤ 1 || (x + 1) ^ 2 + (y - 1) ^ 2 ≤ 2}, {x, y}]

非有界の問題：

Wolfram Language code: ArgMax[{x + y, x ≤ y ^ 2}, {x, y}]

実行不可能な問題：

Wolfram Language code: ArgMax[{x + y, x ^ 2 + y ^ 2 < 0}, {x, y}]

上限値には達しないかもしれない：

Wolfram Language code: ArgMax[-Exp[x], x]

ベクトル変数とベクトル不等式を使う：

Wolfram Language code: ArgMax[{{-1, -1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]

一変数の問題 (7)

制約条件のない一変数多項式の最大化：

Wolfram Language code: ArgMax[-x ^ 4 + 2x ^ 3 + 5x - 7, x]

制約条件のある一変数多項式の最大化：

Wolfram Language code: ArgMax[{-3x ^ 2 - x + 9, 2x ^ 3 + 5x - 7 ≥ 0}, x]

指数対数関数：

Wolfram Language code: ArgMax[-E ^ (2E ^ x) + Log[x ^ 2 + 1] + 20x, x]

有界の条件上での解析関数：

Wolfram Language code: ArgMax[{AiryAi[x + Sin[x]] + Cos[x ^ 2], -5 ≤ x ≤ 5}, x]

Wolfram Language code:

Plot[AiryAi[x + Sin[x]] + Cos[x ^ 2], {x, -5, 5}, Epilog -> {Red, Point[{%, AiryAi[x + Sin[x]] + Cos[x ^ 2] /. x -> %}]}]

Wolfram Language code: ArgMax[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], 0 ≤ x ≤ 10}, x]

Wolfram Language code:

Plot[BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], {x, 0, 10}, Epilog -> {Red, Point[{%, BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x] /. x -> %}]}]

周期関数：

Wolfram Language code: ArgMax[{Sin[x], -1 / 2 ≤ Cos[x] ≤ 1 / 2}, x]

三角関数と通約可能な周期の組合せ：

Wolfram Language code: ArgMax[Sin[E ^ (x / 3) - 3 x] + 2 Cos[2 E ^ (x / 3) - 6 x + 1] ^ 2, x]

区分関数：

Wolfram Language code: ArgMax[{Floor[x + UnitStep[x - 1]] - x, Ceiling[Abs[x]] < 5}, x]

関数の特性情報を使って可解の制約条件がない問題：

Wolfram Language code: ArgMax[SinhIntegral[DawsonF[x]], x]

Wolfram Language code: ArgMax[BesselJ[7 / 4, x ^ 2 + x + 1], x]

多変数の問題 (9)

多変数線形制約条件付き関数の最大化：

Wolfram Language code: ArgMax[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

線形分数制約条件付き関数の最大化：

Wolfram Language code: ArgMax[{(2x + y - z) / (5x - 7y + 3), 0 ≤ x + y + z ≤ 1 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

制約条件なしの多項式の最大化：

Wolfram Language code: ArgMax[x ^ 2 - 2y - 1 - (x ^ 2 - 2y) ^ 2, {x, y}]

制約条件付き多項式の最適化は常に解くことができる：

Wolfram Language code: ArgMax[{x y - 1, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

最大値には達しないかもしれない：

Wolfram Language code: ArgMax[{1 - x ^ 2, x y ≥ 1}, {x, y}]

目的関数は非有界かもしれない：

Wolfram Language code: ArgMax[{x, x y ≤ 1}, {x, y}]

制約条件を満足する点は存在しないかもしれない：

Wolfram Language code: ArgMax[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]

定量化された多項式制約：

Wolfram Language code:

ArgMax[{-(x + 7)^2 - (y - 8)^2, Subscript[∀, z]Subscript[∃, w]3 z^2 w + (x + y) z^4 - 1 == (x^3 - x y + y^2 - 1) w^2}, {x, y}]

代数的最大化：

Wolfram Language code: ArgMax[{-x - Sqrt[x + y] , x Sqrt[y] ≥ 1}, {x, y}]

有界の超越関数の最大化：

Wolfram Language code: ArgMax[{E ^ x + Log[y], x Log[y] == 2 && -10 ≤ x ≤ 10 && 1 / 10 ≤ y ≤ 10}, {x, y}]

区分関数の最大化：

Wolfram Language code: ArgMax[{-Max[x - y, Abs[y]], Min[x - 2, x - y ^ 2] ≥ Abs[x y - 1]}, {x, y}]

凸最大化：

Wolfram Language code: ArgMax[v.{1, -1}, {VectorGreaterEqual[{{{1, 0}, {0, 1}, {-1, -2}}.v, {0, 0, -2}}, "ExponentialCone"]}, v]

が半正定でとなるように凹目的関数を最大にする：

Wolfram Language code:

res = ArgMax[{Log[x + y], (⁠|       |       |
| ----- | ----- |
| x + y | 1     |
| 1     | x - y |⁠)Underscript[, {"SemidefiniteCone", 2}]0 && 1 ≤ x ≤ 10 && -1 ≤ y ≤ 1}, {x, y}]

領域と最小化点をプロットする：

Wolfram Language code:

Show[Plot3D[Log[x + y], {x, 1, 10}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[0.05], Point[Append[res, Log[x + y] /. Thread[{x, y} -> res]]]}]]

パラメトリック問題 (4)

パラメトリック線形最適化：

Wolfram Language code:

ArgMax[{8x + 7y, -6 x - 4 y ≤ 8 - 5 a - 7 b && 7 x + 5 y ≤ a + 4 b && -x + y ≤ 6 + 4a - 5 b && -4 x + 7 y ≤ -1 - 2 a - 7 b && 5 y ≤ 6 - 9 b}, {x, y}]

最小となる点の座標はパラメータの連続関数である：

Wolfram Language code: GraphicsRow[Plot3D[#, {a, -3, 3}, {b, 0, 3}, Axes -> False]& /@ %, ImageSize -> Medium]

パラメトリック二次最適化：

Wolfram Language code: ArgMax[{-(x - 1) ^ 2 - (2y - 1) ^ 2, x + 2y ≤ a + b && 2x - y ≤ a - b + 1 && x - 2y ≤ 2a - b + 1}, {x, y}]

最小となる点の座標はパラメータの連続関数である：

Wolfram Language code: GraphicsRow[Plot3D[#, {a, -3, 3}, {b, 0, 3}, Axes -> False]& /@ %, ImageSize -> Medium]

制約条件なしのパラメトリック多項式の最大化：

Wolfram Language code: ArgMax[-x ^ 4 + a x ^ 2 + b, x]

制約条件付きのパラメトリック多項式の最大化：

Wolfram Language code: ArgMax[{-x ^ 2 - y ^ 2, x ^ 3 + y ^ 2 == a}, {x, y}]

整数上の最適化 (3)

一変数問題：

Wolfram Language code: ArgMax[{x ^ 3 Log[x] - E ^ x, x > 0}, x, Integers]

整数線形計画法：

Wolfram Language code: ArgMax[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}, Integers]

整数上の多項式の最大化：

Wolfram Language code: ArgMax[{-x ^ 2 - x y + 1, x y ≥ 1}, {x, y}, Integers]

領域上の最適化 (6)

領域上で最大化する：

Wolfram Language code: ℛ = Cylinder[{{1, 2, 3}, {3, 2, 1}}, 1];

Wolfram Language code: ArgMax[z, {x, y, z}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[%]}}]

2領域で最大距離を実現する点を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];

Wolfram Language code: ArgMax[(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[Partition[%, 2]]}}]

三角形と楕円が交差する最大のを求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];

Wolfram Language code: ArgMax[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

これをプロットする：

Wolfram Language code:

Graphics[{{StandardBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Thread[{r, x, y} -> %]]

に指定された3点が入る最大のを求める：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];

Wolfram Language code: ArgMax[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, Subscript[ℛ, 3]} /. Thread[{a, b, r} -> %], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]

を使い，が中のベクトルであるように指定する：

Wolfram Language code: ℛ = Sphere[];

Wolfram Language code: ArgMax[x.{1, 2, 3}, x∈ℛ]

最大距離を実現する2領域の点を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];

Wolfram Language code: ArgMax[(x - y).(x - y), {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[%]}}]

オプション (2)

Method (1)

ArgMaxが円筒代数分解を使用するよう指定する：

Wolfram Language code: maxcad = ArgMax[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "CAD"]

ラグランジュ(Lagrange)乗数を使う：

Wolfram Language code: maxlm = ArgMax[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "LagrangeMultipliers"]

デフォルトメソッドを使う：

Wolfram Language code: maxdef = ArgMax[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}]

結果はすべて同等である：

Wolfram Language code: RootReduce[maxcad] === RootReduce[maxlm] === RootReduce[maxdef]

WorkingPrecision (1)

厳密な最大の点を求めるのには時間がかかる：

Wolfram Language code: TimeConstrained[ArgMax[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}], 60]

WorkingPrecision->200とすると，最大値の近似点を求めることができる：

Wolfram Language code:

ArgMax[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}, WorkingPrecision -> 200]//Timing

アプリケーション (15)

基本的な問題 (3)

面積が最大の単位パラメータ長方形の辺の長さを求める：

Wolfram Language code: ArgMax[{x y, 2x + 2y == 1 && x > 0 && y > 0}, {x, y}]

面積が最大の単位パラメータ三角形の辺の長さを求める：

Wolfram Language code:

triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a;
s = 1 / 2(a + b + c);

Wolfram Language code: ArgMax[{Sqrt[s(s - a)(s - b)(s - c)], triangle && a + b + c == 1}, {a, b, c}]

発射体が最高の高さに達する時間を求める：

Wolfram Language code: ArgMax[ {v Sin[α] t - 5 t ^ 2, t ≥ 0 && 0 < Sin[α] ≤ 1 && v > 0}, t]

Wolfram Language code: Refine[%, 0 < Sin[α] ≤ 1 && v > 0]

幾何学的距離 (9)

指定された点 p から最も遠い領域 ℛ 内の点 q はArgMax[{Norm[p-q],q∈ℛ},q]で与えられる．{1,1}から最も遠いDisk[] 内の点を求める：

Wolfram Language code:

p = {1, 1};
ℛ = Disk[];

Wolfram Language code: q = Simplify@ArgMax[Norm[p - {q1, q2}], {q1, q2}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Red, Point[{p, q}]}, {Dashed, Line[{p, q}]}}]

{1,2}から最も遠い，標準的な単位単体Simplex[2]内の点を求める：

Wolfram Language code:

p = {1, 2};
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code: q = Simplify@ArgMax[Norm[p - {q1, q2}], {q1, q2}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Red, Point[{p, q}]}, {Dashed, Line[{p, q}]}}]

{1,1,1}から最も遠い，標準単位球Sphere[]上の点を求める：

Wolfram Language code:

p = {1, 1, 1};
ℛ = Sphere[];

Wolfram Language code: q = Simplify@ArgMax[Norm[p - {q1, q2, q3}], {q1, q2, q3}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], ℛ}, {Red, Point[{p, q}]}, {Dashed, Line[{p, q}]}}]

{-1,1,1}から最も遠い，標準単位単体Simplex[3]内の点を求める：

Wolfram Language code:

p = {-1, 1, 1};
ℛ = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: q = Simplify@ArgMax[Norm[p - {q1, q2, q3}], {q1, q2, q3}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], ℛ}, {Red, Point[{p, q}]}, {Dashed, Line[{p, q}]}}]

領域 ℛ の直径は，ℛ 内の最も遠い点間の距離で与えられる．これは，ArgMax[Norm[p-q],{q∈ℛ,p∈ℛ}]で計算することができる．Circle[]の直径を求める：

Wolfram Language code: ℛ = Circle[];

Wolfram Language code: {pt, qt} = ArgMax[Norm[p - q], {q∈ℛ, p∈ℛ}]

次が直径である：

Wolfram Language code: Norm[pt - qt]//Simplify

これをプロットする：

Wolfram Language code: Graphics[{{ℛ}, {Red, Point[{pt, qt}]}, {Dashed, Line[{pt, qt}]}}]

標準的な単位単体Simplex[2]の直径を求める：

Wolfram Language code: ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code: {pt, qt} = ArgMax[Norm[p - q], {q∈ℛ, p∈ℛ}]

次が直径である：

Wolfram Language code: Norm[pt - qt]

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Red, Point[{pt, qt}]}, {Dashed, Line[{pt, qt}]}}]

標準的な単位立方体Cuboid[]の直径を求める：

Wolfram Language code: ℛ = Cuboid[];

Wolfram Language code: {pt, qt} = ArgMax[Norm[p - q], {q∈ℛ, p∈ℛ}]

次が直径である：

Wolfram Language code: Norm[pt - qt]//Simplify

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], ℛ}, {Red, Point[{pt, qt}]}, {Dashed, Line[{pt, qt}]}}]

最も遠い点 p∈ と q∈ はArgMax[Norm[p-q],{p∈,q∈}]で求めることができる．Disk[{0,0}]およびRectangle[{3,3}]内の最も遠い点を求める：

Wolfram Language code: 𝒫 = Disk[{0, 0}]; 𝒬 = Rectangle[{3, 3}];

Wolfram Language code: {pt, qt} = Simplify@ArgMax[Norm[p - q], {p∈𝒫, q∈𝒬}]

最も遠い距離：

Wolfram Language code: Norm[pt - qt]//Simplify

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], 𝒫, 𝒬}, {Red, Point[{pt, qt}]}, {Dashed, Line[{pt, qt}]}}]

Line[{{0,0,0},{1,1,1}}]およびBall[{5,5,0},1]内の最も遠い点を求める：

Wolfram Language code: 𝒫 = Line[{{0, 0, 0}, {1, 1, 1}}]; 𝒬 = Ball[{5, 5, 0}, 1];

Wolfram Language code: {pt, qt} = Simplify@ArgMax[Norm[p - q], {p∈𝒫, q∈𝒬}]

最も遠い距離：

Wolfram Language code: Norm[pt - qt]//Simplify

これをプロットする：

Wolfram Language code: Graphics3D[{{𝒫, {Opacity[0.5], 𝒬}}, {Red, Point[{pt, qt}]}, {Dashed, Line[{pt, qt}]}}]

幾何学的中心 (3)

ℛ⊆ⁿが全次元の領域であれば，Chebyshev Center は-SignedRegionDistance[ℛ,p]を最大にする，つまり，補領域までの距離である点 p∈ℛ である．Disk[]のChebyshev Centerを求める：

Wolfram Language code: ℛ = Disk[];

Wolfram Language code: p = ArgMax[-SignedRegionDistance[ℛ, {p1, p2}], {p1, p2}∈ℛ]

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Red, Point[p]}}]

Rectangle[]についてのChebyshev Centerを求める：

Wolfram Language code: ℛ = Rectangle[];

Wolfram Language code: p = ArgMax[-SignedRegionDistance[ℛ, {p1, p2}], {p1, p2}∈ℛ]

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], ℛ}, {Red, Point[p]}}]

不等式 ℛ=ImplicitRegion[f₁[x]≥0∧⋯∧f_m[x]≥0,x]で定義される領域の「解析の中心」はArgMax[{Log[f₁[x]⋯ f_m[x]],x∈ℛ},x]で与えられる．Triangle[{{0,0},{1,0},{0,1}}]の解析の中心を求める：

Wolfram Language code: RegionMember[Triangle[{{0, 0}, {1, 0}, {0, 1}}], {x, y}]

上記の条件から不等私意表現が得られる：

Wolfram Language code: {f1, f2, f3} = {x, y, 1 - x - y};

解析的中心：

Wolfram Language code: c = ArgMax[Log[f1 f2 f3], {x, y}∈Triangle[{{0, 0}, {1, 0}, {0, 1}}]]

これをプロットする：

Wolfram Language code: Graphics[{{StandardBlue, EdgeForm[Gray], Triangle[{{0, 0}, {1, 0}, {0, 1}}]}, {Red, Point[c]}}]

Cylinder[]についての解析的中心を求める：

Wolfram Language code: RegionMember[Cylinder[], {x, y, z}]

これで不等式表現が得られる：

Wolfram Language code: {f1, f2, f3} = {(1 + z) / 2, 1 - (1 + z) / 2, 1 - (x^2 + y^2)};

解析的中心も得られる：

Wolfram Language code: c = ArgMax[Log[f1 f2 f3], {x, y, z}∈Cylinder[]]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.3], Cylinder[]}, {Red, Point[c]}}]

特性と関係 (4)

Maximizeは最大値と最大になる点の両方の値を与える：

Wolfram Language code: Maximize[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

ArgMaxは厳密に最大値となる点を与える：

Wolfram Language code: f = Expand[-Product[(x - i)(x - 100 - i), {i, 5}]];

Wolfram Language code: ArgMax[f, x]

Wolfram Language code: Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], Green, Point[{%, f /. x -> %}]}]

NArgMaxは数値的に最大値となる点を求めようとするが，極大値となる点を求めることがある：

Wolfram Language code: NArgMax[f, x]

Wolfram Language code: Plot[f, {x, 0.5, 5.5}, Epilog -> {PointSize[Medium], Red, Point[{%, f /. x -> %}]}]

FindArgMaxは始点によって極大値となる点を求める：

Wolfram Language code: FindArgMax[f, {x, #}]& /@ {1, 50}

Wolfram Language code:

Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], {Red, Point[{%[[1, 1]], f /. x -> %[[1, 1]]}]}, {Green, Point[{%[[2, 1]], f /. x -> %[[2, 1]]}]}}]

メッセージが出ない限り，最大となる点は制約条件を満たしている：

Wolfram Language code: m = ArgMin[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

Wolfram Language code: x ^ 2 + y ^ 2 ≤ 1 /. Thread[{x, y} -> m]

与えられた点は点{2,}からの距離を最大にする：

Wolfram Language code:

RegionPlot[x ^ 2 + y ^ 2 ≤ 1, {x, -1.2, 2.2}, {y, -1.2, 2.2}, Epilog -> {PointSize[Medium], {Red, Point[m]}, {Green, Point[{2, 3 / 2}]}}]

最大値に達しない場合，ArgMaxは境界上の点を与えることがある：

Wolfram Language code: ArgMax[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 < 1}, {x, y}]

ここでは，y が無限大に向かうときに目的関数が最大値に向かっている：

Wolfram Language code: ArgMax[{1 - x, x y == 1 && x > 0}, {x, y}]

ArgMaxは線形最適化問題を解くことができる：

Wolfram Language code: res = ArgMax[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

LinearOptimizationは引数の符号を負にすることで与えられた同じ問題を解くことができる：

Wolfram Language code:

LinearOptimization[-(2x + 3y - z), {1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2
	 && x - y - z == 3}, {x, y, z}]

考えられる問題 (2)

最大値には達しないかもしれない：

Wolfram Language code: ArgMax[{1 - x ^ 2, x y ≥ 1}, {x, y}]

目的関数は有界ではないかもしれない：

Wolfram Language code: ArgMax[{x, x y ≤ 1}, {x, y}]

制約条件を満足する点が存在しないかもしれない：

Wolfram Language code: ArgMax[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]

ArgMaxは入力中に存在するすべての関数が実数値を持つことを必要とする：

Wolfram Language code: ArgMax[{-x - y, Sqrt[x] - Sqrt[y] == 0}, {x, y}]

方程式は満足するが平方根が実数とはならない値は認められない：

Wolfram Language code: {Sqrt[x] - Sqrt[y] == 0, Sqrt[x], Sqrt[y]} /. {x -> -1, y -> -1}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArgMax

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

Method (1)

WorkingPrecision (1)

アプリケーション (15)

基本的な問題 (3)

幾何学的距離 (9)

幾何学的中心 (3)

特性と関係 (4)

考えられる問題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArgMax

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

Method (1)

WorkingPrecision (1)

アプリケーション (15)

基本的な問題 (3)

幾何学的距離 (9)

幾何学的中心 (3)

特性と関係 (4)

考えられる問題 (2)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX