WOLFRAM

Wolfram 语言与系统参考资料中心

BiweightMidvariance[list]

给出 list 中元素的双加权中值方差 (biweight midvariance) 的值.

BiweightMidvariance[list,c]

给出缩放参数为 c 的双加权中值方差.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

BiweightMidvariance

BiweightMidvariance[list]

给出 list 中元素的双加权中值方差 (biweight midvariance) 的值.

BiweightMidvariance[list,c]

给出缩放参数为 c 的双加权中值方差.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

列表的 BiweightMidvariance：

Wolfram Language code: BiweightMidvariance[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}]

矩阵的列的 BiweightMidvariance：

Wolfram Language code: BiweightMidvariance[{{1., 2.}, {4., 8.}, {5., 3.}, {2., 15.}}]

缩放因子为 8 时列表的 BiweightMidvariance：

Wolfram Language code: BiweightMidvariance[{1, 2, 3, 2, 1}, 8]

日期列表的 BiweightMidvariance：

Wolfram Language code: BiweightMidvariance[{Yesterday, Today, Tomorrow}]

范围  (9)

精确输入给出精确输出：

Wolfram Language code: BiweightMidvariance[{1, 20, 3, 4}]

近似输入给出近似输出：

Wolfram Language code: BiweightMidvariance[{1., 2., 3., 4.}]
Wolfram Language code: BiweightMidvariance[N[{1, 2, 3, 4}, 30]]

不同缩放参数时的双加权中值方差：

Wolfram Language code: BiweightMidvariance[{1.2, 3.8, 4.2, -0.5, -5.2}, 10]
Wolfram Language code: BiweightMidvariance[{1.2, 3.8, 4.2, -0.5, -5.2}, 100]

矩阵的双加权中值方差给出的是按列估计的结果：

Wolfram Language code: BiweightMidvariance[RandomReal[1, {50, 3}]]

一个大型数组的双加权中值方差：

Wolfram Language code: BiweightMidvariance[RandomReal[1, 10 ^ 6]]
Wolfram Language code: BiweightMidvariance[RandomReal[1, {10 ^ 6, 3}]]

求 TimeSeries 的双加权中值方差:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{3, 8, 4, 11, 9, 2}}, {{{1, 3, 5, 7, 8, 10}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: BiweightMidvariance[ts]//N

双加权中值方差只取决于值：

Wolfram Language code: BiweightMidvariance[ts["Values"]//N]

可将双加权中值方差用于含有量的数据：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: BiweightMidvariance[data]

计算日期的双加权中值方差：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];
Wolfram Language code: DateHistogram[dates]
Wolfram Language code: BiweightMidvariance[dates]
Wolfram Language code: UnitConvert[%, "Years" ^ 2]

计算时间的双加权中值方差：

Wolfram Language code: RandomTime[3]
Wolfram Language code: BiweightMidvariance[%]

不同时区规格的时间列表：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}
Wolfram Language code: BiweightMidvariance[%]

应用  (5)

在极值出现的情况下，计算分散度稳健估计值：

Wolfram Language code: BiweightMidvariance[{3, 10, 10 ^ 6, 20, 5, 6}]//N

样本方差受极值的影响很大：

Wolfram Language code: Variance[{3, 10, 10 ^ 6, 20, 5, 6}]//N

识别股票数据中的高波动周期：

Wolfram Language code: data = TemporalData[«4»];
Wolfram Language code: DateListPlot[data]

用五年移动双加权中值方差的平方根来平滑数据：

Wolfram Language code: smooth = Sqrt[MovingMap[BiweightMidvariance, data, {Quantity[5, "Year"]}]];
Wolfram Language code: DateListPlot[smooth]

计算随机过程中一组路径的切片的双加权中值方差：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

选择几个切片时间：

Wolfram Language code: times = Range[0.1, 1, .1];
Wolfram Language code: md = Map[{#, BiweightMidvariance[data["SliceData", #]]}&, times]

绘制这些路径上的双加权中值方差：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[md, PlotStyle -> Black]]

求一个班的孩子们的身高的双加权中值方差：

Wolfram Language code: heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];
Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]
Wolfram Language code: bmv = BiweightMidvariance[heights]//N

绘制双加权中值方差相对于中位数的平方根：

Wolfram Language code: m = Median[heights]; n = Length[heights]; sbmv = Sqrt[bmv];
Wolfram Language code: ListPlot[{heights, {{0, m}, {n, m}}, {{0, m - sbmv}, {n, m - sbmv}}, {{0, m + sbmv}, {n, m + sbmv}}}, Filling -> {1 -> 0, 3 -> {4}}, Joined -> {False, True, True, True}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, PlotLegends -> {"heights", "median", "bands"}, AxesLabel -> Automatic]

