WOLFRAM

Wolfram 语言与系统参考资料中心

BatchNormalizationLayer[]

表示通过学习数据均值和方差可使输入数据归一化的可训练网层.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
Ports  
Parameters  
"Biases"  
"Scaling"  
选项  
"Epsilon"  
"Momentum"  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

BatchNormalizationLayer

BatchNormalizationLayer[]

表示通过学习数据均值和方差可使输入数据归一化的可训练网层.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建一个 BatchNormalizationLayer：

Wolfram Language code: BatchNormalizationLayer[]

创建一个接受向量并返回向量的已初始化的 BatchNormalizationLayer：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Input" -> 3]

把该层应用于输入向量：

Wolfram Language code: batchnorm[{1, 2, 3}]

范围  (4)

Ports  (2)

创建一个接受 3 阶数组并返回 3 阶数组的已初始化的 BatchNormalizationLayer：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Input" -> {2, 3, 3}]
Wolfram Language code: batchnorm[RandomReal[1, {2, 3, 3}]]//Normal//MatrixForm

创建一个接受向量并返回向量的已初始化的 BatchNormalizationLayer：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Input" -> 3]

把该层应用于一批输入向量中：

Wolfram Language code: batchnorm[{{1, 2, 3}, {4, 0.2, 3}}]

使用 NetEvaluationMode 来使用 BatchNormalizationLayer 的训练行为：

Wolfram Language code: batchnorm[{{1, 2, 3}, {4, 0.2, 3}}, NetEvaluationMode -> "Train"]

Parameters  (2)

"Biases"  (1)

创建一个带有 "Biases" 参数初始值的 BatchNormalizationLayer：

Wolfram Language code: batchnorm = BatchNormalizationLayer["Biases" -> {-1, 3.4}]

提取 "Biases" 参数：

Wolfram Language code: NetExtract[batchnorm, "Biases"]

由 NetInitialize 选择的 "Biases" 默认值是零向量：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Input" -> 2]; NetExtract[batchnorm, "Biases"]

"Scaling"  (1)

创建一个已初始化的 BatchNormalizationLayer，其中设 "Scaling" 参数为零，"Biases" 参数设为自定义的值：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Scaling" -> {0, 0, 0}, "Biases" -> {1.3, -22.1, 1.2}]

把该层应用于任何输入，返回 "Biases" 参数的值：

Wolfram Language code: batchnorm[{1, 2, 3}]
Wolfram Language code: batchnorm[{-3.4, 2.3, 100}]

NetInitialize 选择的 "Scaling" 默认值是 1 的向量：

Wolfram Language code: batchnorm = NetInitialize@BatchNormalizationLayer["Input" -> 2]; NetExtract[batchnorm, "Scaling"]

选项  (2)

"Epsilon"  (1)

创建一个带有明确指定 "Epsilon" 参数的 BatchNormalizationLayer：

Wolfram Language code: batchnorm = BatchNormalizationLayer["Epsilon" -> 0.1]

提取 "Epsilon" 参数：

Wolfram Language code: NetExtract[batchnorm, "Epsilon"]

"Momentum"  (1)

创建一个 BatchNormalizationLayer，其中明确指定 "Momentum" 参数：

Wolfram Language code: batchnorm = BatchNormalizationLayer["Momentum" -> 0.1]

提取 "Momentum" 参数：

Wolfram Language code: NetExtract[batchnorm, "Momentum"]

应用  (1)

BatchNormalizationLayer 通常被插入在 ConvolutionLayer 和它的激活函数之间，以稳定并加速训练：

Wolfram Language code: NetChain[{ConvolutionLayer[3, {3, 3}], BatchNormalizationLayer["Input" -> {3, 28, 28}], ElementwiseLayer[Ramp]}]

属性和关系  (1)

在一般的运算中，BatchNormalizationLayer 计算以下函数：

Wolfram Language code: batchNormFunction = Function[Block[{sd = Sqrt[#MovingVariance + #Epsilon]}, (#2 * #Scaling / sd ) + (#Biases - (#Scaling * #MovingMean) / sd)]];

在含有一个通道的向量实例上运行 BatchNormalizationLayer：

Wolfram Language code: params = <|"Scaling" -> {3}, "Biases" -> {2}, "MovingMean" -> {1}, "MovingVariance" -> {2}, "Epsilon" -> 0.001|>; layer = BatchNormalizationLayer@@Normal[params]
Wolfram Language code: layer[{5}]//Normal

手动计算，得到同样的结果：

Wolfram Language code: batchNormFunction[params, {5}]

可能存在的问题  (3)

指定 "MovingVariance" 参数的负值，在计算时会导致数值错误：

Wolfram Language code: batchnorm = NetInitialize[BatchNormalizationLayer["Input" -> {1, 2, 2}, "MovingVariance" -> {-2}]]
Wolfram Language code: batchnorm[RandomReal[1, {1, 2, 2}]]

BatchNormalizationLayer 不可以被初始化，直到知道其所有的输入和输出维数：

Wolfram Language code: NetInitialize@BatchNormalizationLayer[]
Wolfram Language code: NetInitialize@BatchNormalizationLayer["Input" -> 3]

不能共享 BatchNormalizationLayer 的 "MovingMean" 和 "MovingVariance" 数组：

Wolfram Language code: BatchNormalizationLayer["MovingMean" -> NetArray["MovingMean"]]

创建具有共享数组的 BatchNormalizationLayer：

Wolfram Language code: sharedBatchNorm = NetInsertSharedArrays[BatchNormalizationLayer[]]

在一些数据上训练：

Wolfram Language code: net = NetTrain[NetChain[{2, sharedBatchNorm, 2, sharedBatchNorm, 2}], {{0, 1} -> {1, 0}, {1, 0} -> {0, 1}}]

提取训练过的批量归一化层：

Wolfram Language code: {batchnorm1, batchnorm2} = NetExtract[net, {{2}, {4}}]

"Scaling" 和 "Biases" 数组被共享，但 "MovingMean" 或 "MovingVariance" 数组没有：

Wolfram Language code: Normal /@ Information[batchnorm1, "Arrays"]
Wolfram Language code: Normal /@ Information[batchnorm2, "Arrays"]
Wolfram Research (2016)，BatchNormalizationLayer，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html （更新于 2020 年）.

文本

Wolfram Research (2016)，BatchNormalizationLayer，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html （更新于 2020 年）.

CMS

Wolfram 语言. 2016. "BatchNormalizationLayer." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html.

APA

Wolfram 语言. (2016). BatchNormalizationLayer. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html 年

BibTeX

@misc{reference.wolfram_2026_batchnormalizationlayer, author="Wolfram Research", title="{BatchNormalizationLayer}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_batchnormalizationlayer, organization={Wolfram Research}, title={BatchNormalizationLayer}, year={2020}, url={https://reference.wolfram.com/language/ref/BatchNormalizationLayer.html}, note=[Accessed: 17-August-2026]}