WOLFRAM

Wolfram 语言与系统参考资料中心

AudioSpectralTransformation[f,audio]

通过对音频信号的短时傅立叶变换应用时间-频率变换 f 给出修改过的 audio 版本.

AudioSpectralTransformation[f,video]

变换 video 中的第一个音轨.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
DataRange  
PartitionGranularity  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

AudioSpectralTransformation

AudioSpectralTransformation[f,audio]

通过对音频信号的短时傅立叶变换应用时间-频率变换 f 给出修改过的 audio 版本.

AudioSpectralTransformation[f,video]

变换 video 中的第一个音轨.

更多信息和选项

  • 对音频信号的短时傅立叶变换应用任意时间-频率变换可产生非常有趣的音频特效，适用于创新应用.
  • AudioSpectralTransformation 计算音频信号的短时傅立叶变换，把位置 f[{time,freq}] 处的每个值映射到 {time,freq}，并用重叠相加法计算逆变换.
  • 可给出下列选项：
  • DataRange Automatic假定的时间和频率的范围
    Padding0使用的填充方案
    PartitionGranularity Automatic音频划分指定
    ResamplingAutomatic重新采样的方法
  • 缺省情况下，使用 DataRange->{{0,dur},{0,sr/2}}，其中 dur 和 sr 为 audio 的时长和采样率.

范例

打开所有单元 关闭所有单元

基本范例  (1)

修改信号的频谱：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\);
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralTransformation[# / 2&, a]
Wolfram Language code: Spectrogram[%]

范围  (4)

只沿着时间轴变换：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency}; AudioSpectralTransformation[f, a]

只沿着频率轴变换：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency * .5} AudioSpectralTransformation[f, a]

沿着时间轴和频率轴变换：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: dur = QuantityMagnitude[Duration[a]];f[{time_, frequency_}] := {Tanh[time / dur]dur + frequency / 10000, frequency - time ^ 3}
Wolfram Language code: AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%]

处理视频的音轨：

Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency}; AudioSpectralTransformation[f, \!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]

选项  (2)

DataRange  (1)

默认情况下，数据范围是 {{0,duration},{0,samplerate/2}}：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralTransformation[# - {1, 0}&, a]
Wolfram Language code: Spectrogram[%]

为函数指定不同的数据范围：

Wolfram Language code: AudioSpectralTransformation[# - {.5, 0}&, a, DataRange -> {{0, 1}, {0, 11025}}]
Wolfram Language code: Spectrogram[%]

PartitionGranularity  (1)

使用 PartitionGranularity 选项改变结果的质量：

Wolfram Language code: a = ExampleData[{"Sound", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[x_] := x / 2; AudioSpectralTransformation[f, a]
Wolfram Language code: AudioSpectralTransformation[f, a, PartitionGranularity -> {.05, .008, BlackmanWindow}]

应用  (5)

压缩时间并进行时间相关的频率拉伸：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: f[{time_, frequency_}] := {time * 1.2, frequency + time * frequency ^ .5}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

对谱图应用曲线变形：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[pt_] := With[{s = {.5, .1}}, Module[{r, a, an}, r = Norm[pt - s];a = ArcTan@@(pt - s);an = a + 2r; s + r{Cos[an], Sin[an]}]] AudioSpectralTransformation[f, a, DataRange -> {{0, 1}, {0, 1}}]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

量化频率和时间频谱：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {.05Floor[time / .05], 100Floor[frequency / 100] + 1}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

创建时间相关的频移：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency + 400Sin[2 Pi time]}; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

对频谱图应用鱼眼变换：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[pt_] := With[{s = {2, 10000}}, Module[{r, a}, r = Norm[pt - s]^2 / Norm[s];a = ArcTan@@(pt - s); s + r{Cos[a], Sin[a]}]]; AudioSpectralTransformation[f, a]
Wolfram Language code: Spectrogram[%, 1024, 2048, ImageSize -> Medium]

属性和关系  (4)

执行恒等不返回输入采样值：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralTransformation[Identity, a] == a

即使在恒等情况下，也执行短时傅立叶变换，然后进行重叠相加操作. 结果只与输入有微小的差异：

Wolfram Language code: {Mean[#], StandardDeviation[#]}&[AudioSpectralTransformation[Identity, a] - a]

创建一个粗略的变调效果：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, frequency * .5} AudioSpectralTransformation[f, a]

比较 AudioPitchShift：

Wolfram Language code: AudioPitchShift[a, 2]

创建一个粗略的时间延伸效果：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time * .5, frequency} AudioSpectralTransformation[f, a]

比较 AudioTimeStretch：

Wolfram Language code: AudioTimeStretch[a, 2]

创建一个粗略的频移效果：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[{time_, frequency_}] := {time, 200 + frequency} AudioSpectralTransformation[f, a]

比较 AudioFrequencyShift：

Wolfram Language code: AudioFrequencyShift[a, 200]
Wolfram Research (2017)，AudioSpectralTransformation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html （更新于 2024 年）.

文本

Wolfram Research (2017)，AudioSpectralTransformation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html （更新于 2024 年）.

CMS

Wolfram 语言. 2017. "AudioSpectralTransformation." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html.

APA

Wolfram 语言. (2017). AudioSpectralTransformation. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html 年

BibTeX

@misc{reference.wolfram_2026_audiospectraltransformation, author="Wolfram Research", title="{AudioSpectralTransformation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiospectraltransformation, organization={Wolfram Research}, title={AudioSpectralTransformation}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioSpectralTransformation.html}, note=[Accessed: 10-August-2026]}