BooleanCountingFunction
BooleanCountingFunction
BooleanCountingFunction[kmax,n]
BooleanCountingFunction[{k},n]
BooleanCountingFunction[{kmin,kmax},n]
BooleanCountingFunction[{{k1,k2,…}},n]
BooleanCountingFunction[spec,{a1,a2,…}]
给出变量 ai 的布尔表达式，相应 spec 指定的布尔统计函数.
BooleanCountingFunction[spec,{a1,a2,…},form]
给出由 form 指定形式的布尔表达式.
更多信息
- BooleanCountingFunction[spec] 给出一个布尔函数对象，其作用方式类似 Function.
- BooleanCountingFunction[spec][a1,a2,…] 给出等价于显式布尔表达式 BooleanCountingFunction[spec,{a1,a2,…}] 的一个隐式表示.
- BooleanConvert 将 BooleanCountingFunction[spec][vars] 转换为一个明确的布尔表达式.
- 当 kmin、kmin+s、…、kmax 个变量为 True 时，BooleanCountingFunction[{kmin,kmax,s},…] 给出 True.
- 任何对称的布尔函数可以用 BooleanCountingFunction 唯一表示.
- 在 BooleanCountingFunction[spec,{a1,a2,…},form]，对 BooleanConvert 给出可能形式.
- BooleanCountingFunction[spec,{a1,a2,…}] 缺省下按析取范式给出一个表达式.
范例
打开所有单元 关闭所有单元基本范例 (1)
范围 (6)
f = BooleanCountingFunction[2, 4]{f[True, True, False, False], f[True, True, False, True]}g = BooleanCountingFunction[{2}, 4]{g[True, False, True, False], g[False, True, False, False]}h = BooleanCountingFunction[{2, 3}, 4]{h[True, False, True, True], h[True, False, False, False]}i = BooleanCountingFunction[{1, 5, 2}, 5]{i[True, False, True, False, True], i[True, False, False, False, True]}f = BooleanCountingFunction[{{1, 4, 5}}, 5]{f[False, True, True, True, True], f[False, True, False, False, True]}BooleanCountingFunction 缺省下保留函数形式：
f = BooleanCountingFunction[{2, 3}, 5][a, b, c, d, e]用 BooleanConvert 转换到其它形式：
BooleanConvert[f, "DNF"]BooleanConvert[f, "CNF"]当给出明确的变量列表，BooleanCountingFunction 自动转换：
BooleanCountingFunction[{2, 3}, {a, b, c, d, e}]BooleanCountingFunction[{2, 3}, {a, b, c, d, e}, "CNF"]Length@BooleanCountingFunction[{5, 15}, Array[a, 20]]f = BooleanCountingFunction[{5, 15}, Array[a, 20]];g = BooleanCountingFunction[{5, 15}, 20]@@Array[a, 20];rules = Thread[Array[a, 20] -> RandomChoice[{True, False}, 20]];Timing@(f /. rules)Timing@(g /. rules)BooleanCountingFunction[{3, 4}, 6]@@{a, True, b, False, c, d}BooleanCountingFunction[{3, 4}, 6]@@{a, True, b, True, c, d}BooleanCountingFunction[0, 4]@@{a, b, c, d}BooleanCountingFunction[4, 4]@@{a, b, c, d}BooleanCountingFunction[{4}, 4]@@{a, b, c, d}应用 (4)
AtMostK[k_, v_] := BooleanCountingFunction[{0, k}, Length[v]]@@vAtLeastK[k_, v_] := BooleanCountingFunction[{k, Length[v]}, Length[v]]@@vExactlyK[k_, v_] := BooleanCountingFunction[{k}, Length[v]]@@vineqs = Table[(x - Cos[i 2Pi / 6]) ^ 2 + (y - Sin[i 2Pi / 6]) ^ 2 < 1, {i, 0, 5}]{RegionPlot[AtMostK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35],
RegionPlot[AtLeastK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35], RegionPlot[ExactlyK[2, ineqs], {x, -2, 2}, {y, -2, 2}, PlotPoints -> 35]}NIntegrate[Boole[AtLeastK[2, ineqs]], {x, -2, 2}, {y, -2, 2}]Integrate[Boole[AtLeastK[2, ineqs]], {x, -2, 2}, {y, -2, 2}]定义一个布尔函数，当真值变量的数目等于 k 模 m 时，函数为真：
BooleanModCount[{k_, m_}, v_] := BooleanCountingFunction[{Mod[k, m], Length[v], m}, Length[v]]@@v当 k=0 且 m=2 时，则得到 Xnor：
TautologyQ[Equivalent[Xnor@@Array[a, 10], BooleanModCount[{0, 2}, Array[a, 10]]]]当 k=1 且 m=2 时，则得到 Xor：
TautologyQ[Equivalent[Xor@@Array[a, 10], BooleanModCount[{1, 2}, Array[a, 10]]]]Table[BooleanModCount[{1, 3}, Join[ConstantArray[True, {k}], ConstantArray[False, {10 - k}]]], {k, 0, 10}]Boole[%]ArrayPlot[BooleanTable[BooleanModCount[{1, 3}, Array[a, 10]], Array[a, 5], Array[a, 5, 6]], ColorRules -> {False -> White, True -> Black}]BooleanSort[v_] := Table[BooleanCountingFunction[{k, Length[v]}, Length[v]]@@v, {k, Length[v], 1, -1}]BooleanTable[BooleanSort[{a, b}], {a, b}]BooleanTable[BooleanSort[{a, b, c}], {a, b, c}]求系统的平均无故障时间，该系统由三个组件组成，要求其中两个组件正常工作：
{𝒟1, 𝒟2, 𝒟3} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, 𝒟1}, {y, 𝒟2}, {z, 𝒟3}}];Mean[ℛ]属性和关系 (6)
BooleanCountingFunction 按它的参数是对称的：
f = BooleanCountingFunction[{1, 2}, 3]f@@@Permutations[{True, False, True}]BooleanCountingFunction 的逻辑组合相应于在指数上集合操作：
e1 = BooleanCountingFunction[{{1, 3}}, 4][a, b, c, d]∨BooleanCountingFunction[{{1, 4}}, 4][a, b, c, d];e2 = BooleanCountingFunction[{Union[{1, 3}, {1, 4}]}, 4][a, b, c, d];TautologyQ[Equivalent[e1, e2]]基本规定可以等价于用 Range 指定：
f = BooleanCountingFunction[{1, 5, 2}, 5]g = BooleanCountingFunction[{Range[1, 5, 2]}, 5]TautologyQ[Equivalent[f@@Array[a, 5], g@@Array[a, 5]], Array[a, 5]]许多指令可以用 BooleanCountingFunction 的形式指定：
vars = Array[x, 10];And：
and[v__] := BooleanCountingFunction[{Length[{v}]}, Length[{v}]][v]TautologyQ[Equivalent[And@@vars, and@@vars]]Or：
or[v__] := BooleanCountingFunction[{1, Length[{v}]}, Length[{v}]][v]TautologyQ[Equivalent[Or@@vars, or@@vars]]Nand：
nand[v__] := BooleanCountingFunction[Length[{v}] - 1, Length[{v}]][v]TautologyQ[Equivalent[Nand@@vars, nand@@vars]]Nor：
nor[v__] := BooleanCountingFunction[0, Length[{v}]][v]TautologyQ[Equivalent[Nor@@vars, nor@@vars]]Xor：
xor[v__] := BooleanCountingFunction[{1, Length[{v}], 2}, Length[{v}]][v]TautologyQ[Equivalent[Xor@@vars, xor@@vars]]Xnor：
xnor[v__] := BooleanCountingFunction[{0, Length[{v}], 2}, Length[{v}]][v]TautologyQ[Equivalent[Xnor@@vars, xnor@@vars]]equivalent[v__] := BooleanCountingFunction[{{0, Length[{v}]}}, Length[{v}]][v]TautologyQ[Equivalent[Equivalent@@vars, equivalent@@vars]]majority[v__] := BooleanCountingFunction[{Floor[Length[{v}] / 2] + 1, Length[{v}]}, Length[{v}]][v]TautologyQ[Equivalent[Majority@@vars, majority@@vars]]BooleanCountingFunction 的真值集的大小是 Subsets 的长度：
SatisfiabilityCount[BooleanCountingFunction[{5, 10}, 15]]Length[Subsets[Range[15], {5, 10}]]BooleanCountingFunction 的真值集的大小可以由组合和给出：
SatisfiabilityCount[BooleanCountingFunction[{300, 700}, 1000]@@Array[a, 1000]]Sum[Binomial[1000, k], {k, 300, 700}]%% == %巧妙范例 (1)
当恰好 i 个变量为真时，BooleanCountingFunction 具有不相交的真值集：
Table[ArrayPlot[BooleanTable[BooleanCountingFunction[{i}, 10]@@Array[x, 10], Array[x, 5], Array[x, 5, 6]], ColorRules -> {False -> None, True -> ColorData["Rainbow"][i / 11]}], {i, 0, 10}]Show[%]
Wolfram Research (2008)，BooleanCountingFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.
文本
Wolfram Research (2008)，BooleanCountingFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.
CMS
Wolfram 语言. 2008. "BooleanCountingFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanCountingFunction.html.
APA
Wolfram 语言. (2008). BooleanCountingFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BooleanCountingFunction.html 年