Wolfram 语言与系统参考资料中心

BoundaryDiscretizeRegion

BoundaryDiscretizeRegion[reg]

将区域 reg 离散化为 BoundaryMeshRegion.

BoundaryDiscretizeRegion[reg,{{x_min,x_max},…}]

限制范围为 .

范例

打开所有单元关闭所有单元

基本范例 (2)

得到圆盘的离散化边界表示：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[]]

限制于第一象限：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[], {{0, 1}, {0, 1}}]

得到球的离散化边界表示：

Wolfram Language code: BoundaryDiscretizeRegion[Ball[]]

限制于第一卦限：

Wolfram Language code: BoundaryDiscretizeRegion[Ball[], {{0, 1}, {0, 1}, {0, 1}}]

范围 (24)

一维区域 (5)

Line 和 Interval 是一维中的全维区域：

Wolfram Language code: BoundaryDiscretizeRegion[Interval[{1, 3}]]

Wolfram Language code: BoundaryDiscretizeRegion[Line[Transpose@{List /@ Range[1, 20, 2], List /@ Range[2, 20, 2]}]]

如果 ImplicitRegion 有一个变量，则它是一维的：

Wolfram Language code: BoundaryDiscretizeRegion[ImplicitRegion[Abs[Sin[x]] ≤ 3 / 4, {{x, 0, 10}}]]

离散化可以被裁剪到指定的范围：

Wolfram Language code: ℛ = ImplicitRegion[Abs[Sin[x]] ≤ 3 / 4, {x}];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, {{0, 10}}]

如果 ParametricRegion 仅有一个函数，则它是一维的：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{t + 5}, {{t, 0, 10}}]]

离散化可以被裁剪到指定的范围：

Wolfram Language code:

ℛ = ParametricRegion[{t + 5}, {{t, 0, ∞}}];
BoundedRegionQ[ℛ]

因为该区域是无界的，剪切它以离散化：

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, {{0, 10}}]

一维中的 BooleanRegion：

Wolfram Language code: BoundaryDiscretizeRegion[BooleanRegion[Xor, {Line[{{-2}, {1}}], Line[{{-1}, {2}}]}]]

边界离散化只能表示全维区域的分量：

Wolfram Language code: ℛ = ImplicitRegion[x == 0 || x ≥ 1, {{x, 0, 3}}];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

也可以使用 DiscretizeRegion 离散化低维分量：

Wolfram Language code: DiscretizeRegion[ℛ]

二维区域 (8)

Rectangle、Disk 和 Simplex 是在二维中可以是全维的特殊区域：

Wolfram Language code: BoundaryDiscretizeRegion[Rectangle[]]

Disk：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[]]

Simplex：

Wolfram Language code: BoundaryDiscretizeRegion[Simplex[2]]

如果 ImplicitRegion 有两个变量，则它是二维的：

Wolfram Language code: BoundaryDiscretizeRegion[ImplicitRegion[x ^ 2 - y ^ 2 ≤ 1, {{x, -3, 3}, {y, -3, 3}}]]

对于无界区域，把离散化剪切到一个指定的范围：

Wolfram Language code:

ℛ = ImplicitRegion[x ^ 2 - y ^ 2 ≤ 1, {x, y}];
BoundedRegionQ[ℛ]

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, {{-3, 3}, {-3, 3}}]

如果 ParametricRegion 有两个函数，则是二维的：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{{t, s (1 - t ^ 2)}, -1 ≤ s ≤ 1 && -1 ≤ t ≤ 1}, {s, t}]]

剪切区域：

Wolfram Language code:

BoundaryDiscretizeRegion[ParametricRegion[{{t, s (1 - t ^ 2)}, -1 ≤ s ≤ 1 && -1 ≤ t ≤ 1}, {s, t}], {{-1, 1}, {-2 / 3, 2 / 3}}]

二维区域，参数限制在单位圆盘上：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{{s, s t}, s ^ 2 + t ^ 2 ≤ 1}, {s, t}]]

