Wolfram言語＆システムドキュメントセンター

BrownianBridgeProcess

BrownianBridgeProcess[σ,{t₁,a},{t₂,b}]

時点 t₁における値 a から時点 t₂における値 b までの，ボラティリティ σ のブラウン(Brownian)橋過程を表す．

BrownianBridgeProcess[{t₁,a},{t₂,b}]

時点 t₁における値 a から時点 t₂における値 b までの標準ブラウン橋過程を表す．

BrownianBridgeProcess[t₁,t₂]

時点 t₁と t₂において0でピン止めされた標準ブラウン橋過程を表す．

BrownianBridgeProcess[]

時点0と1において0でピン止めされた標準ブラウン橋過程を表す．

BrownianBridgeProcess

BrownianBridgeProcess[σ,{t₁,a},{t₂,b}]

時点 t₁における値 a から時点 t₂における値 b までの，ボラティリティ σ のブラウン(Brownian)橋過程を表す．

BrownianBridgeProcess[{t₁,a},{t₂,b}]

時点 t₁における値 a から時点 t₂における値 b までの標準ブラウン橋過程を表す．

BrownianBridgeProcess[t₁,t₂]

時点 t₁と t₂において0でピン止めされた標準ブラウン橋過程を表す．

BrownianBridgeProcess[]

時点0と1において0でピン止めされた標準ブラウン橋過程を表す．

詳細

BrownianBridgeProcessはピン止めブラウン運動過程としても知られている．
BrownianBridgeProcessは連続時間・連続状態のランダム過程である．
ブラウン橋過程の状態は，とを満足する．
状態は，NormalDistribution[a+(b-a) (t-t₁)/(t₂-t₁),]に従う．
母数 σ，t₁，t₂，a，b は，σ が正で，t₂が t₁より大きくなるような，任意の実数でよい．
BrownianBridgeProcessは，Mean，PDF，Probability，RandomFunction等の関数で使うことができる．

例題

すべて開くすべて閉じる

例 (3)

両端の0でピン止めされたブラウン橋過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[], {0, 1, .01}]

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

平均と分散の関数：

Wolfram Language code: Mean[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

Wolfram Language code: Variance[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

共分散関数：

Wolfram Language code: CovarianceFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}], s, t]

Wolfram Language code: Plot3D[CovarianceFunction[BrownianBridgeProcess[], s, t], {s, 0, 1}, {t, 0, 1}, ColorFunction -> "Rainbow"]

スコープ (13)

基本的な用法 (8)

自己評価の短縮形：

Wolfram Language code: BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]

Wolfram Language code: BrownianBridgeProcess[Subscript[t, 1], Subscript[t, 2]]

Wolfram Language code: BrownianBridgeProcess[]

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[], {0, 1, .01}, 4]

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

任意精度でシミュレーションを行う：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

さまざまな値にピンを打ったブラウン橋過程の経路のシミュレーションを行う：

Wolfram Language code:

proc[x_] := BrownianBridgeProcess[{0, -1}, {2, x}];
end = {-1, 0, 1};
data = RandomFunction[proc[#], {0, 2, .01}]& /@ end;

Wolfram Language code: ListLinePlot[data, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ end)]

過程の台のい含まれる区間でブラウン橋過程のシミュレーションを行う：

Wolfram Language code:

sample2 = RandomFunction[BrownianBridgeProcess[], {.2, .8, .01}, 3];ListLinePlot[sample2, PlotRange -> {{0, 1}, {-2, 2}}]

過程母数推定：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[{0, -16 / 10}, {2, 1}], {0, 2, .01}];

Wolfram Language code: EstimatedProcess[data, BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]]

相関関数：

Wolfram Language code: 𝒫 = BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}];

Wolfram Language code: CorrelationFunction[𝒫, s, t]

絶対相関関数：

Wolfram Language code: 𝒫 = BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}];

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]

過程スライス特性 (5)

一変量SliceDistribution：

Wolfram Language code: SliceDistribution[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}], t]

一次確率密度関数：

Wolfram Language code:

Plot[Evaluate@Table[PDF[BrownianBridgeProcess[][t], x], {t, {.9, .8, .3}}], {x, -1.5, 1.5}, Filling -> Axis, PlotLegends -> {"t = 0.9", "t = 0.8", "t = 0.3"}]

Wolfram Language code: PDF[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], x]

多変量スライス分布：

