WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanCountingFunction[kmax,n]

最高で kmax個の変数がTrueであればTrueを返す n 変数のブール関数を表す．

BooleanCountingFunction[{k},n]

厳密に k 変数がTrueであればTrueを返す n 変数の関数を表す．

BooleanCountingFunction[{kmin,kmax},n]

kmin個から kmax個までの変数がTrueであればTrueを返す関数を表す．

BooleanCountingFunction[{{k1,k2,…}},n]

厳密に ki変数がTrueであればTrueを返す関数を表す．

BooleanCountingFunction[spec,{a1,a2,…}]

spec で指定されるブール計数関数に対応する変数 aiのブール式を返す．

BooleanCountingFunction[spec,{a1,a2,…},form]

form で指定された形式のブール式を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BooleanCountingFunction

BooleanCountingFunction[kmax,n]

最高で kmax個の変数がTrueであればTrueを返す n 変数のブール関数を表す．

BooleanCountingFunction[{k},n]

厳密に k 変数がTrueであればTrueを返す n 変数の関数を表す．

BooleanCountingFunction[{kmin,kmax},n]

kmin個から kmax個までの変数がTrueであればTrueを返す関数を表す．

BooleanCountingFunction[{{k1,k2,…}},n]

厳密に ki変数がTrueであればTrueを返す関数を表す．

BooleanCountingFunction[spec,{a1,a2,…}]

spec で指定されるブール計数関数に対応する変数 aiのブール式を返す．

BooleanCountingFunction[spec,{a1,a2,…},form]

form で指定された形式のブール式を返す．

詳細

例題

すべて開く すべて閉じる

例  (1)

最高で2つの条件が真である：

Wolfram Language code: BooleanCountingFunction[2, 4][a, b, c, d]

選言標準形に変換する：

Wolfram Language code: BooleanConvert[%]

スコープ  (6)

最大で2個の引数が真であるとき f は真であると指定する：

Wolfram Language code: f = BooleanCountingFunction[2, 4]
Wolfram Language code: {f[True, True, False, False], f[True, True, False, True]}

厳密に2個の引数が真である：

Wolfram Language code: g = BooleanCountingFunction[{2}, 4]
Wolfram Language code: {g[True, False, True, False], g[False, True, False, False]}

2個から3個の間の数の引数が真である：

Wolfram Language code: h = BooleanCountingFunction[{2, 3}, 4]
Wolfram Language code: {h[True, False, True, True], h[True, False, False, False]}

1個，3個，あるいは5個の引数が真である：

Wolfram Language code: i = BooleanCountingFunction[{1, 5, 2}, 5]
Wolfram Language code: {i[True, False, True, False, True], i[True, False, False, False, True]}

厳密に1個，4個あるいは5個の引数が真であるとき f が真であると指定する：

Wolfram Language code: f = BooleanCountingFunction[{{1, 4, 5}}, 5]
Wolfram Language code: {f[False, True, True, True, True], f[False, True, False, False, True]}

BooleanCountingFunctionはデフォルトで関数の形で保存される：

Wolfram Language code: f = BooleanCountingFunction[{2, 3}, 5][a, b, c, d, e]

BooleanConvertを使って他の形に変換する：

Wolfram Language code: BooleanConvert[f, "DNF"]
Wolfram Language code: BooleanConvert[f, "CNF"]

明示的な変数のリストが与えられるとBooleanCountingFunctionは自動的に変換される：

Wolfram Language code: BooleanCountingFunction[{2, 3}, {a, b, c, d, e}]
Wolfram Language code: BooleanCountingFunction[{2, 3}, {a, b, c, d, e}, "CNF"]

変数の数が増えるとき，拡張形は大きくなることがある：

Wolfram Language code: Length@BooleanCountingFunction[{5, 15}, Array[a, 20]]

関数形を評価する際のパフォーマンスがかなり向上する場合もある：

Wolfram Language code: f = BooleanCountingFunction[{5, 15}, Array[a, 20]];
Wolfram Language code: g = BooleanCountingFunction[{5, 15}, 20]@@Array[a, 20];
Wolfram Language code: rules = Thread[Array[a, 20] -> RandomChoice[{True, False}, 20]];
Wolfram Language code: Timing@(f /. rules)
Wolfram Language code: Timing@(g /. rules)