考虑来自标准正态分布的一组数据，其异常值由另一个展布较大的正态分布模拟：

Wolfram Language code: BlockRandom[ SeedRandom[10]; data = RandomVariate[MixtureDistribution[{0.95, 0.05}, {NormalDistribution[], NormalDistribution[0, 10]}], 10 ^ 4]; ]
Wolfram Language code: QuantilePlot[data]

用标准正态分布检验数据：

Wolfram Language code: DistributionFitTest[data, NormalDistribution[], "TestConclusion"]

计算双加权中值方差：

Wolfram Language code: bmv = BiweightMidvariance[data]

选取距样本中位数双加权中值方差的平方根的三倍范围内的数据点，从而移除异常点：

Wolfram Language code: bound = 3Sqrt[bmv]; med = Median[data];
Wolfram Language code: ndata = Pick[data, Sign[Abs[data - med] - bound], -1];
Wolfram Language code: QuantilePlot[ndata]

用标准正态分布检验新数据：

Wolfram Language code: DistributionFitTest[ndata, NormalDistribution[], "TestConclusion"]

属性和关系  (3)

计算样本的双加权中值方差：

Wolfram Language code: data = {-1000, 3, 10, 20, 1, -3, 5, 0, 6, 1000};
Wolfram Language code: bw1 = N@BiweightMidvariance[data]

区间 之外的值对统计量没有影响. 这里 是样本中位数， 是绝对中位差. 是缩放参数，默认值为 9：

Wolfram Language code: {x0, δ} = {Median[data], MedianDeviation[data]}

计算双加权中值方差所用加权函数 w(x) 的形状：

Wolfram Language code: Plot[Max[1 - ((x - x0) / (9 δ)) ^ 2, 0] ^ 2, {x, -60, 70}]

把样本中的最小值和最大值乘以 2，再次计算双加权中值方差：

Wolfram Language code: data[[{1, -1}]] *= 2;
Wolfram Language code: bw2 = N@BiweightMidvariance[data]
Wolfram Language code: bw1 == bw2

BiweightMidvariance 和 Variance 是数据的分散度估计量：

Wolfram Language code: data = RandomVariate[StudentTDistribution[2], 10 ^ 4]; est = {BiweightMidvariance, Variance};
Wolfram Language code: TableForm[Through[est[data]], TableHeadings -> {est}]

对数据进行重新抽样以产生自助估计：

Wolfram Language code: {bmvbootstrap, varbootstrap} = Transpose[Table[Through[est[RandomChoice[data, 10 ^ 4]]], {10 ^ 3}]];

计算每个估计量的自助估计的标准偏差/均值所得的比值；较小的数值表示更准确的分散度量：

Wolfram Language code: StandardDeviation[bmvbootstrap] / Mean[bmvbootstrap]
Wolfram Language code: StandardDeviation[varbootstrap] / Mean[varbootstrap]

当 c 取较大值时，BiweightMidvariance 收敛于第二中心矩：

Wolfram Language code: data = RandomReal[StudentTDistribution[1], 1000];
Wolfram Language code: cm = CentralMoment[data, 2]
Wolfram Language code: Plot[{BiweightMidvariance[data, c], cm}, {c, 5, 10 ^ 4}, AxesLabel -> {c}, PlotRange -> All, PlotLegends -> {"biweight mid-variance", "second central moment"}]

可能存在的问题  (1)

对于带有小标量参数的偶数个元素的向量，双加权中值方差可能未定义：

Wolfram Language code: data1 = {1., 2., 3., 4.};
Wolfram Language code: BiweightMidvariance[data1, 0.5]

对于奇数长度的向量和相当小的 c，双加权中值方差可能假设相当大的值：

Wolfram Language code: data2 = {1., 2., 3., 4., 5.};
Wolfram Language code: Plot[BiweightMidvariance[data2, c], {c, 1, 2}, PlotRange -> All]
Wolfram Language code: BiweightMidvariance[data2, 1.678245]
Wolfram Research (2017)，BiweightMidvariance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiweightMidvariance.html （更新于 2024 年）.

文本

Wolfram Research (2017)，BiweightMidvariance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiweightMidvariance.html （更新于 2024 年）.

CMS

Wolfram 语言. 2017. "BiweightMidvariance." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/BiweightMidvariance.html.

APA

Wolfram 语言. (2017). BiweightMidvariance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BiweightMidvariance.html 年

BibTeX

@misc{reference.wolfram_2026_biweightmidvariance, author="Wolfram Research", title="{BiweightMidvariance}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/BiweightMidvariance.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_biweightmidvariance, organization={Wolfram Research}, title={BiweightMidvariance}, year={2024}, url={https://reference.wolfram.com/language/ref/BiweightMidvariance.html}, note=[Accessed: 18-August-2026]}