WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BinCounts[data]

値が連続する整数ビンにある data の要素数を数える．

BinCounts[data,binspec]

値が binspec で指定された連続するビンにある data の要素数を数える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
単位があるデータ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

BinCounts

BinCounts[data]

値が連続する整数ビンにある data の要素数を数える．

BinCounts[data,binspec]

値が binspec で指定された連続するビンにある data の要素数を数える．

詳細

  • BinCountsは，値が実数に対応しない要素を除去する．
  • 次のビン幅指定 binspec を使うことができる．
  • dx幅 dx のビン »
    {xmin,xmax,dx}xminから xmaxまでの幅 dx のビン »
    {{b1,b2,…}}区間[b1,b2), [b2,b3), … »
    xbins,ybins,…{{x1,y1,…},{x2,y2, …},…}と理解される多変量 data についてのビン指定 »
  • BinCounts[data,dx]は，ビンの境界が dx の整数倍であり，最初のビンがCeiling[Min[data]-dx,dx]で始まり最後のビンがFloor[Max[data]+dx,dx]で終るとする．
  • BinCounts[data]はBinCounts[data,1]に等しい．
  • BinCounts[data,{xmin,xmax,dx}]の要素は，その値が を満足する場合はビン i で数えられる．
  • BinCounts[data,{xmin,xmax}]はBinCounts[data,{xmin,xmax,1}]に等しい．
  • BinCounts[data,{{b1,b2,…}}]では，値が を満足するとき要素はビン i で数えられる．
  • BinCounts[data,{{b1,b2,…}}]の形のとき，それぞれの末尾の biは-Infinityと+Infinityでもよい．
  • biは，増加列を形成しない場合は自動的にBinCountsによってソートされる．
  • data が長さ n の部分リストからなる場合は n ビン指定が与えられなければならず，BinCounts[data,…]は深さ n の配列を返す．
  • data は，以下の形式と解釈を持つことができる．
  • {x1,x2,…}実数または数量のリスト »
    {{x1,y1,…},{x2,y2,…},…}同じ次元のベクトルのリスト »
    SparseArrayNormal[data]と等価の配列 »
    QuantityArray列の互換の数量の配列 »
    TimeSeries, TemporalData,…値のベクトルまたは配列（タイムスタンプは無視される） »

例題

すべて開く すべて閉じる

例  (3)

指定された幅のビン内の要素の数を数える：

Wolfram Language code: BinCounts[{1, 3, 2, 1, 4, 5, 6, 2}, 2]

0から10までの幅1のビン中の要素数を数える：

Wolfram Language code: BinCounts[{1, 3, 2, 1, 4, 5, 6, 2}, {0, 10, 1}]

連続する範囲内の要素数を数える：

Wolfram Language code: BinCounts[{1, 3, 2, 1, 4, 5, 6, 2}, {{-Infinity, 2, 5, 7, Infinity}}]

スコープ  (11)

基本的な用法  (8)

3と5を法とする平方を二次元の単位ビンで数える：

Wolfram Language code: data = Table[Mod[i ^ 2, {3, 5}], {i, 100}]; Dimensions[data]
Wolfram Language code: BinCounts[data, 1, 1]

どちらの次元も幅0.25のビンでランダムなペアを数える：

Wolfram Language code: data = RandomReal[{-1, 1}, {1000, 2}]; Dimensions[data]
Wolfram Language code: BinCounts[data, {-1, 1, .25}, {-1, 1, .25}]

範囲内で複数次元のデータを数える：

Wolfram Language code: data = RandomReal[{-1, 1}, {1000, 2}];
Wolfram Language code: BinCounts[data, {{-2, .3, 2}}, {{-1, -.4, .2, 1}}]

任意次元のデータを数える：

Wolfram Language code: BinCounts[RandomReal[{-1, 1}, {1000, 5}]]

実数ではない値を無視してビンデータを数える：

Wolfram Language code: BinCounts[{1.5, 3, a, 2.5, 1, I}, 2]

任意精度のビンデータを数える：

Wolfram Language code: BinCounts[{1.5, 3, N[3, 20], 2.5, 1, E}, 2]

SparseArrayデータは密な配列と同じように使うことができる：

Wolfram Language code: data = SparseArray[{{1, 1} -> 5, {3, 2} -> 4}, {100, 2}]
Wolfram Language code: BinCounts[data]
Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j == i + 1 :> i - 1}, {100, 10}, 3]
Wolfram Language code: BinCounts[sp]

時系列データの値を数える：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-0.8514215942160073, 0.498847153572056, -0.5117595526567502, -0.1541269987967291, 0.21199829846035145, 0.7834143496676975, -0.16460155429334833, 0.8166857502105551, -0.662728145444706, -0.9440223497598601, 0.34 ... -0.3857042044709651}}, {TemporalData`DateSpecification[{2014, 2, 2, 0, 0, 0.}, {2014, 6, 1, 0, 0, 0}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 10.1];
Wolfram Language code: BinCounts[ts, .1]

タイムスタンプは無視される：

Wolfram Language code: BinCounts[ts["Values"], .1]
Wolfram Language code: %% == %

単位があるデータ  (3)

単位があるデータをビンに入れる：

Wolfram Language code: data = {Quantity[-1.541, "Grams"], Quantity[-0.849, "Grams"], Quantity[-0.477, "Grams"], Quantity[-0.133, "Grams"], Quantity[-0.11, "Grams"], Quantity[-0.054, "Grams"], Quantity[0.226, "Grams"], Quantity[0.259, "Grams"], Quantity[1.4, "Grams"], Quantity[1.661, "Grams"]};

自動ビン：

Wolfram Language code: BinCounts[data]

ビン幅を指定する：

Wolfram Language code: BinCounts[data, Quantity[.5, "Grams"]]

固定幅のビン，最小と最大：

Wolfram Language code: BinCounts[data, {Quantity[-1, "Grams"], Quantity[1, "Grams"], Quantity[.1, "Grams"]}]

ビンの間隔を指定する：

Wolfram Language code: BinCounts[data, {{Quantity[-2, "Grams"], Quantity[0, "Grams"], Quantity[2, "Grams"]}}]

混合タイプのデータをビンに入れる：

Wolfram Language code: mat = RandomReal[10, {3, 3}]; mat[[All, 1]] *= Quantity["Meters"]; mat[[All, 3]] *= Quantity["Seconds"];

単位は各次元で互換でなければならない：

Wolfram Language code: mat//MatrixForm

各次元のビン幅を指定する：

Wolfram Language code: BinCounts[mat, Quantity[2, "Meters"], 3, Quantity[1, "Seconds"]]
Wolfram Language code: Normal[%]

QuantityArrayは配列と同じように使うことができる：

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

自動ビン：

Wolfram Language code: BinCounts[data]

ビン幅を互換単位で指定する：

Wolfram Language code: BinCounts[data, Quantity[.2, "Kilograms"]]

アプリケーション  (1)

二次元ビンデータの密度を可視化する：

Wolfram Language code: counts = BinCounts[RandomReal[{-5, 5}, {1000, 2}]];
Wolfram Language code: ArrayPlot[counts]
Wolfram Language code: ListPlot3D[counts, InterpolationOrder -> 0, Filling -> Axis, Mesh -> None]

特性と関係  (1)

BinCountsの結果はBinListsの長さに等しい：

Wolfram Language code: data = RandomReal[{-5, 5}, 1000];
Wolfram Language code: BinCounts[data]
Wolfram Language code: Map[Length, BinLists[data]]

ベクトルのリストについて：

Wolfram Language code: data2 = RandomReal[{-5, 5}, {1000, 2}];
Wolfram Language code: BinCounts[data2] === Map[Length, BinLists[data2], {2}]

考えられる問題  (4)

ビンの区間は左側が閉じている：

Wolfram Language code: BinCounts[{1, 2, 3, 4, 5}]
Wolfram Language code: BinCounts[{1 - $MachineEpsilon, 2, 3, 4, 5}]

単位を含むデータについてのビン指定は互換単位で与えられなければならない：

Wolfram Language code: data = Quantity[RandomReal[1, 20], "Meters"];
Wolfram Language code: BinCounts[data, .2]
Wolfram Language code: BinCounts[data, Quantity[20, "Centimeters"]]

行列データは列と互換の単位を持たなければならない：

Wolfram Language code: mat = {{Quantity[1.03, "Meters"], Quantity[1.65, "Meters"], Quantity[1.49, "Meters"]}, {4.013, 3.40, 2.5}, {Quantity[3.9, "Seconds"], Quantity[1.88, "Seconds"], Quantity[3.52, "Seconds"]}};
Wolfram Language code: BinCounts[mat]
Wolfram Language code: BinCounts[Transpose@mat]

{min,max,dx}指定を使って入手されたビンは，すべてのデータ点を含まないかもしれない：

Wolfram Language code: data = Range[1, 50];
Wolfram Language code: res1 = BinCounts[data, {Min[data], Max[data], 10}]
Wolfram Language code: {Length[data], Total[res1]}

すべてのデータ点がビンの範囲に含まれるように min と max を指定する：

Wolfram Language code: dx = 10; min = 1; max = min + dx * Ceiling[Length[data] / dx];
Wolfram Language code: res2 = BinCounts[data, {min, max, dx}]
Wolfram Language code: Total[res2]

幅のみのビン指定 dx を使うこともできる：

Wolfram Language code: res3 = BinCounts[data, 10]
Wolfram Language code: Total[res3]
Wolfram Research (2007), BinCounts, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinCounts.html （2024年に更新）.

テキスト

Wolfram Research (2007), BinCounts, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinCounts.html （2024年に更新）.

CMS

Wolfram Language. 2007. "BinCounts." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/BinCounts.html.

APA

Wolfram Language. (2007). BinCounts. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BinCounts.html

BibTeX

@misc{reference.wolfram_2026_bincounts, author="Wolfram Research", title="{BinCounts}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/BinCounts.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bincounts, organization={Wolfram Research}, title={BinCounts}, year={2024}, url={https://reference.wolfram.com/language/ref/BinCounts.html}, note=[Accessed: 18-August-2026]}