WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChatEvaluate[chat,prompt]

ChatObject chat に prompt とその補足を加える．

ChatEvaluate[prompt]

ChatObjectに適用可能なChatEvaluateの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Authentication  
LLMEvaluator  
ProgressReporting  
アプリケーション  
ツールの呼出し  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ChatEvaluate

この機能には次が必要です：LLMアクセス »

ChatEvaluate[chat,prompt]

ChatObject chat に prompt とその補足を加える．

ChatEvaluate[prompt]

ChatObjectに適用可能なChatEvaluateの演算子形を表す．

詳細とオプション

  • ChatEvaluateはChatObjectの会話を続けるために使われる．
  • ChatEvaluateは，外部サービスの認証，請求，インターネット接続を必要とする．
  • 次は，使用可能な prompt の値である．
  • "text"静的テキスト
    LLMPrompt["name"]リポジトリのプロンプト
    StringTemplate[…]テンプレートのテキスト
    TemplateObject[…]プロンプト作成用のテンプレート
    Image[…]画像
    {prompt1,…}プロンプトのリスト
  • テンプレートオブジェクトはTemplateObject[…][]によって自動的にメッセージの内容に変換される．
  • TemplateObjectで作成したプロンプトには，テキストと画像を入れることができる．すべてのLLMが画像をサポートする訳ではない．
  • 次は，使用可能なオプションである．
  • Authentication Inherited認証スキーム
    LLMEvaluator Inherited使用するLLMの設定
    ProgressReporting $ProgressReporting計算の進捗状況の報告方法
  • LLMEvaluatorがInheritedに設定されているときは，chat で指定されたLLM設定が使われる．
  • LLMEvaluatorをLLMConfigurationオブジェクトあるいは以下のキーの任意のものを持つ連想に設定することができる．
  • "MaxTokens"生成するトークンの最大数
    "Model"ベースモデル
    "PromptDelimiter"プロンプト間に挿入する文字列
    "Prompts"初期プロンプトまたはLLMPromptGeneratorオブジェクト
    "StopTokens"生成を止めるトークン
    "Temperature"サンプリング温度
    "ToolMethod"ツールの呼出しに使用するメソッド
    "Tools"使用可能にするLLMToolオブジェクトのリスト
    "TopProbabilities"サンプリングクラスのカットオフ
    "TotalProbabilityCutoff"サンプリング確率のカットオフ（核サンプリング）
  • 次は，"Model"の有効な形式である．
  • name名前付きのモデル
    {service,name}service からの名前付きのモデル
    <|"Service"service,"Name"name|>完全に指定されたモデル
  • "Prompts"で指定されたプロンプトは，ロールが"System"に設定された chat のメッセージの先頭に追加される．
  • 複数のプロンプトは"PromptDelimiter"特性で分離される．
  • 生成されたテキストは，配布物からサンプリングされる．サンプリングの詳細は，以下のLLMEvaluator特性で指定できる．
  • "Temperature"tAutomatic正の温度 t を使ったサンプリング
    "TopProbabilities"kAutomatic最もありそうな k 個のクラスからのサンプリング
    "TotalProbabilityCutoff"pAutomatic最低でも p の累積確率を持つ最もありそうな選択肢からのサンプリング（核サンプリング）
  • これらのパラメータがAutomaticのときは，指定された"Model"のデフォルトが使われる．
  • 次は，"ToolMethod"の可能な値である．
  • "Service"service のツールメカニズムに依存する
    "Textual"プロンプトベースのツール呼出しを使う
  • 次は，Authenticationの可能な値である．
  • Automatic認証スキームを自動選択する
    Inheritedchat から設定を継承する
    Environment環境変数のキーをチェックする
    SystemCredentialシステムキーチェーンのキーをチェックする
    ServiceObject[…]サービスオブジェクトから認証を継承する
    "string"明示的なAPIキーを与える
  • AuthenticationAutomaticのとき，関数はEnvironmentとSystemCredentialの変数ToUpperCase[service]<>"_API_KEY"をチェックする．それ以外の場合はServiceConnect[service]が使われる．
  • ChatEvaluateは機械学習を使う．含まれるメソッド，訓練集合，バイアスはWolfram言語のバージョンによって異なることがあり，与えられる結果も異なる可能性がある．

例題

すべて開く すべて閉じる

例  (3)

新たなチャットを作成する：

Wolfram Language code: chat = ChatObject[]

会話にメッセージと応答を加える：

Wolfram Language code: ChatEvaluate[chat, "What's the tallest mountain?"]

マルチモーダルモデルを指定してチャットを作成する：

Wolfram Language code: multichat = ChatObject[LLMEvaluator -> <|"Model" -> {"WolframAIAccess", Automatic}|>]

これで，テキストと画像の両方が会話に使える：

Wolfram Language code: ChatEvaluate[multichat, {"what is this picture?", Entity["TaxonomicSpecies", "FelisCatus::ddvt3"][EntityProperty["TaxonomicSpecies", "Image"]]}]

ツールでチャットオブジェクトを作成する：

Wolfram Language code: toolchat = ChatObject[LLMEvaluator -> <|"Tools" -> LLMTool["countcharacter", "string", StringLength]|>]

LLMの答をツールの呼出しステップとともに表示する：

Wolfram Language code: ChatEvaluate[toolchat, "How many letters in the word \"characters\" (use the tool) ?"]

スコープ  (3)

新たな会話を始める：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me a joke"]

既存の会話を続ける：