定数引数は簡約される：

Wolfram Language code: BooleanCountingFunction[{3, 4}, 6]@@{a, True, b, False, c, d}
Wolfram Language code: BooleanCountingFunction[{3, 4}, 6]@@{a, True, b, True, c, d}

極端なケースは自動的に式に変換される：

Wolfram Language code: BooleanCountingFunction[0, 4]@@{a, b, c, d}
Wolfram Language code: BooleanCountingFunction[4, 4]@@{a, b, c, d}
Wolfram Language code: BooleanCountingFunction[{4}, 4]@@{a, b, c, d}

アプリケーション  (4)

最大で k 個，少なくとも k 個，あるいは厳密に k 個の引数が真であるときに真となる新たなプリミティブを作成する：

Wolfram Language code: AtMostK[k_, v_] := BooleanCountingFunction[{0, k}, Length[v]]@@v
Wolfram Language code: AtLeastK[k_, v_] := BooleanCountingFunction[{k, Length[v]}, Length[v]]@@v
Wolfram Language code: ExactlyK[k_, v_] := BooleanCountingFunction[{k}, Length[v]]@@v

単位円に沿って多数の円板領域を作成する：

Wolfram Language code: ineqs = Table[(x - Cos[i 2Pi / 6]) ^ 2 + (y - Sin[i 2Pi / 6]) ^ 2 < 1, {i, 0, 5}]

新たに組み合せられた範囲を示す：

Wolfram Language code: {RegionPlot[AtMostK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35], RegionPlot[AtLeastK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35], RegionPlot[ExactlyK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35]}

これらの領域上で積分する：

Wolfram Language code: NIntegrate[Boole[AtLeastK[2, ineqs]], {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: Integrate[Boole[AtLeastK[2, ineqs]], {x, -2, 2}, {y, -2, 2}]

真となる引数が m を法として k 個である場合に真となるブール関数を定義する：

Wolfram Language code: BooleanModCount[{k_, m_}, v_] := BooleanCountingFunction[{Mod[k, m], Length[v], m}, Length[v]]@@v

k=0で m=2のときはXnorになる：

Wolfram Language code: TautologyQ[Equivalent[Xnor@@Array[a, 10], BooleanModCount[{0, 2}, Array[a, 10]]]]

k=1で m=2のときはXorになる：

Wolfram Language code: TautologyQ[Equivalent[Xor@@Array[a, 10], BooleanModCount[{1, 2}, Array[a, 10]]]]

k と m の上記以外の値については，新たな機能を得る：

Wolfram Language code: Table[BooleanModCount[{1, 3}, Join[ConstantArray[True, {k}], ConstantArray[False, {10 - k}]]], {k, 0, 10}]
Wolfram Language code: Boole[%]

2D真理値表：

Wolfram Language code: ArrayPlot[BooleanTable[BooleanModCount[{1, 3}, Array[a, 10]], Array[a, 5], Array[a, 5, 6]], ColorRules -> {False -> White, True -> Black}]

真理値のリストをソートするブール関数を定義する：

Wolfram Language code: BooleanSort[v_] := Table[BooleanCountingFunction[{k, Length[v]}, Length[v]]@@v, {k, Length[v], 1, -1}]

結果のリストは常にソートされた順になる：

Wolfram Language code: BooleanTable[BooleanSort[{a, b}], {a, b}]
Wolfram Language code: BooleanTable[BooleanSort[{a, b, c}], {a, b, c}]

正常に機能するためには3つのコンポーネントのうちの2つが必要な系の，故障までの平均時間を求める：

Wolfram Language code: {𝒟1, 𝒟2, 𝒟3} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, 𝒟1}, {y, 𝒟2}, {z, 𝒟3}}];
Wolfram Language code: Mean[ℛ]

特性と関係  (6)

BooleanCountingFunctionは引数について対称である：

Wolfram Language code: f = BooleanCountingFunction[{1, 2}, 3]
Wolfram Language code: f@@@Permutations[{True, False, True}]

