WOLFRAM

Wolfram 语言与系统参考资料中心

BetweennessCentrality[g]

给出图 g 中顶点的中介中心度的一个列表.

BetweennessCentrality[{vw,…}]

使用 vw 规则来指定图 g.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BetweennessCentrality

BetweennessCentrality[g]

给出图 g 中顶点的中介中心度的一个列表.

BetweennessCentrality[{vw,…}]

使用 vw 规则来指定图 g.

更多信息

  • BetweennessCentrality 对位于其他顶点对的最短路径上的顶点，给出高中心度.
  • 对于连通图中的顶点 ，BetweennessCentrality 由 给出，其中 是从 到 的最短路径数目，而 是从 经过 到 的最短路径的数目.
  • 当从 到 没有路径时，比值 为零.
  • BetweennessCentrality 适用于无向图、有向图、多重图和混合图.

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算中介中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: BetweennessCentrality[g]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

对顶点排名。排名最高的顶点在许多其他顶点对的最短路径上：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Sort[BetweennessCentrality[g], Greater]
Wolfram Language code: Part[VertexList[g], Ordering[BetweennessCentrality[g], All, Greater]]

范围  (6)

BetweennessCentrality 适用于无向图：

Wolfram Language code: BetweennessCentrality[[image]]

有向图：

Wolfram Language code: BetweennessCentrality[[image]]

多重图：

Wolfram Language code: BetweennessCentrality[[image]]

混合图：

Wolfram Language code: BetweennessCentrality[[image]]

使用规则来指定图：

Wolfram Language code: BetweennessCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

BetweennessCentrality 适用于大型图：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: BetweennessCentrality[g]//Short//Timing

应用  (6)

按照与其他顶点之间的最短路径的比例，对顶点进行排名：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], BetweennessCentrality[g]}, Last]//Reverse

突出显示 CycleGraph 的中介中心度：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = BetweennessCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

找到网络传输中可以很容易地隐瞒或歪曲信息的成员：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ZacharyKarateClub"}];
Wolfram Language code: Part[VertexList[g], Ordering[BetweennessCentrality[g], -5]]

突出显示网络：

Wolfram Language code: HighlightGraph[g, %]

一个代表美国的西部各州电网拓扑结构的电网. 确定故障将最大影响到电网的关键节点：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];
Wolfram Language code: c = BetweennessCentrality[g];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

关键节点的附近：

Wolfram Language code: NeighborhoodGraph[g, %, 3, GraphLayout -> "SpringEmbedding"]

在收费公路网络中，找到赚钱最多的收费站：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = BetweennessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

对于具有 个顶点的图，在最中心的顶点与其他顶点之间中介中心度之差的最大和为 ：

Wolfram Language code: n = 10; g = StarGraph[n]; c = BetweennessCentrality[g];
Wolfram Language code: {Total[Max[c] - c], (n - 1)((n - 1)(n - 2)) / 2}

测量与其他顶点相比，最中心的顶点的中心程度：

Wolfram Language code: betweenness[g_] := With[{c = BetweennessCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1) ^ 2(n - 2) / 2)]]

社交网络的集中化：

Wolfram Language code: betweenness[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]
Wolfram Language code: betweenness[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

属性和关系  (3)

无向图的中介中心度与各个分量的中心度等价：

Wolfram Language code: g = [image];
Wolfram Language code: BetweennessCentrality[g]

计算每个分量的中心度得到相同的结果：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]
Wolfram Language code: {BetweennessCentrality[g1], BetweennessCentrality[g2]}
Wolfram Language code: Join@@%

孤立顶点的中介中心度是零：

Wolfram Language code: BetweennessCentrality[[image]]

使用 VertexIndex 获得具体顶点的中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: BetweennessCentrality[g][[VertexIndex[g, "Anna"]]]
Wolfram Research (2010)，BetweennessCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetweennessCentrality.html （更新于 2015 年）.

文本

Wolfram Research (2010)，BetweennessCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetweennessCentrality.html （更新于 2015 年）.

CMS

Wolfram 语言. 2010. "BetweennessCentrality." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/BetweennessCentrality.html.

APA

Wolfram 语言. (2010). BetweennessCentrality. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BetweennessCentrality.html 年

BibTeX

@misc{reference.wolfram_2026_betweennesscentrality, author="Wolfram Research", title="{BetweennessCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/BetweennessCentrality.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_betweennesscentrality, organization={Wolfram Research}, title={BetweennessCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/BetweennessCentrality.html}, note=[Accessed: 17-August-2026]}