Wolfram Language code: ChatEvaluate[ChatObject[Association["LLMEvaluator" -> LLMConfiguration[ Association["Model" -> Association["Service" -> "OpenAI", "Name" -> "gpt-4"], "MaxTokens" -> Automatic, "Temperature" -> Automatic, "TotalProbabilityCutoff" -> Automatic, "P ... 1.}, {21.00040054321289, 21.}}}]}, FaceForm[RGBColor[0.5372549019607843, 0.5372549019607843, 0.5372549019607843, 1.]]]}, ImageSize -> {{27., 27.}, {27., 27.}}, PlotRange -> {{-0.5, 26.5}, {-0.5, 26.5}}, AspectRatio -> Automatic]]], "And what about doctors?"]

関数を演算子として使う：

Wolfram Language code: ChatEvaluate["Hi there!"][ChatObject[Association["LLMEvaluator" -> LLMConfiguration[Association["Model" -> Automatic, "MaxTokens" -> Automatic, "Temperature" -> Automatic, "TotalProbabilityCutoff" -> Automatic, "Prompts" -> Automatic, "PromptDelimiter" -> "\n\n" ... 1.}, {21.00040054321289, 21.}}}]}, FaceForm[RGBColor[0.5372549019607843, 0.5372549019607843, 0.5372549019607843, 1.]]]}, ImageSize -> {{27., 27.}, {27., 27.}}, PlotRange -> {{-0.5, 26.5}, {-0.5, 26.5}}, AspectRatio -> Automatic]]]]

オプション  (12)

Authentication  (5)

Wolfram AI Accessを使う：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> LLMConfiguration["WolframAIAccess"]], "which element has atomic number 2?"]

APIの認証キーを与える：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>], "which element has atomic number 2?", Authentication -> "<my-key>"]

オペレーティングシステムのキーチェーンを使ってAPIキーを格納する：

Wolfram Language code: SystemCredential["ANTHROPIC_API_KEY"] = "<my-key>"

システムのキーチェーン内にキーを探す：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>], "which element has atomic number 2?", Authentication -> SystemCredential]

キーの名前（接続時にのみ照会される）を指定する：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>], "which element has atomic number 2?", Authentication :> SystemCredential["MY_OTHER_ANTHROPIC_API_KEY"]]

システム環境内でキーを探す：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"GoogleGemini", Automatic}|>], "which element has atomic number 2?", Authentication -> Environment]

サービスオブジェクトを介して認証する：

Wolfram Language code: so = ServiceConnect["Cohere"]
Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Cohere", Automatic}|>], "which element has atomic number 2?", Authentication -> so]

LLMEvaluator  (6)

解答の生成に使うサービスを指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>]

サービスとモデルの両方を指定する：

Wolfram Language code: modelname = First@ServiceConnect["Anthropic"]["ChatModelList"]
Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> {"Anthropic", modelname}|>]

デフォルトで，テキスト生成は終了トークンが生成されるまで続く：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi"]

生成されるサンプル（トークン）の量を制限する：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"MaxTokens" -> 3|>]

サンプリングを温度0で行うように指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 0|>]

生成においてより大きな変動を得るために，高い温度を指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 2|>]

分布を打ち切る前の累積確率の最大値を指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"TotalProbabilityCutoff" -> .5|>]

生成に使用するサービスとモデルを指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"Model" -> {"OpenAI", "gpt-4"}|>]

プロンプトが自動的に挿入されるように指定する：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"Prompts" -> LLMPrompt["ELI5"]|>]

ProgressReporting  (1)

進捗情報は報告しない：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the tallest mountain?", ProgressReporting -> False]

アプリケーション  (1)

ツールの呼出し  (1)

LLMが呼び出せるツールを定義する：

Wolfram Language code: altimeter = LLMTool[{"altimeter", "gives the altitude at a location"}, {"where" -> "Location"}, GeoElevationData[#where]&]

このツールでチャットオブジェクトのインスタンスを作成する：

Wolfram Language code: chat = ChatObject[LLMEvaluator -> <|"Tools" -> altimeter|>]

このツールを使って正確な答が得られる質問を行う：

Wolfram Language code: ChatEvaluate[chat, "what's the altitude of mount Kilimanjaro?"]

考えられる問題  (1)

認証キーを指定してチャットセッションを評価すると，情報が埋め込まれる：

Wolfram Language code: chat = ChatEvaluate[ChatObject[], "Who are you?", LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>, Authentication -> "<my-key>"]

デフォルト設定のAuthenticationInheritedのときは，別のサービスの認証がうまくいかない：

Wolfram Language code: ChatEvaluate[chat, "Who are you?", LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>]

AuthenticationAutomaticを使うか，新たなサービスに対する明示的な認証を与えるかして再接続する：

Wolfram Language code: ChatEvaluate[chat, "Who are you?", LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>, Authentication -> Automatic]
Wolfram Research (2023), ChatEvaluate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChatEvaluate.html.

テキスト

Wolfram Research (2023), ChatEvaluate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChatEvaluate.html.

CMS

Wolfram Language. 2023. "ChatEvaluate." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ChatEvaluate.html.

APA

Wolfram Language. (2023). ChatEvaluate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChatEvaluate.html

BibTeX

@misc{reference.wolfram_2026_chatevaluate, author="Wolfram Research", title="{ChatEvaluate}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/ChatEvaluate.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_chatevaluate, organization={Wolfram Research}, title={ChatEvaluate}, year={2023}, url={https://reference.wolfram.com/language/ref/ChatEvaluate.html}, note=[Accessed: 11-September-2026]}