WOLFRAM

Wolfram 语言与系统参考资料中心

ChatEvaluate[chat,prompt]

将 prompt 及其后续内容追加到 ChatObject chat.

ChatEvaluate[prompt]

表示可应用于 ChatObject 的算符形式的 ChatEvaluate.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Authentication  
LLMEvaluator  
ProgressReporting  
应用  
Tool Calling  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ChatEvaluate

该功能需要访问 LLM »

ChatEvaluate[chat,prompt]

将 prompt 及其后续内容追加到 ChatObject chat.

ChatEvaluate[prompt]

表示可应用于 ChatObject 的算符形式的 ChatEvaluate.

更多信息和选项

  • ChatEvaluate 被用于 ChatObject 中继续进行对话.
  • ChatEvaluate 需要外部服务认证、计费和互联网连接.
  • prompt 的可能值包括：
  • "text"静态文本
    LLMPrompt["name"]存储库提示
    StringTemplate[…]模板文本
    TemplateObject[…]创建文本的模板
    Image[…]图像
    {prompt1,…}提示列表
  • 通过 TemplateObject[…][] 将模板对象自动转换为消息内容.
  • 使用 TemplateObject 创建的提示可以包含文本和图像. 并非所有 LLM 都支持图像输入.
  • 可指定以下选项：
  • Authentication Inherited认证方式
    LLMEvaluator Inherited使用的 LLM 配置
    ProgressReporting $ProgressReporting如何报告计算进度
  • 如果 LLMEvaluator 被设为 Inherited，使用 chat 指定的 LLM 配置.
  • LLMEvaluator 可被设为 LLMConfiguration 对象或含有以下键的关联：
  • "MaxTokens"生成词元的最大数量
    "Model"基础模型
    "PromptDelimiter"在提示符之间插入字符串
    "Prompts"初始提示或 LLMPromptGenerator 对象
    "StopTokens"用来指示停止生成的词元
    "Temperature"采样温度
    "ToolMethod"用于工具调用的方法
    "Tools"要提供的 LLMTool 对象列表
    "TopProbabilities"采样类型截止
    "TotalProbabilityCutoff"采样概率截止（核取样）
  • "Model" 的有效形式包括：
  • name已命名模型
    {service,name}来自 service 的已命名模型
    <|"Service"service,"Name"name|>完全指定的模型
  • "Prompts" 中指定的提示将添加到 chat 的消息中，角色设置为 "System".
  • "PromptDelimiter" 属性分隔多个提示.
  • 生成的文本采样自一个分布. 可用 LLMEvaluator 的以下属性指定采样的详细信息：
  • "Temperature"tAutomatic用正的温度 t 进行采样
    "TopProbabilities"kAutomatic仅在 k 个最高概率类别中进行采样
    "TotalProbabilityCutoff"pAutomatic在累积概率至少为 p 的最可能的选择中进行抽样（核心抽样）
  • 这些参数的 Automatic 值使用指定 "Model" 的默认值.
  • "ToolMethod" 的可能设置包括：
  • "Service"依托 service 的工具机制
    "Textual"使用基于提示的工具调用
  • Authentication 的可能的值为：
  • Automatic自动选择认证方式
    Inherited从 chat 中继承设置
    Environment检查环境变量中的密钥
    SystemCredential检查系统钥匙串中的密钥
    ServiceObject[…]从服务对象继承认证
    "string"提供明确的 API 密钥
  • 当 AuthenticationAutomatic 时，函数会检查 Environment 和 SystemCredential 中的变量 ToUpperCase[service]<>"_API_KEY"；否则会使用 ServiceConnect[service].
  • ChatEvaluate 使用机器学习. 在不同版本的 Wolfram 语言中，其方法、训练集和偏差可能会改变并给出不同的结果.

范例

打开所有单元 关闭所有单元

基本范例  (3)

创建新的聊天：

Wolfram Language code: chat = ChatObject[]

向对话添加消息和回复：

Wolfram Language code: ChatEvaluate[chat, "What's the tallest mountain?"]

创建指定多模式模型的聊天：

Wolfram Language code: multichat = ChatObject[LLMEvaluator -> <|"Model" -> {"WolframAIAccess", Automatic}|>]

现在，文字和图像都可以在对话中使用：

Wolfram Language code: ChatEvaluate[multichat, {"what is this picture?", Entity["TaxonomicSpecies", "FelisCatus::ddvt3"][EntityProperty["TaxonomicSpecies", "Image"]]}]

使用工具创建聊天对象：

Wolfram Language code: toolchat = ChatObject[LLMEvaluator -> <|"Tools" -> LLMTool["countcharacter", "string", StringLength]|>]

显示 LLM 答案和调用工具的步骤：

Wolfram Language code: ChatEvaluate[toolchat, "How many letters in the word \"characters\" (use the tool) ?"]

范围  (3)

开始新的对话：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me a joke"]

继续现有对话：