Wolfram Language code: SliceDistribution[BrownianBridgeProcess[], {s, t}]//Simplify

Wolfram Language code: BrownianBridgeProcess[2, {0, 1}, {3, 2}][{1, 2, 3}]//Mean

二次PDF：

Wolfram Language code: PDF[BrownianBridgeProcess[][{s, t}], {x, y}]//Simplify[#, 1 ≥ s ≥ 0 && 1 ≥ t ≥ 0]&

式の期待値を計算する：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xBrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}]]

ある事象の確率を計算する：

Wolfram Language code: Probability[x[t] < 6, xBrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}]]

歪度と尖度は一定である：

Wolfram Language code: Skewness[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

Wolfram Language code: Kurtosis[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

Moment：

Wolfram Language code: Moment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]

母関数：

Wolfram Language code: CharacteristicFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

Wolfram Language code: MomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

CentralMomentとその母関数：

Wolfram Language code: CentralMoment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]

Wolfram Language code: CentralMomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

FactorialMomentは記号次数では閉形式を持たない：

Wolfram Language code: FactorialMoment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], 3]//Simplify

Wolfram Language code: FactorialMomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

Cumulantとその母関数：

Wolfram Language code: Cumulant[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]

Wolfram Language code: CumulantGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

一般化と拡張 (1)

役に立つ短縮形は，評価すると完全形になる：

Wolfram Language code: BrownianBridgeProcess[]

Wolfram Language code: BrownianBridgeProcess[Subscript[t, 1], Subscript[t, 2]]

Wolfram Language code: BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]

特性と関係 (9)

ブラウン橋過程は弱定常ではない：

Wolfram Language code: WeakStationarity[BrownianBridgeProcess[σ, {t1, a}, {t2, b}]]

Wolfram Language code: WeakStationarity[BrownianBridgeProcess[]]

ブラウン橋過程は独立増分を持たない：

Wolfram Language code: proc = BrownianBridgeProcess[σ, {0, a}, {1, b}];

Wolfram Language code:

assumps = 0 < t1 < t2 < t3 < t4 < 1;
mjoint = Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> assumps]//Simplify

期待値の積と比較する：

Wolfram Language code:

mprod = Expectation[(x[t2] - x[t1]), xproc, Assumptions -> assumps] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> assumps]

Wolfram Language code: Simplify[mjoint == mprod, assumps && σ > 0]

条件付き累積確率分布：

Wolfram Language code:

Table[Plot[Evaluate@Probability[(x[.8] <= Subscript[x, 2])(x[.2] == Subscript[x, 1]), xBrownianBridgeProcess[]], {Subscript[x, 2], -3, 3}, Filling -> Axis, PlotRange -> {0, 1}, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {-1.5, -.3, 1.4, 3}}]

Wolfram Language code:

Probability[(x[Subscript[t, 2]] ≤ Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xBrownianBridgeProcess[], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

ブラウン橋過程は特別なItoProcessである：

Wolfram Language code: ItoProcess[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}]]

StratonovichProcessでもある：

Wolfram Language code: StratonovichProcess[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}]]

ブラウン橋過程は確率微分方程式の解である：

Wolfram Language code: T = 3;a = 3;b = 11;

Wolfram Language code:

noisysol = RandomFunction[BrownianBridgeProcess[{0, a}, {T, b}], {0, T, 0.01}, 3 10 ^ 2];
meanFunction = TimeSeriesThread[Mean, noisysol];

Wolfram Language code:

Show[ListLinePlot[noisysol, PlotStyle -> Directive[Opacity[.1]]], ListLinePlot[meanFunction, PlotStyle -> Directive[Thick, Black]]]

対応する平滑化解と比較する：

Wolfram Language code: sol = DSolve[{P'[t] == (b - P[t]) / (T - t), P[0] == a}, P, t]

Wolfram Language code: Plot[P[t] /. sol[[1]], {t, 0, T}, PlotRange -> {1, 12}]

ブラウン橋過程は，始めのうちは，対応するWienerProcessに従う：

Wolfram Language code:

Block[{sample1, sample2, n = 22, σ = 1, start = 0, end = 1, step = 0.01}, 
	SeedRandom[n];sample1 = RandomFunction[BrownianBridgeProcess[σ, {start, 0}, {end, 0}], {start, end, step}];
	SeedRandom[n];
	sample2 = RandomFunction[WienerProcess[0, σ], {start, end, step}];
	ListLinePlot[{sample1, sample2}, Filling -> {1 -> {2}}]]

BrownianBridgeProcessの絶対上限の分布は，Kolmogorov分布に従う：

Wolfram Language code: CDFKolmogorov[x_] = Sqrt[2 π] / x Sum[Exp[-(2 k - 1) ^ 2 π ^ 2 / (8 x ^ 2)], {k, 1, ∞}]

サンプル分布のシミュレーションを行う：

Wolfram Language code: bridges = Map[Max[Abs[#]]&, RandomFunction[BrownianBridgeProcess[], {0, 1, .0001}, 10 ^ 3]["ValueList"]];

Wolfram Language code: SmoothHistogram[bridges, Automatic, "PDF", Filling -> Axis]

累積ヒストグラムをKolmogorov分布の累積分布関数と比較する：

Wolfram Language code: Show[Histogram[bridges, 40, "CDF"], Plot[CDFKolmogorov[x], {x, Min[bridges], Max[bridges]}, PlotStyle -> Thick]]

BrownianBridgeProcessは，WienerProcessから直接シミュレーションすることができる：

Wolfram Language code: μ = 0;σ = 1 / 3;t0 = 0;t1 = 2;x0 = 0;x1 = 0;

Wolfram Language code:

proc = WienerProcess[μ, σ];
SeedRandom[3];
data = RandomFunction[proc, {t0, t1, .1}];

ランダムサンプルに変換を適用する：

Wolfram Language code:

sample = TimeSeriesMapThread[x0(x1 - x0)(#1 - t0) / (t1 - t0) + #2 - (#1 - t0) Last[data["Values"]] / (t1 - t0) - (t1 - #1)First[data["Values"]] / (t1 - t0)&, data];

対応するBrownianBridgeProcessと比較する：

Wolfram Language code:

SeedRandom[3];
data = RandomFunction[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}], {t0, t1, .1}];

Wolfram Language code: ListLinePlot[{sample, data}, PlotStyle -> {Thick, Dotted}]

ブラウン橋過程は条件付きのWienerProcessである：

Wolfram Language code: cdf[z_] = Probability[(x[t] ≤ z)(x[1] == 0), xWienerProcess[], Assumptions -> 0 < t < 1]

ブラウン橋過程のスライス分布の累積分布関数と比較する：

Wolfram Language code: CDF[BrownianBridgeProcess[][t], z]

Wolfram Language code: % - cdf[z]//Simplify

考えられる問題 (1)

シミュレーションは過程の台の中でのみサポートされている：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 2, .01}]

0から1までのシミュレーション：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 1, .01}]

台の一部でのシミュレーション：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0.3, 0.7, .01}]

おもしろい例題 (3)

ブラウン橋過程のシミュレーションを二次元で行う：

Wolfram Language code:

proc = BrownianBridgeProcess[];
SeedRandom[104];
sample = RandomFunction[proc, {0, 1, 0.001}, 2]["ValueList"];
ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

ブラウン橋過程のシミュレーションを三次元で行う：

Wolfram Language code:

proc = BrownianBridgeProcess[];
SeedRandom[123];
sample = Table[RandomFunction[proc, {0, 1, 0.01}, 3]["ValueList"], {6}];

Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 6}]

ブラウン橋過程からの500の経路のシミュレーションを行う：

Wolfram Language code: SeedRandom[3];data = RandomFunction[BrownianBridgeProcess[], {0, 1 / 2, .01}, 500];

1/2におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 1 / 2];

Wolfram Language code:

cf = ColorData["Rainbow"];
sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 75]&[HistogramList[sd, {Range[-3, 3, .3]}]];

1/2における経路およびスライス分布のヒストグラムの分布をプロットする：

Wolfram Language code:

ListLinePlot[data, ImageSize -> 400, PlotRange -> All, 
	AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {.5, 0}, {0, 10.8}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BrownianBridgeProcess

詳細

例題

例 (3)

スコープ (13)

基本的な用法 (8)

過程スライス特性 (5)

一般化と拡張 (1)

特性と関係 (9)

考えられる問題 (1)

おもしろい例題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

BrownianBridgeProcess

詳細

例題

例 (3)

スコープ (13)

基本的な用法 (8)

過程スライス特性 (5)

一般化と拡張 (1)

特性と関係 (9)

考えられる問題 (1)

おもしろい例題 (3)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX