WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioSpectralTransformation[f,audio]

時間周波数変換 f を短時間フーリエ(Fourier)変換に適用し，変更を加えた audio を返す．

AudioSpectralTransformation[f,video]

video の最初の音声トラックを変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DataRange  
PartitionGranularity  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AudioSpectralTransformation

AudioSpectralTransformation[f,audio]

時間周波数変換 f を短時間フーリエ(Fourier)変換に適用し，変更を加えた audio を返す．

AudioSpectralTransformation[f,video]

video の最初の音声トラックを変換する．

詳細とオプション

  • 任意の時間周波数変換を音声信号の短時間フーリエ変換に適用すると，音声がおもしろくまた効果的に変化し，創造的に使うことができる．
  • AudioSpectralTransformationは音声の短時間フーリエ変換を計算し，位置 f[{time,freq}]のすべての値を{time,freq}にマップし，重畳加算法を用いて逆関数を計算する．
  • 次は使用可能なオプションである．
  • DataRange Automatic時間と周波数について仮定する範囲
    Padding0使用する充填法
    PartitionGranularity Automatic音声分割指定
    ResamplingAutomaticリサンプルの方法
  • デフォルトで，DataRange->{{0,dur},{0,sr/2}}が使われる．ただし，dur と sr は audio の持続時間とサンプルレートである．

例題

すべて開く すべて閉じる

例  (1)

信号のスペクトログラムを修正する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\);
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralTransformation[# / 2&, a]
Wolfram Language code: Spectrogram[%]

スコープ  (4)

時間軸に沿ってのみ変換する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency}; AudioSpectralTransformation[f, a]

周波数軸に沿ってのみ変換する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency * .5} AudioSpectralTransformation[f, a]

時間と周波数の両軸に沿って変換する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: dur = QuantityMagnitude[Duration[a]];f[{time_, frequency_}] := {Tanh[time / dur]dur + frequency / 10000, frequency - time ^ 3}
Wolfram Language code: AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%]

動画の音声トラックを処理する：

Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency}; AudioSpectralTransformation[f, \!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]

オプション  (2)

DataRange  (1)

デフォルトで，データ範囲は{{0,duration},{0,samplerate/2}}である：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralTransformation[# - {1, 0}&, a]
Wolfram Language code: Spectrogram[%]

関数に対して別のデータ範囲を指定する：

Wolfram Language code: AudioSpectralTransformation[# - {.5, 0}&, a, DataRange -> {{0, 1}, {0, 11025}}]
Wolfram Language code: Spectrogram[%]

PartitionGranularity  (1)

PartitionGranularityオプションを使って結果の質を変える：

Wolfram Language code: a = ExampleData[{"Sound", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[x_] := x / 2; AudioSpectralTransformation[f, a]
Wolfram Language code: AudioSpectralTransformation[f, a, PartitionGranularity -> {.05, .008, BlackmanWindow}]

アプリケーション  (5)

時間を圧縮し，時間依存の周波数引き伸ばしを行う：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: f[{time_, frequency_}] := {time * 1.2, frequency + time * frequency ^ .5}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

スペクトログラムに曲線歪みを適用する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[pt_] := With[{s = {.5, .1}}, Module[{r, a, an}, r = Norm[pt - s];a = ArcTan@@(pt - s);an = a + 2r; s + r{Cos[an], Sin[an]}]] AudioSpectralTransformation[f, a, DataRange -> {{0, 1}, {0, 1}}]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

時間と周波数に両方についてスペクトログラムを量子化する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {.05Floor[time / .05], 100Floor[frequency / 100] + 1}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

時間依存の周波数シフトを行う：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency + 400Sin[2 Pi time]}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

スペクトログラムに魚眼変換を適用する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[pt_] := With[{s = {2, 10000}}, Module[{r, a}, r = Norm[pt - s]^2 / Norm[s];a = ArcTan@@(pt - s); s + r{Cos[a], Sin[a]}]]; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

特性と関係  (4)

一致演算を行っても入力のサンプル値は返されない：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralTransformation[Identity, a] == a

恒等写像の場合でさえも，短時間フーリエ変換が行われ次に重畳加算操作が行われる．結果は入力と若干異なるだけである：

Wolfram Language code: {Mean[#], StandardDeviation[#]}&[AudioSpectralTransformation[Identity, a] - a]

おおまかなピッチシフト効果を出す：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency * .5} AudioSpectralTransformation[f, a]

AudioPitchShiftと比較する：

Wolfram Language code: AudioPitchShift[a, 2]

大まかな時間引き伸ばし効果を出す：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency} AudioSpectralTransformation[f, a]

AudioTimeStretchと比較する：

Wolfram Language code: AudioTimeStretch[a, 2]

大まかな周波数シフト効果を出す：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, 200 + frequency} AudioSpectralTransformation[f, a]

AudioFrequencyShiftと比較する：

Wolfram Language code: AudioFrequencyShift[a, 200]
Wolfram Research (2017), AudioSpectralTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html （2024年に更新）.

テキスト

Wolfram Research (2017), AudioSpectralTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html （2024年に更新）.

CMS

Wolfram Language. 2017. "AudioSpectralTransformation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html.

APA

Wolfram Language. (2017). AudioSpectralTransformation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html

BibTeX

@misc{reference.wolfram_2026_audiospectraltransformation, author="Wolfram Research", title="{AudioSpectralTransformation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiospectraltransformation, organization={Wolfram Research}, title={AudioSpectralTransformation}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html}, note=[Accessed: 12-August-2026]}