Wolfram Language code: ChatEvaluate[ChatObject[Association["LLMEvaluator" -> LLMConfiguration[ Association["Model" -> Association["Service" -> "OpenAI", "Name" -> "gpt-4"], "MaxTokens" -> Automatic, "Temperature" -> Automatic, "TotalProbabilityCutoff" -> Automatic, "P ... 1.}, {21.00040054321289, 21.}}}]}, FaceForm[RGBColor[0.5372549019607843, 0.5372549019607843, 0.5372549019607843, 1.]]]}, ImageSize -> {{27., 27.}, {27., 27.}}, PlotRange -> {{-0.5, 26.5}, {-0.5, 26.5}}, AspectRatio -> Automatic]]], "And what about doctors?"]

将函数用作运算符：

Wolfram Language code: ChatEvaluate["Hi there!"][ChatObject[Association["LLMEvaluator" -> LLMConfiguration[Association["Model" -> Automatic, "MaxTokens" -> Automatic, "Temperature" -> Automatic, "TotalProbabilityCutoff" -> Automatic, "Prompts" -> Automatic, "PromptDelimiter" -> "\n\n" ... 1.}, {21.00040054321289, 21.}}}]}, FaceForm[RGBColor[0.5372549019607843, 0.5372549019607843, 0.5372549019607843, 1.]]]}, ImageSize -> {{27., 27.}, {27., 27.}}, PlotRange -> {{-0.5, 26.5}, {-0.5, 26.5}}, AspectRatio -> Automatic]]]]

选项  (12)

Authentication  (5)

使用 Wolfram LLMKit 服务：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> LLMConfiguration["WolframAIAccess"]], "which element has atomic number 2?"]

为 API 提供身份验证密钥：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>], "which element has atomic number 2?", Authentication -> "<my-key>"]

使用操作系统的密钥链存储 API 密钥：

Wolfram Language code: SystemCredential["ANTHROPIC_API_KEY"] = "<my-key>"

在系统密钥链中查找密钥：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>], "which element has atomic number 2?", Authentication -> SystemCredential]

指定密钥的名称 (只在连接时被查询：)

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>], "which element has atomic number 2?", Authentication :> SystemCredential["MY_OTHER_ANTHROPIC_API_KEY"]]

在系统环境中查找密钥：

Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"GoogleGemini", Automatic}|>], "which element has atomic number 2?", Authentication -> Environment]

通过服务对象认证：

Wolfram Language code: so = ServiceConnect["Cohere"]
Wolfram Language code: ChatEvaluate[ChatObject[LLMEvaluator -> <|"Model" -> {"Cohere", Automatic}|>], "which element has atomic number 2?", Authentication -> so]

LLMEvaluator  (6)

指定用于生成答案的服务：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>]

同时指定服务和模型：

Wolfram Language code: modelname = First@ServiceConnect["Anthropic"]["ChatModelList"]
Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> {"Anthropic", modelname}|>]

默认情况下，文本生成一直持续到生成终止词元为止：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi"]

限制生成的样本（词元）的数量：

Wolfram Language code: ChatEvaluate[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"MaxTokens" -> 3|>]

指定采样应在零温度下进行：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 0|>]

指定高一点儿的温度，使生成的内容有更多的变化：

Wolfram Language code: ChatEvaluate[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 2|>]

指定截断分布前的最大累积概率：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"TotalProbabilityCutoff" -> .5|>]

指定用于生成的服务和模型：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"Model" -> {"OpenAI", "gpt-4"}|>]

指定要自动插入的提示：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"Prompts" -> LLMPrompt["ELI5"]|>]

ProgressReporting  (1)

不报告任何进度信息：

Wolfram Language code: ChatEvaluate[ChatObject[], "What's the tallest mountain?", ProgressReporting -> False]

应用  (1)

Tool Calling  (1)

定义一个可由 LLM 调用的工具：

Wolfram Language code: altimeter = LLMTool[{"altimeter", "gives the altitude at a location"}, {"where" -> "Location"}, GeoElevationData[#where]&]

使用该工具实例化一个聊天对象：

Wolfram Language code: chat = ChatObject[LLMEvaluator -> <|"Tools" -> altimeter|>]

提出一个可以通过该工具获得准确答案的问题：

Wolfram Language code: ChatEvaluate[chat, "what's the altitude of mount Kilimanjaro?"]

可能存在的问题  (1)

评估特定服务的聊天会话时会嵌入身份验证信息：

Wolfram Language code: chat = ChatEvaluate[ChatObject[], "Who are you?", LLMEvaluator -> <|"Model" -> {"Anthropic", Automatic}|>, Authentication -> "<my-key>"]

使用默认设置 AuthenticationInherited，身份验证将无法在不同的服务上运行：

Wolfram Language code: ChatEvaluate[chat, "Who are you?", LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>]

使用 AuthenticationAutomatic 或为新服务重新连接提供显式身份验证：

Wolfram Language code: ChatEvaluate[chat, "Who are you?", LLMEvaluator -> <|"Model" -> {"OpenAI", Automatic}|>, Authentication -> Automatic]
Wolfram Research (2023)，ChatEvaluate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChatEvaluate.html.

文本

Wolfram Research (2023)，ChatEvaluate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChatEvaluate.html.

CMS

Wolfram 语言. 2023. "ChatEvaluate." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ChatEvaluate.html.

APA

Wolfram 语言. (2023). ChatEvaluate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ChatEvaluate.html 年

BibTeX

@misc{reference.wolfram_2026_chatevaluate, author="Wolfram Research", title="{ChatEvaluate}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/ChatEvaluate.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_chatevaluate, organization={Wolfram Research}, title={ChatEvaluate}, year={2023}, url={https://reference.wolfram.com/language/ref/ChatEvaluate.html}, note=[Accessed: 18-August-2026]}