WOLFRAM

Wolfram 语言与系统参考资料中心

BrownianBridgeProcess[σ,{t1,a},{t2,b}]

表示布朗桥过程，从时间 t1 处的数值 a 到时间 t2 处的数值 b，波动率为 σ.

BrownianBridgeProcess[{t1,a},{t2,b}]

表示标准布朗桥过程，从时间 t1 处的数值 a 到时间 t2 处的数值 b.

BrownianBridgeProcess[t1,t2]

表示标准布朗桥过程，在时间 t1 和 t2 处固定为 0.

BrownianBridgeProcess[]

表示标准布朗桥过程，在时间 0 和时间 1 处固定为 0.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
过程切片性质  
推广和延伸  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BrownianBridgeProcess

BrownianBridgeProcess[σ,{t1,a},{t2,b}]

表示布朗桥过程，从时间 t1 处的数值 a 到时间 t2 处的数值 b，波动率为 σ.

BrownianBridgeProcess[{t1,a},{t2,b}]

表示标准布朗桥过程，从时间 t1 处的数值 a 到时间 t2 处的数值 b.

BrownianBridgeProcess[t1,t2]

表示标准布朗桥过程，在时间 t1 和 t2 处固定为 0.

BrownianBridgeProcess[]

表示标准布朗桥过程，在时间 0 和时间 1 处固定为 0.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

模拟一个在两端固定为 0 的布朗桥过程：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[], {0, 1, .01}]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: Mean[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]
Wolfram Language code: Variance[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

协方差函数：

Wolfram Language code: CovarianceFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[BrownianBridgeProcess[], s, t], {s, 0, 1}, {t, 0, 1}, ColorFunction -> "Rainbow"]

范围  (13)

基本用法  (8)

迅速完成自动计算：

Wolfram Language code: BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]
Wolfram Language code: BrownianBridgeProcess[Subscript[t, 1], Subscript[t, 2]]
Wolfram Language code: BrownianBridgeProcess[]

模拟路径的一个组合：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[], {0, 1, .01}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

以任意精度模拟：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

模拟在不同值处绑定的布朗桥过程的路径：

Wolfram Language code: proc[x_] := BrownianBridgeProcess[{0, -1}, {2, x}]; end = {-1, 0, 1}; data = RandomFunction[proc[#], {0, 2, .01}]& /@ end;
Wolfram Language code: ListLinePlot[data, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ end)]

在包含过程支持的区间上模拟一个布朗桥过程：

Wolfram Language code: sample2 = RandomFunction[BrownianBridgeProcess[], {.2, .8, .01}, 3];ListLinePlot[sample2, PlotRange -> {{0, 1}, {-2, 2}}]

过程参数估计：

Wolfram Language code: data = RandomFunction[BrownianBridgeProcess[{0, -16 / 10}, {2, 1}], {0, 2, .01}];
Wolfram Language code: EstimatedProcess[data, BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]]

相关函数：

Wolfram Language code: 𝒫 = BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}];
Wolfram Language code: CorrelationFunction[𝒫, s, t]

绝对相关函数：

Wolfram Language code: 𝒫 = BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}];
Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]

过程切片性质  (5)

单变量 SliceDistribution:

Wolfram Language code: SliceDistribution[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}], t]

一阶概率密度函数：

Wolfram Language code: Plot[Evaluate@Table[PDF[BrownianBridgeProcess[][t], x], {t, {.9, .8, .3}}], {x, -1.5, 1.5}, Filling -> Axis, PlotLegends -> {"t = 0.9", "t = 0.8", "t = 0.3"}]
Wolfram Language code: PDF[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], x]

多变量切片分布：

Wolfram Language code: SliceDistribution[BrownianBridgeProcess[], {s, t}]//Simplify
Wolfram Language code: BrownianBridgeProcess[2, {0, 1}, {3, 2}][{1, 2, 3}]//Mean

二阶 PDF：

Wolfram Language code: PDF[BrownianBridgeProcess[][{s, t}], {x, y}]//Simplify[#, 1 ≥ s ≥ 0 && 1 ≥ t ≥ 0]&

计算表达式的期望：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xBrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}]]

计算事件概率：

Wolfram Language code: Probability[x[t] < 6, xBrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}]]

偏度和峰度是常量：

Wolfram Language code: Skewness[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]
Wolfram Language code: Kurtosis[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t]]

Moment：

Wolfram Language code: Moment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]

母函数：

Wolfram Language code: CharacteristicFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]
Wolfram Language code: MomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

CentralMoment 和它的母函数：

Wolfram Language code: CentralMoment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

对于符号式阶数，FactorialMoment 没有解析形式：

Wolfram Language code: FactorialMoment[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], 3]//Simplify
Wolfram Language code: FactorialMomentGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

Cumulant 和它的母函数：

Wolfram Language code: Cumulant[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], r]
Wolfram Language code: CumulantGeneratingFunction[BrownianBridgeProcess[σ, {Subscript[t, 1], a}, {Subscript[t, 2], b}][t], w]

推广和延伸  (1)

有用的快捷方式计算它们对应的完整形式：

Wolfram Language code: BrownianBridgeProcess[]
Wolfram Language code: BrownianBridgeProcess[Subscript[t, 1], Subscript[t, 2]]
Wolfram Language code: BrownianBridgeProcess[{Subscript[t, 1], a}, {Subscript[t, 2], b}]

属性和关系  (9)

布朗桥不是弱平稳的：

Wolfram Language code: WeakStationarity[BrownianBridgeProcess[σ, {t1, a}, {t2, b}]]
Wolfram Language code: WeakStationarity[BrownianBridgeProcess[]]

布朗桥过程不具有独立增量：

Wolfram Language code: proc = BrownianBridgeProcess[σ, {0, a}, {1, b}];
Wolfram Language code: assumps = 0 < t1 < t2 < t3 < t4 < 1; mjoint = Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> assumps]//Simplify

与期望值的乘积比较：

Wolfram Language code: mprod = Expectation[(x[t2] - x[t1]), xproc, Assumptions -> assumps] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> assumps]
Wolfram Language code: Simplify[mjoint == mprod, assumps && σ > 0]

条件累积概率分布：

Wolfram Language code: Table[Plot[Evaluate@Probability[(x[.8] <= Subscript[x, 2])(x[.2] == Subscript[x, 1]), xBrownianBridgeProcess[]], {Subscript[x, 2], -3, 3}, Filling -> Axis, PlotRange -> {0, 1}, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {-1.5, -.3, 1.4, 3}}]
Wolfram Language code: Probability[(x[Subscript[t, 2]] ≤ Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xBrownianBridgeProcess[], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

布朗桥过程是一种特殊的 ItoProcess：

Wolfram Language code: ItoProcess[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}]]

也是一种特殊的 StratonovichProcess：

Wolfram Language code: StratonovichProcess[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}]]

布朗桥过程是随机微分方程 的解：

Wolfram Language code: T = 3;a = 3;b = 11;
Wolfram Language code: noisysol = RandomFunction[BrownianBridgeProcess[{0, a}, {T, b}], {0, T, 0.01}, 3 10 ^ 2]; meanFunction = TimeSeriesThread[Mean, noisysol];
Wolfram Language code: Show[ListLinePlot[noisysol, PlotStyle -> Directive[Opacity[.1]]], ListLinePlot[meanFunction, PlotStyle -> Directive[Thick, Black]]]

与相应的平滑解比较：

Wolfram Language code: sol = DSolve[{P'[t] == (b - P[t]) / (T - t), P[0] == a}, P, t]
Wolfram Language code: Plot[P[t] /. sol[[1]], {t, 0, T}, PlotRange -> {1, 12}]

布朗桥过程最初遵循其对应的 WienerProcess：

Wolfram Language code: Block[{sample1, sample2, n = 22, σ = 1, start = 0, end = 1, step = 0.01}, SeedRandom[n];sample1 = RandomFunction[BrownianBridgeProcess[σ, {start, 0}, {end, 0}], {start, end, step}]; SeedRandom[n]; sample2 = RandomFunction[WienerProcess[0, σ], {start, end, step}]; ListLinePlot[{sample1, sample2}, Filling -> {1 -> {2}}]]

BrownianBridgeProcess 绝对上确界服从柯尔莫哥洛夫分布：

Wolfram Language code: CDFKolmogorov[x_] = Sqrt[2 π] / x Sum[Exp[-(2 k - 1) ^ 2 π ^ 2 / (8 x ^ 2)], {k, 1, ∞}]

模拟样本分布：

Wolfram Language code: bridges = Map[Max[Abs[#]]&, RandomFunction[BrownianBridgeProcess[], {0, 1, .0001}, 10 ^ 3]["ValueList"]];
Wolfram Language code: SmoothHistogram[bridges, Automatic, "PDF", Filling -> Axis]

将累积直方图与柯尔莫哥洛夫分布的累积分布函数进行比较：

Wolfram Language code: Show[Histogram[bridges, 40, "CDF"], Plot[CDFKolmogorov[x], {x, Min[bridges], Max[bridges]}, PlotStyle -> Thick]]

BrownianBridgeProcess 可以直接从 WienerProcess 模拟：

Wolfram Language code: μ = 0;σ = 1 / 3;t0 = 0;t1 = 2;x0 = 0;x1 = 0;
Wolfram Language code: proc = WienerProcess[μ, σ]; SeedRandom[3]; data = RandomFunction[proc, {t0, t1, .1}];

对随机样本应用变换：

Wolfram Language code: sample = TimeSeriesMapThread[x0(x1 - x0)(#1 - t0) / (t1 - t0) + #2 - (#1 - t0) Last[data["Values"]] / (t1 - t0) - (t1 - #1)First[data["Values"]] / (t1 - t0)&, data];

与相应的 BrownianBridgeProcess 进行比较：

Wolfram Language code: SeedRandom[3]; data = RandomFunction[BrownianBridgeProcess[σ, {t0, x0}, {t1, x1}], {t0, t1, .1}];
Wolfram Language code: ListLinePlot[{sample, data}, PlotStyle -> {Thick, Dotted}]

布朗桥是条件 WienerProcess:

Wolfram Language code: cdf[z_] = Probability[(x[t] ≤ z)(x[1] == 0), xWienerProcess[], Assumptions -> 0 < t < 1]

与布朗桥切片分布的累积分布函数相比：

Wolfram Language code: CDF[BrownianBridgeProcess[][t], z]
Wolfram Language code: % - cdf[z]//Simplify

可能存在的问题  (1)

模拟仅在过程支持内被支持：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 2, .01}]

在0到1上进行模拟：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0, 1, .01}]

在部分支持上进行模拟：

Wolfram Language code: RandomFunction[BrownianBridgeProcess[], {0.3, 0.7, .01}]

巧妙范例  (3)

模拟二维布朗桥过程：

Wolfram Language code: proc = BrownianBridgeProcess[]; SeedRandom[104]; sample = RandomFunction[proc, {0, 1, 0.001}, 2]["ValueList"]; ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

模拟三维布朗桥过程：

Wolfram Language code: proc = BrownianBridgeProcess[]; SeedRandom[123]; sample = Table[RandomFunction[proc, {0, 1, 0.01}, 3]["ValueList"], {6}];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 6}]

模拟布朗桥过程的500个路径：

Wolfram Language code: SeedRandom[3];data = RandomFunction[BrownianBridgeProcess[], {0, 1 / 2, .01}, 500];

在1/2处取切片，并可视化其分布：

Wolfram Language code: sd = data["SliceData", 1 / 2];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 75]&[HistogramList[sd, {Range[-3, 3, .3]}]];

绘制切变分布在1/2处的路径和直方图分布：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {.5, 0}, {0, 10.8}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]
Wolfram Research (2012)，BrownianBridgeProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html.

文本

Wolfram Research (2012)，BrownianBridgeProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html.

CMS

Wolfram 语言. 2012. "BrownianBridgeProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html.

APA

Wolfram 语言. (2012). BrownianBridgeProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html 年

BibTeX

@misc{reference.wolfram_2026_brownianbridgeprocess, author="Wolfram Research", title="{BrownianBridgeProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_brownianbridgeprocess, organization={Wolfram Research}, title={BrownianBridgeProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/BrownianBridgeProcess.html}, note=[Accessed: 09-August-2026]}