参数限制在矩形上：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{{s, s t}, Element[{s, t}, Rectangle[{-1, -1}, {1, 1}]]}, {s, t}]]

已知两个精确区域，ParametricRegion 可以用来表示它们的的闵可夫斯基和：

Wolfram Language code:

r1 = Disk[{0, 0}, 1 / 2];
r2 = Polygon[{{0, 0}, {3, -1}, {1, 0}, {3, 1}}];
pr = ParametricRegion[{{x1 + x2, y1 + y2}, {x1, y1}∈r1 && {x2, y2}∈r2}, {x1, x2, y1, y2}];
BoundaryDiscretizeRegion[pr]

二维中的 RegionUnion：

Wolfram Language code: BoundaryDiscretizeRegion[RegionUnion[Disk[{0, 0}, 1], Disk[{1, 0}, 1]]]

区域可以包括不同维度的分量：

Wolfram Language code:

ℛ = ImplicitRegion[x ^ 2 + y ^ 2 ≤ 1 || x == y, {{x, -2, 2}, {y, -2, 2}}];
DiscretizeRegion[ℛ]

然而，边界离散仅能表示全维的分量：

Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

具有 GeoGridPosition 的多边形：

Wolfram Language code:

ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, 
   {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, 
   {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, 
   {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, 
   {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, 
   {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

三维区域 (5)

Cuboid、Ellipsoid 和 Simplex 是在三维中可以是全维的特殊区域：

Wolfram Language code: BoundaryDiscretizeRegion[Cuboid[{0, 0, 0}, {1, 1, 1}]]

Ellipsoid：

Wolfram Language code: BoundaryDiscretizeRegion[Ellipsoid[{0, 0, 0}, {{5, 2, 3}, {2, 3, 2}, {3, 2, 5}}]]

Simplex：

Wolfram Language code: BoundaryDiscretizeRegion[Simplex[3]]

如果 ImplicitRegion 有精确的三个变量，则它是三维的：

Wolfram Language code:

BoundaryDiscretizeRegion[ImplicitRegion[(x ^ 2 + (9 / 4)y ^ 2 + z ^ 2 - 1) ^ 3 - x ^ 2z ^ 3 - (9 / 80)y ^ 2z ^ 3 ≤ 0, {x, y, z}]]

剪切区域：

Wolfram Language code:

ℛ = ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 ≤ 1, {x, y, z}];
BoundaryDiscretizeRegion[ℛ, {{-3 / 4, 3 / 4}, {-3 / 4, 3 / 4}, {-3 / 4, 3 / 4}}]

如果 ParametricRegion 恰好有三个函数，则是三维的：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{x, y, z + x * y}, {{x, -1, 1}, {y, -1, 1}, {z, -1, 1}}]]

所生成的三维固体，其中参数限制在单位球上：

Wolfram Language code: BoundaryDiscretizeRegion[ParametricRegion[{{x, y, z + y * x}, x ^ 2 + y ^ 2 + z ^ 2 <= 1}, {x, y, z}]]

区域可以包括不同维度的分量：

Wolfram Language code:

ℛ = ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 ≤ 1 || x + y + z == 0, {{x, -2, 2}, {y, -2, 2}, {z, -2, 2}}];
DiscretizeRegion[ℛ]

然而，边界离散仅能表示全维的分量：

Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

详细信息 (2)

使用 MaxCellMeasure 可以控制离散化中的单元测量：

Wolfram Language code: Ω = ImplicitRegion[Abs[x] + Abs[y] ≥ 1, {{x, -2, 2}, {y, -2, 2}}];

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> #], 0]& /@ {Automatic, 5, 1, 1 / 5}

默认情况下，当作为数字给出时，它适用于边界维度：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> .5], 0]

由于面积为 a，长度 l 可以通过面积为 a、边长为 l 的三角形计算得到：

Wolfram Language code: HighlightMesh[bmr = BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> {"Area" -> .1}], 0]

使用相同规范的 TriangulateMesh 将使质量保持在边缘附近：

Wolfram Language code: TriangulateMesh[bmr, MaxCellMeasure -> {"Area" -> .1}]

对于非线性区域，边界单元的测量取决于几个选项：

Wolfram Language code:

Ω = Disk[{1, 2}, {3, 4}, {5, 6}];
HighlightMesh[BoundaryDiscretizeRegion[Ω], 0]

任何线段的长度可以通过 MaxCellMeasure 控制：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> {"Length" -> #}], 0]& /@ {5, 1, 1 / 5}

默认 PrecisionGoal 所选的值使得曲线视觉上显得平滑：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, PrecisionGoal -> #], 0]& /@ {Automatic, 1, 4}

MaxCellMeasure->∞ 可用于将边界度量基于精度：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> ∞, PrecisionGoal -> #], 0]& /@ {Automatic, 1, 2, 3, 4}

PrecisionGoal->None 可用于将边界度量基于 MaxCellMeasure：

Wolfram Language code:

HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> {"Length" -> #}, PrecisionGoal -> None], 0]& /@ {5, 1, 1 / 5}

AccuracyGoal->a 可用于指定绝对绝对公差：

Wolfram Language code:

HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> ∞, PrecisionGoal -> None, AccuracyGoal -> #], 0]& /@ {0, 1, 2, 3}

默认情况下，MaxCellMeasure 应用边界维度：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> #], 0]& /@ {10, 1, 1 / 10}

边界上的度量可能会受近似要求的进一步限制：

Wolfram Language code: HighlightMesh[BoundaryDiscretizeRegion[Ω, MaxCellMeasure -> #, AccuracyGoal -> 4], 0]& /@ {10, 1, 1 / 10}

质量 (4)

离散化中的单元度量可以使用 MaxCellMeasure 控制：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[], MaxCellMeasure -> #]& /@ {1, 0.1, 0.01}

默认情况下，它控制着边的度量：

Wolfram Language code: Max[AnnotationValue[{#, 1}, MeshCellMeasure]]& /@ %

使用 AccuracyGoal 来确保离散后的边界接近确切边界：

Wolfram Language code: {ℛ1, ℛ2} = BoundaryDiscretizeRegion[Disk[], AccuracyGoal -> #]& /@ {2, 5}

具有较高 AccuracyGoal 的离散化距离真实边界较近：

Wolfram Language code: 1 - Max[Norm[#]& /@ AnnotationValue[{#, {1}}, MeshCellCentroid]]& /@ {ℛ1, ℛ2}

使用 PrecisionGoal 来确保离散后的边界接近确切边界：

Wolfram Language code: {ℛ1, ℛ2} = BoundaryDiscretizeRegion[Disk[], PrecisionGoal -> #]& /@ {2, 5}

具有较高 PrecisionGoal 的离散化距离真实边界较近：

Wolfram Language code: 1 - Max[Norm[#]& /@ AnnotationValue[{#, {1}}, MeshCellCentroid]]& /@ {ℛ1, ℛ2}

设定 PerformanceGoal 为 "Quality" 以得到高质量的离散化：

Wolfram Language code: ℛ = ImplicitRegion[-1 + 2 x^2 ≤ y ≤ x^2, {{x, -1, 1}, {y, -1, 1}}];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, PerformanceGoal -> "Quality"]

或者设定为 "Speed" 使离散化速度更快，但质量可能会降低：

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, PerformanceGoal -> "Speed"]

选项 (24)

AccuracyGoal (1)

确保离散边界表示接近边界：

Wolfram Language code: bmr = BoundaryDiscretizeRegion[Disk[], AccuracyGoal -> 2]

真实圆盘的最大偏差位于区段的中心：

Wolfram Language code: ListPlot[err = Map[{ArcTan@@#, Norm[#] - 1}&, AnnotationValue[{bmr, 1}, MeshCellCentroid]]]

精确度目标较高时，通过使用更多的点来减小误差：

Wolfram Language code:

bmr = BoundaryDiscretizeRegion[Disk[], AccuracyGoal -> 3];
ListPlot[err = Map[{ArcTan@@#, Norm[#] - 1}&, AnnotationValue[{bmr, 1}, MeshCellCentroid]]]

MaxCellMeasure (2)

在 MaxCellMeasure->m 时，边界单元尺寸小于或等于：

Wolfram Language code: bmr = BoundaryDiscretizeRegion[Disk[{0, 0}, {2, 1}], MaxCellMeasure -> .1]

这里给出线段的长度：

Wolfram Language code: Histogram[AnnotationValue[{bmr, 1}, MeshCellMeasure]]

在三维空间中，各面的面积由 MaxCellMeasure 控制：

Wolfram Language code: bmr = BoundaryDiscretizeRegion[Ellipsoid[{0, 0, 0}, {3, 2, 1}], MaxCellMeasure -> .1]

这里给出各面的面积：

Wolfram Language code: Histogram[AnnotationValue[{bmr, 2}, MeshCellMeasure]]

边的长度通过设定 "Length" 的最大度量控制：

Wolfram Language code: bmr = BoundaryDiscretizeRegion[Ellipsoid[{0, 0, 0}, {3, 2, 1}], MaxCellMeasure -> {"Length" -> 0.3}]

这仅是一个探试；有些边可能更大：

Wolfram Language code: Histogram[AnnotationValue[{bmr, 1}, MeshCellMeasure]]

MeshCellHighlight (3)

MeshCellHighlight 允许指定部分 BoundaryMeshRegion 的突出显示：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[], MeshCellHighlight -> {{1, All} -> Red, {0, All} -> Black}]

通过使表面透明，可以看见三维 BoundaryMeshRegion 的内部结构：

Wolfram Language code: BoundaryDiscretizeRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], MeshCellHighlight -> {{2, All} -> Opacity[0.5, Orange]}]

个体单元可以使用它们的单元索引进行突出显示：

Wolfram Language code:

BoundaryDiscretizeRegion[Simplex[2], MaxCellMeasure -> 1, MeshCellHighlight -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Black}}]

或者通过单元自身：

Wolfram Language code:

BoundaryDiscretizeRegion[Simplex[2], MaxCellMeasure -> 1, MeshCellHighlight -> {Line[{1, 2}] -> {Thick, Red}, Line[{2, 4}] -> {Dashed, Black}}]

MeshCellLabel (3)

MeshCellLabel 可用于标记部分 BoundaryMeshRegion：

Wolfram Language code: BoundaryDiscretizeRegion[Interval[{1, 3}], MeshCellLabel -> {0 -> "Index"}]

标记矩形的顶点和边：

Wolfram Language code: BoundaryDiscretizeRegion[Rectangle[], MaxCellMeasure -> 1, MeshCellLabel -> {0 -> "Index", 1 -> "Index"}]

可以使用单元索引标记个体单元：

Wolfram Language code: BoundaryDiscretizeRegion[Interval[{1, 3}], MeshCellLabel -> {{0, 1} -> "x", {0, 2} -> "y"}]

或者通过单元自身：

Wolfram Language code: BoundaryDiscretizeRegion[Interval[{1, 3}], MeshCellLabel -> {Point[1] -> "x", Point[2] -> "y"}]

MeshCellMarker (1)

MeshCellMarker 可用于给部分 BoundaryMeshRegion 赋值：

Wolfram Language code: BoundaryDiscretizeRegion[Rectangle[], MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2}]

使用 MeshCellLabel 显示标记：

Wolfram Language code: BoundaryDiscretizeRegion[Rectangle[], MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction (2)

MeshCellShapeFunction 允许指定部分 BoundaryMeshRegion 的函数：

Wolfram Language code: BoundaryDiscretizeRegion[Rectangle[], MaxCellMeasure -> 1, MeshCellShapeFunction -> {0 -> (Disk[#, .1]&)}]

个体单元可以使用它们的单元索引绘制：

Wolfram Language code:

BoundaryDiscretizeRegion[Rectangle[], MaxCellMeasure -> 1, MeshCellShapeFunction -> {{0, 1} -> (Disk[#, .1]&), {0, 2} -> (Disk[#, {.1, .2}]&)}]

或者通过单元自身：

Wolfram Language code:

BoundaryDiscretizeRegion[Rectangle[], MaxCellMeasure -> 1, MeshCellShapeFunction -> {Point[1] -> (Disk[#, .1]&), Point[2] -> (Disk[#, {.1, .2}]&)}]

MeshCellStyle (3)

MeshCellStyle 允许指定部分 BoundaryMeshRegion 的样式：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[], MeshCellStyle -> {{1, All} -> Red, {0, All} -> Black}]

通过使表面透明，可以看见三维 BoundaryMeshRegion 的内部结构：

Wolfram Language code: BoundaryDiscretizeRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], MeshCellStyle -> {{2, All} -> Opacity[0.5, Orange]}]

个体单元可以使用它们的单元索引被突出显示：

Wolfram Language code:

BoundaryDiscretizeRegion[Simplex[2], MaxCellMeasure -> 1, MeshCellStyle -> {{1, 1} -> Directive[Thick, Red], {1, 2} -> Directive[Dashed, Black]}]

或者通过它们自身：

Wolfram Language code:

BoundaryDiscretizeRegion[Simplex[2], MaxCellMeasure -> 1, MeshCellStyle -> {Line[{1, 2}] -> Directive[Thick, Red], Line[{2, 4}] -> Directive[Dashed, Black]}]

Method (6)

方法 "Continuation" 使用曲线延拓方法，在许多情况下可以处理角、尖和急剧变化的情况：

Wolfram Language code: ℛ = ImplicitRegion[-1 + 2 x^2 ≤ y ≤ x^2, {{x, -1, 1}, {y, -1, 1}}];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, Method -> "Continuation"]

方法 "RegionPlot" 基于改善 RegionPlot 的输出，有些时候使得速度较快：

Wolfram Language code: ℛ = ImplicitRegion[-1 + 2 x^2 ≤ y ≤ x^2, {{x, -1, 1}, {y, -1, 1}}];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ, Method -> "RegionPlot"]

方法 "Boolean" 对于布尔区域是最优化的：

Wolfram Language code: BoundaryDiscretizeRegion[RegionUnion[Disk[{0, 0}, 1], Disk[{1, 0}, 1]], Method -> "Boolean"]

方法 "DiscretizeGraphics" 对于图形基元是最优化的：

Wolfram Language code: BoundaryDiscretizeRegion[Disk[], Method -> "DiscretizeGraphics"]

用于三维区域的方法 "RegionPlot3D" 基于 RegionPlot3D：

Wolfram Language code: BoundaryDiscretizeRegion[Ball[], Method -> "RegionPlot3D"]

用于三维区域的方法 "ContourPlot3D" 基于 ContourPlot3D：

Wolfram Language code: BoundaryDiscretizeRegion[Ball[], Method -> "ContourPlot3D"]

PlotTheme (2)

使用具有网格线和图例的主题：

Wolfram Language code: BoundaryDiscretizeRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], PlotTheme -> "Detailed"]

使用主题绘制线框：

Wolfram Language code: BoundaryDiscretizeRegion[Cuboid[{0, 0, 0}, {1, 1, 1}], PlotTheme -> "Lines"]

PrecisionGoal (1)

确保离散化的边界表示靠近边界：

Wolfram Language code: bmr = BoundaryDiscretizeRegion[Disk[], PrecisionGoal -> 2]

距真实圆盘的最大偏差是线段的中心：

Wolfram Language code: ListPlot[err = Map[{ArcTan@@#, Norm[#] - 1}&, AnnotationValue[{bmr, 1}, MeshCellCentroid]]]

提高精度目标，通过使用更多的点使误差减小：

Wolfram Language code:

bmr = BoundaryDiscretizeRegion[Disk[], AccuracyGoal -> 3];
ListPlot[err = Map[{ArcTan@@#, Norm[#] - 1}&, AnnotationValue[{bmr, 1}, MeshCellCentroid]]]

应用 (2)

可视化 LaminaData：

Wolfram Language code: f = LaminaData["Salinon", "Region"]

离散并可视化该区域：

Wolfram Language code: BoundaryDiscretizeRegion[f[1, .5]]

可视化 SolidData：

Wolfram Language code: f = SolidData["CylindricalHalfShell", "Region"]

离散并可视化该区域：

Wolfram Language code: BoundaryDiscretizeRegion[f[1, .5, 2]]

属性和关系 (5)

BoundaryDiscretizeRegion 的输出是 BoundaryMeshRegion：

Wolfram Language code: ℛ = BoundaryDiscretizeRegion[Disk[]]

Wolfram Language code: BoundaryMeshRegionQ[ℛ]

已知边界离散，TriangulateMesh 能够离散内部：

Wolfram Language code: {ℛ = BoundaryDiscretizeRegion[Disk[]], TriangulateMesh[ℛ]}

边界离散表示区域的常规闭包：

Wolfram Language code: ℛ = RegionUnion[Disk[], Line[{{-1, -1}, {1, 1}}]];

Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

较低维的分量丢失，但可以通过 DiscretizeRegion 表示：

Wolfram Language code: DiscretizeRegion[ℛ]

BoundaryDiscretizeRegion 可以离散有孔的区域：

Wolfram Language code: BoundaryDiscretizeRegion[ImplicitRegion[1 ≤ x^2 + y^2 ≤ 4, {x, y}]]

BoundaryDiscretizeRegion 可对具有不相交部分的区域进行离散化：

Wolfram Language code: BoundaryDiscretizeRegion[ImplicitRegion[Sin[x y] ≤ 0.2, {x, y}], {{0, 5}, {0, 5}}]

巧妙范例 (1)

离散隐式的李萨如区域：

Wolfram Language code:

BoundaryDiscretizeRegion[ImplicitRegion[-1 + (-1 + 18 x^2 - 48 x^4 + 32 x^6)^2 + (-1 + 18 y^2 - 48 y^4 + 32 y^6)^2  ≤ 0, {x, y}]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

BoundaryDiscretizeRegion

更多信息和选项

范例

基本范例 (2)

范围 (24)

一维区域 (5)

二维区域 (8)

三维区域 (5)

详细信息 (2)

质量 (4)

选项 (24)

AccuracyGoal (1)

MaxCellMeasure (2)

MeshCellHighlight (3)

MeshCellLabel (3)

MeshCellMarker (1)

MeshCellShapeFunction (2)

MeshCellStyle (3)

Method (6)

PlotTheme (2)

PrecisionGoal (1)

应用 (2)

属性和关系 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

AccuracyGoal	Automatic	所追求的准确度位数
MaxCellMeasure	Automatic	最大单元度量
Method	Automatic	所用方法
PerformanceGoal	$PerformanceGoal	考虑速度还是质量
PrecisionGoal	Automatic	所追求的精度位数

BoundaryDiscretizeRegion

更多信息和选项

范例

基本范例 (2)

范围 (24)

一维区域 (5)

二维区域 (8)

三维区域 (5)

详细信息 (2)

质量 (4)

选项 (24)

AccuracyGoal (1)

MaxCellMeasure (2)

MeshCellHighlight (3)

MeshCellLabel (3)

MeshCellMarker (1)

MeshCellShapeFunction (2)

MeshCellStyle (3)

Method (6)

PlotTheme (2)

PrecisionGoal (1)

应用 (2)

属性和关系 (5)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX