WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BetweennessCentrality[g]

グラフ g 中の頂点の媒介中心性のリストを与える．

BetweennessCentrality[{vw,…}]

規則 vw を使ってグラフ g を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BetweennessCentrality

BetweennessCentrality[g]

グラフ g 中の頂点の媒介中心性のリストを与える．

BetweennessCentrality[{vw,…}]

規則 vw を使ってグラフ g を指定する．

詳細

  • BetweennessCentralityは他の多くの頂点ペアの最短路上にある頂点に高い中心性を与える．
  • 連結グラフの頂点 のBetweennessCentralityは で与えられる．は から までの最短経路の数，は を通る から までの最短経路の数である．
  • から までの経路が存在しない場合の比 は0であるとみなされる．
  • BetweennessCentralityは，無向グラフ，有向グラフ，多重グラフ，混合グラフに使うことができる．

例題

すべて開く すべて閉じる

例  (2)

媒介中心性を計算する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: BetweennessCentrality[g]

ハイライトする：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

頂点に順位を付ける．順位が最高の頂点は他の頂点ペアの多くの最短経路上にある：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Sort[BetweennessCentrality[g], Greater]
Wolfram Language code: Part[VertexList[g], Ordering[BetweennessCentrality[g], All, Greater]]

スコープ  (6)

BetweennessCentralityは無向グラフに使うことができる：

Wolfram Language code: BetweennessCentrality[[image]]

有向グラフ：

Wolfram Language code: BetweennessCentrality[[image]]

多重グラフ：

Wolfram Language code: BetweennessCentrality[[image]]

混合グラフ：

Wolfram Language code: BetweennessCentrality[[image]]

規則を使ってグラフを指定する：

Wolfram Language code: BetweennessCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

BetweennessCentralityは大きいグラフに使うことができる：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: BetweennessCentrality[g]//Short//Timing

アプリケーション  (6)

頂点を他の頂点との間の経路の割合で順位付けする：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], BetweennessCentrality[g]}, Last]//Reverse

CycleGraphの媒介中心性をハイライトする：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

ネットワークの中で簡単に情報を伝えなかったり捩じ曲げたりするメンバーを求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ZacharyKarateClub"}];
Wolfram Language code: Part[VertexList[g], Ordering[BetweennessCentrality[g], -5]]

ネットワークをハイライトする：

Wolfram Language code: HighlightGraph[g, %]

合衆国のWestern States Power Gridの位相を表す送電網．故障するとグリッドに最も大きい影響を与える臨界ノードを特定する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];
Wolfram Language code: c = BetweennessCentrality[g];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

この臨界ノードの近傍：

Wolfram Language code: NeighborhoodGraph[g, %, 3, GraphLayout -> "SpringEmbedding"]

有料道路のネットワークでもっともたくさん集金する料金所を求める：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = BetweennessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

頂点数が のグラフの場合，最も中心的な頂点と他のすべての頂点の間の媒介中心性の差の最大総和はである：

Wolfram Language code: n = 10; g = StarGraph[n]; c = BetweennessCentrality[g];
Wolfram Language code: {Total[Max[c] - c], (n - 1)((n - 1)(n - 2)) / 2}

最も中心的な頂点が他の頂点に比べてどの程度中心にあるかを測定する：

Wolfram Language code: betweenness[g_] := With[{c = BetweennessCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1) ^ 2(n - 2) / 2)]]

ソーシャルネットワークの集中化：

Wolfram Language code: betweenness[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]
Wolfram Language code: betweenness[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

特性と関係  (3)

無向グラフの媒介中心性は各成分の中心性と等しい：

Wolfram Language code: g = [image];
Wolfram Language code: BetweennessCentrality[g]

各成分の中心性を計算しても同じ結果が得られる：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]
Wolfram Language code: {BetweennessCentrality[g1], BetweennessCentrality[g2]}
Wolfram Language code: Join@@%

孤立頂点の媒介中心性は0であるとみなされる：

Wolfram Language code: BetweennessCentrality[[image]]

VertexIndexを使って特定の頂点の中心性を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: BetweennessCentrality[g][[VertexIndex[g, "Anna"]]]
Wolfram Research (2010), BetweennessCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetweennessCentrality.html （2015年に更新）.

テキスト

Wolfram Research (2010), BetweennessCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetweennessCentrality.html （2015年に更新）.

CMS

Wolfram Language. 2010. "BetweennessCentrality." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/BetweennessCentrality.html.

APA

Wolfram Language. (2010). BetweennessCentrality. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BetweennessCentrality.html

BibTeX

@misc{reference.wolfram_2026_betweennesscentrality, author="Wolfram Research", title="{BetweennessCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/BetweennessCentrality.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_betweennesscentrality, organization={Wolfram Research}, title={BetweennessCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/BetweennessCentrality.html}, note=[Accessed: 17-August-2026]}