WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BinomialPointProcess[n,reg]

領域 reg に n 個の点がある二項点過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BinomialPointProcess

BinomialPointProcess[n,reg]

領域 reg に n 個の点がある二項点過程を表す．

詳細

例題

すべて開く すべて閉じる

例  (2)

BinomialPointProcessからサンプルを取る：

Wolfram Language code: pts = RandomPointConfiguration[BinomialPointProcess[200, Disk[]], Disk[]]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

いくつかの実現からサンプルを取る：

Wolfram Language code: pts = RandomPointConfiguration[BinomialPointProcess[1000, Disk[]], Disk[], 3]
Wolfram Language code: pts["ConfigurationCount"]
Wolfram Language code: pts["PointCountList"]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

スコープ  (2)

RegionEmbeddingDimensionがRegionDimensionと等しい任意の有効なRegionQからサンプルを取る：

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];
Wolfram Language code: {RegionQ[ℛ], RegionEmbeddingDimension[ℛ] == RegionDimension[ℛ]}
Wolfram Language code: pts = RandomPointConfiguration[BinomialPointProcess[500, ℛ], ℛ]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

二項点過程を地理領域上に作成する：

Wolfram Language code: reg = GeoDisk[Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Quantity[2, "Miles"]];
Wolfram Language code: proc = BinomialPointProcess [20, reg]

同じ領域上で点のシミュレーションを行う：

Wolfram Language code: sample = RandomPointConfiguration[proc, reg]
Wolfram Language code: GeoListPlot[sample]

アプリケーション  (1)

射手が射撃場で直径1メートルの丸いターゲットにランダムに12発の弾丸を発射する．可能な弾丸パターンのシミュレーションを行う：

Wolfram Language code: reg = Disk[]; proc = BinomialPointProcess[12, reg];
Wolfram Language code: simulations = RandomPointConfiguration[proc, reg, 4]
Wolfram Language code: Show[Region[reg], ListPlot[#, PlotStyle -> PointSize[0.03]]]& /@ simulations["PointsList"]

特性と関係  (4)

BinomialPointProcess内の点の数は n によって定義される：

Wolfram Language code: PointCountDistribution[BinomialPointProcess[n, Disk[{0, 0}, r]]]

単位円板上でBinomialPointProcessのシミュレーションを行う：

Wolfram Language code: reg = Disk[]; proc = BinomialPointProcess[n = 100, reg];
Wolfram Language code: sample = RandomPointConfiguration[proc, reg, 500]

有界部分集合上の対応するPointCountDistribution：

Wolfram Language code: reg1 = Disk[{0, 0}, 1 / 3]; dist = PointCountDistribution[proc, reg1]

部分集合内の点の数のヒストグラムを確率密度関数と比較する：

Wolfram Language code: subdata = SpatialPointData[sample, reg1]
Wolfram Language code: ns = subdata["PointCountList"];
Wolfram Language code: Show[Histogram[ns, {1}, PDF], DiscretePlot[PDF[dist, x], {x, 0, 100}, PlotStyle -> PointSize[Medium]]]

BinomialDistributionを点の数にフィットする：

Wolfram Language code: edist = EstimatedDistribution[ns, BinomialDistribution[n, a]]

適合度を検定する：

Wolfram Language code: DistributionFitTest[ns, edist, "TestConclusion"]

理論上の分布に対して検定する：

Wolfram Language code: DistributionFitTest[ns, dist, "TestConclusion"]

領域被覆上のPointCountDistribution：

Wolfram Language code: reg = Rectangle[]; proc = BinomialPointProcess[100, reg];

3つの集合による被覆を定義する：

Wolfram Language code: r1 = Rectangle[{0, 1 / 2}, {1 / 3, 1}]; r2 = RegionDifference[Disk[{0, 0}, 2 / 3, {0, π / 2}], r1];
Wolfram Language code: covering = {r1, r2, RegionDifference[reg, RegionUnion[r1, r2]]};
Wolfram Language code: Show[Table[Region[Style[covering[[i]], ColorData[97, i]]], {i, 3}]]

この被覆についての点の数の分布：

Wolfram Language code: PointCountDistribution[proc, covering]

二項点過程についてのボイド確率を計算する：

Wolfram Language code: proc = BinomialPointProcess[100, Rectangle[{-1, -1}, {1, 1}]];
Wolfram Language code: reg1 = Disk[{0, 0}, 1 / 10];
Wolfram Language code: PDF[PointCountDistribution[proc, reg1], 0]//N

長方形について：

Wolfram Language code: reg2 = Rectangle[{0, 0}, {.1, .1}];
Wolfram Language code: PDF[PointCountDistribution[proc, reg2], 0]//N

二項点過程は定常であり，強度は並進不変である：

Wolfram Language code: proc = BinomialPointProcess[n, Disk[{0, 0}, 100]];

部分領域における点の数の分布：

Wolfram Language code: subreg1 = Disk[{0, 0}, 50];
Wolfram Language code: dist1 = PointCountDistribution[proc, subreg1]

並進部分領域における点の数の分布：

Wolfram Language code: subreg2 = TransformedRegion[subreg1, TranslationTransform[{RandomInteger[50], RandomInteger[50]}]]
Wolfram Language code: dist2 = PointCountDistribution[proc, subreg2]
Wolfram Language code: dist1 === dist2
Wolfram Research (2020), BinomialPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinomialPointProcess.html.

テキスト

Wolfram Research (2020), BinomialPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinomialPointProcess.html.

CMS

Wolfram Language. 2020. "BinomialPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BinomialPointProcess.html.

APA

Wolfram Language. (2020). BinomialPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BinomialPointProcess.html

BibTeX

@misc{reference.wolfram_2026_binomialpointprocess, author="Wolfram Research", title="{BinomialPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BinomialPointProcess.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_binomialpointprocess, organization={Wolfram Research}, title={BinomialPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/BinomialPointProcess.html}, note=[Accessed: 15-August-2026]}