BooleanCountingFunctionの論理結合は指標に対する集合演算に相当する：

Wolfram Language code: e1 = BooleanCountingFunction[{{1, 3}}, 4][a, b, c, d]∨BooleanCountingFunction[{{1, 4}}, 4][a, b, c, d];
Wolfram Language code: e2 = BooleanCountingFunction[{Union[{1, 3}, {1, 4}]}, 4][a, b, c, d];
Wolfram Language code: TautologyQ[Equivalent[e1, e2]]

基本的な指定はRangeを用いても同じように行うことができる：

Wolfram Language code: f = BooleanCountingFunction[{1, 5, 2}, 5]
Wolfram Language code: g = BooleanCountingFunction[{Range[1, 5, 2]}, 5]
Wolfram Language code: TautologyQ[Equivalent[f@@Array[a, 5], g@@Array[a, 5]], Array[a, 5]]

多くのプリミティブはBooleanCountingFunctionを使って表すことができる：

Wolfram Language code: vars = Array[x, 10];

And：

Wolfram Language code: and[v__] := BooleanCountingFunction[{Length[{v}]}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[And@@vars, and@@vars]]

Or：

Wolfram Language code: or[v__] := BooleanCountingFunction[{1, Length[{v}]}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Or@@vars, or@@vars]]

Nand：

Wolfram Language code: nand[v__] := BooleanCountingFunction[Length[{v}] - 1, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Nand@@vars, nand@@vars]]

Nor：

Wolfram Language code: nor[v__] := BooleanCountingFunction[0, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Nor@@vars, nor@@vars]]

Xor：

Wolfram Language code: xor[v__] := BooleanCountingFunction[{1, Length[{v}], 2}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Xor@@vars, xor@@vars]]

Xnor：

Wolfram Language code: xnor[v__] := BooleanCountingFunction[{0, Length[{v}], 2}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Xnor@@vars, xnor@@vars]]

Equivalent：

Wolfram Language code: equivalent[v__] := BooleanCountingFunction[{{0, Length[{v}]}}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Equivalent@@vars, equivalent@@vars]]

Majority：

Wolfram Language code: majority[v__] := BooleanCountingFunction[{Floor[Length[{v}] / 2] + 1, Length[{v}]}, Length[{v}]][v]
Wolfram Language code: TautologyQ[Equivalent[Majority@@vars, majority@@vars]]

BooleanCountingFunctionの真理集合の大きさはSubsetsの長さである：

Wolfram Language code: SatisfiabilityCount[BooleanCountingFunction[{5, 10}, 15]]
Wolfram Language code: Length[Subsets[Range[15], {5, 10}]]

BooleanCountingFunctionの真理集合の大きさは組合せ総和によって与えられる：

Wolfram Language code: SatisfiabilityCount[BooleanCountingFunction[{300, 700}, 1000]@@Array[a, 1000]]
Wolfram Language code: Sum[Binomial[1000, k], {k, 300, 700}]
Wolfram Language code: %% == %

おもしろい例題  (1)

厳密に i 個の変数が真であるときのBooleanCountingFunctionは互いに素な真理集合を与える：

Wolfram Language code: Table[ArrayPlot[BooleanTable[BooleanCountingFunction[{i}, 10]@@Array[x, 10], Array[x, 5], Array[x, 5, 6]], ColorRules -> {False -> None, True -> ColorData["Rainbow"][i / 11]}], {i, 0, 10}]
Wolfram Language code: Show[%]
Wolfram Research (2008), BooleanCountingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.

テキスト

Wolfram Research (2008), BooleanCountingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.

CMS

Wolfram Language. 2008. "BooleanCountingFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.

APA

Wolfram Language. (2008). BooleanCountingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanCountingFunction.html

BibTeX

@misc{reference.wolfram_2026_booleancountingfunction, author="Wolfram Research", title="{BooleanCountingFunction}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanCountingFunction.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleancountingfunction, organization={Wolfram Research}, title={BooleanCountingFunction}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanCountingFunction.html}, note=[Accessed: 16-August-2026]}