WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChatSubmit[chat,prompt]

フォローアップを追加する prompt をChatObject chat に非同期的に送信する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Authentication  
HandlerFunctions  
HandlerFunctionsKeys  
LLMEvaluator  
アプリケーション  
ツールの呼出し  
関連項目
関連するガイド
履歴
引用書式

ChatSubmit

ChatSubmit[chat,prompt]

フォローアップを追加する prompt をChatObject chat に非同期的に送信する．

詳細とオプション

  • ChatSubmitは，ChatObject内の会話を非同期的に続けるために使われる．
  • ChatSubmitには，外部サービスの認証，請求，インターネット接続が必要である．
  • 次は，prompt の可能な値である．
  • "text"静的テキスト
    LLMPrompt["name"]レポジトリのプロンプト
    StringTemplate[…]テンプレートテキスト
    TemplateObject[…]プロンプト作成用のテンプレート
    Image[…]画像
    {prompt1,…}プロンプトのリスト
  • TemplateObjectで作られたプロンプトはテキストと画像を含むことができる．すべてのLLMが画像入力をサポートする訳ではない．
  • ChatSubmitはTaskObject[…]を返す．
  • 次は，使用可能なオプションである．
  • Authentication Inherited認証スキーム
    HandlerFunctions 生成されたイベントの扱い方
    HandlerFunctionsKeys Automaticハンドラ関数に与えるパラメータ
    LLMEvaluator Inherited使用するLLM設定
  • ChatSubmitの非同期実行の間にさまざまなイベントが生成されることがある．
  • 次は，LLMによってトリガされるイベントである．
  • "ContentChunkReceived"受信された増分メッセージの内容
    "StoppingReasonReceived"受信された生成停止の理由
    "MetadataReceived"受信された他のメタデータ
    "ToolRequestReceived"受信されたLLMToolRequest[…]
    "UsageInformationReceived"受信された増分使用法情報
  • 次は，ローカル処理によってトリガされるイベントである．
  • "ChatObjectGenerated"生成された最終ChatObject[…]
    "ToolResponseGenerated"生成されたLLMToolResponse[…]
  • 次は，タスクフレームワークによってトリガされるイベントである．
  • "FailureOccurred"計算中に生成された失敗
    "TaskFinished"完全に終了したタスク
    "TaskRemoved"削除されつつあるタスク
    "TaskStarted"開始されたタスク
    "TaskStatusChanged"タスクのステータスが変わった
  • HandlerFunctionsf は，すべてのイベントに f を使う．
  • HandlerFunctions-><|…,"eventi"->fi,…|>指定の fi[assoc]は eventiが生成されるたびに評価される．assoc の要素はHandlerFunctionsKeysの設定で指定されたキーを持つ．
  • 次は，HandlerFunctionsKeysによって指定される可能なキーである．
  • "ChatObject"変更されたChatObject[…]
    "ContentChunk"メッセージ部分
    "EventName"処理されているイベント名
    "Failure"タスクが失敗したときに生成される失敗オブジェクト
    "Model"メッセージの生成に使われるモデル
    "Role"メッセージの著者のロール
    "StoppingReason"生成が停止された理由
    "Task"ChatSubmitによって生成されたタスクオブジェクト
    "TaskStatus"タスクの状態
    "TaskUUID"一意的なタスク識別子
    "Timestamp"メッセージのタイムスタンプ
    "ToolRequest"受信されたLLMToolRequest[…]
    "ToolResponse"最後に生成されたLLMToolResponse[…]
    "UsageIncrement"トークンユースエージの更新
    {key1,…}キーのリスト
    Allすべてのキー
    AutomaticHandlerFunctionsに辞書的に現れるキー
  • まだ受け取られていない値はMissing["NotAvailable"]として与えられる．
  • LLMEvaluatorがInheritedに設定されていると，chat で指定されたLLM設定が使われる．
  • LLMEvaluatorは，LLMConfigurationオブジェクトまたは以下の任意のキーを持つ連想に設定できる．
  • "MaxTokens"生成するトークンの最大量
    "Model"ベースモデル
    "PromptDelimiter"プロンプト間に挿入する文字列
    "Prompts"初期プロンプトまたはLLMPromptGeneratorオブジェクト
    "StopTokens"それによって生成を止めるトークン
    "Temperature"サンプリング温度
    "ToolMethod"ツールの呼出しに使用するメソッド
    "Tools"利用できるようにするLLMToolオブジェクトのリスト
    "TopProbabilities"サンプリングクラスのカットオフ
    "TotalProbabilityCutoff"サンプリング確率のカットオフ（核サンプリング）
  • "Model"の有効な形には以下がある．
  • name名前付きのモデル
    {service,name}service からの名前付きのモデル
    <|"Service"service,"Name"name|>完全に指定されたモデル
  • "Prompts"で指定されたプロンプトは，ロールが"System"に設定された chat 内のメッセージの先頭に追加される．
  • 複数のプロンプトは"PromptDelimiter"特性で分割される．
  • 生成されたテキストは分布からサンプリングされる．サンプリングの詳細はLLMEvaluatorの次の特性で指定できる．
  • "Temperature"tAutomatic正の温度 t を使ったサンプリング
    "TopProbabilities"kAutomatic確率が最も高い k 個の確率クラスだけからサンプリングする
    "TotalProbabilityCutoff"pAutomatic少なくとも累積確率 p で最も可能性の高い選択肢の中からサンプリングする (核サンプリング)
  • これらのパラメータのAutomaticという値は，指定された"Model"のデフォルトを使う．
  • 次は，"ToolMethod"の可能な値である．
  • "Service"service のツールメカニズムに依存する
    "Textual"プロンプトに基づいたツールの呼出しを使う
  • 次は，Authenticationの可能な値である．
  • Automatic認証スキームを自動的に選択する
    Inheritedchat から設定を継承する
    Environment環境変数中のキーをチェックする
    SystemCredentialシステムのキーチェーンのキーをチェックする
    ServiceObject[…]サービスオブジェクトから認証を継承する
    "string"明示的なAPIキーを与える
  • AuthenticationAutomaticのとき，関数はEnvironmentおよびSystemCredential内の変数ToUpperCase[service]<>"_API_KEY"をチェックする．それ以外の場合はServiceConnect[service]を使う．
  • ChatSubmitは機械学習を使う．含まれるメソッド，訓練集合，バイアスはWolfram言語のバージョンによって異なることがあり，与えられる結果も異なる可能性がある．

例題

すべて開く すべて閉じる

例  (2)

新規チャットを作成する：

Wolfram Language code: chat = ChatObject[]

会話にメッセージを加え，結果を res に割当てて応答として送信する：

Wolfram Language code: ChatSubmit[chat, "What's the tallest mountain?", HandlerFunctions -> <|"TaskFinished" -> Function[res = #ChatObject]|> ]

生成された会話を調べる：

Wolfram Language code: res

マルチモーダルモデルから生成された応答の一部を受信次第取り出す：

Wolfram Language code: chunks = {}; ChatSubmit[ChatObject[], {"what is this picture?", Entity["TaxonomicSpecies", "FelisCatus::ddvt3"][EntityProperty["TaxonomicSpecies", "Image"]]}, HandlerFunctions -> <|"ContentChunkReceived" -> Function[AppendTo[chunks, #ContentChunk]]|> ]

生成の全ステップを表示する：

Wolfram Language code: chunks

スコープ  (2)

非同期的に新たな会話を始める：

Wolfram Language code: task = ChatSubmit[ChatObject[], "Tell me a joke", HandlerFunctions -> <|"TaskFinished" -> Function[res = #ChatObject]|>]

タスクの現在のステータスを調べる：

Wolfram Language code: task["TaskStatus"]

生成された会話を調べる：

Wolfram Language code: res

既存の会話を非同期的に続ける：

Wolfram Language code: ChatSubmit[ChatObject[Association["LLMEvaluator" -> LLMConfiguration[ Association["Model" -> Association["Service" -> "OpenAI", "Name" -> Automatic, "Alias" -> "Wolfram LLM Service"], "MaxTokens" -> Automatic, "Temperature" -> Automatic, "To ... ]}, FaceForm[RGBColor[0.5372549019607843, 0.5372549019607843, 0.5372549019607843, 1.]]]}, ImageSize -> {{27., 27.}, {27., 27.}}, PlotRange -> {{-0.5, 26.5}, {-0.5, 26.5}}, AspectRatio -> Automatic], "LLMPacletVersion" -> "1.6.3"]], "And what about doctors?", HandlerFunctions -> <|"TaskFinished" -> Function[res = #ChatObject]|>]

生成された会話を調べる：

Wolfram Language code: res

オプション  (14)

Authentication  (4)

APIのための認証キーを与える：

Wolfram Language code: ChatSubmit[ChatObject[], "which element has atomic number 2?", Authentication -> <|"APIKey" -> "1234abcd"|>]

システムのキーチェーンの中にキーを探す：

Wolfram Language code: ChatSubmit[ChatObject[], "which element has atomic number 2?", Authentication -> SystemCredential]

キーの名前を指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "which element has atomic number 2?", Authentication -> {SystemCredential, SystemCredentialKey -> "OPENAI_API_KEY"}]

システム環境の中にキーを探す：

Wolfram Language code: ChatSubmit[ChatObject[], "which element has atomic number 2?", Authentication -> Environment]

サービスオブジェクトを介して認証する：

Wolfram Language code: so = ServiceConnect["OpenAI"]
Wolfram Language code: ChatSubmit[ChatObject[], "which element has atomic number 2?", Authentication -> so]

HandlerFunctions  (2)

生成された全イベント名をメッセージウィンドウに出力する：

Wolfram Language code: ChatSubmit[ ChatObject[], "the first 20 digits of Pi", HandlerFunctions -> Print, HandlerFunctionsKeys -> {"EventName"} ]

存在しないモデルに対してサービスが生成した失敗を捉える：

Wolfram Language code: ChatSubmit[ ChatObject[LLMEvaluator -> <|"Model" -> <|"Service" -> "OpenAI", "Name" -> "WrongName"|>|>], "the first 20 digits of Pi", HandlerFunctions -> <|"FailureOccurred" -> Function@MessageDialog[#Failure]|> ]

HandlerFunctionsKeys  (3)

ハンドラ関数に渡されるハンドラ関数のキーを明示的にリストする：

Wolfram Language code: ChatSubmit[ ChatObject[], "the first 20 digits of Pi", HandlerFunctions -> <|"MetadataReceived" -> MessageDialog|>, HandlerFunctionsKeys -> {"Role", "Model", "Timestamp"} ]

ハンドラ関数にあるスロットからHandlerFunctionsKeysの値を辞書的に推測するように設定する（デフォルト）：

Wolfram Language code: ChatSubmit[ ChatObject[], "the first 20 digits of Pi", HandlerFunctions -> <|"MetadataReceived" -> Function[MessageDialog[{#Role, #Model, #Timestamp}]]|>, HandlerFunctionsKeys -> Automatic ]

すべてのハンドラ関数のキーをハンドラ関数の引数に含める：

Wolfram Language code: ChatSubmit[ ChatObject[], "the first 20 digits of Pi", HandlerFunctions -> <|"MetadataReceived" -> MessageDialog|>, HandlerFunctionsKeys -> All ]

LLMEvaluator  (5)

答を生成するサービスを指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> <|"Service" -> "Anthropic"|>|>]

サービスとモデルの両方を指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> <|"Service" -> "MistralAI", "Name" -> "mistral-medium"|>|>]

デフォルトで，テキスト生成は終了トークンが生成されるまで続く：

Wolfram Language code: ChatSubmit[ChatObject[], "the first 20 digits of Pi", HandlerFunctions -> <|"StoppingReasonReceived" -> Function@MessageDialog[#StoppingReason]|>]

生成するサンプル（トークン）数を制限する：

Wolfram Language code: ChatSubmit[ChatObject[], "the first 20 digits of Pi", LLMEvaluator -> <|"MaxTokens" -> 3|>, HandlerFunctions -> <|"StoppingReasonReceived" -> Function@MessageDialog[#StoppingReason]|>]

サンプリングは零度で行うように指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 0|>, HandlerFunctions -> <|"TaskFinished" -> Function[res1 = #ChatObject]|>]

高い温度を指定して生成されるものがより変化するようにする：

Wolfram Language code: ChatSubmit[ChatObject[], "Tell me three colors", LLMEvaluator -> <|"Temperature" -> 2|>, HandlerFunctions -> <|"TaskFinished" -> Function[res2 = #ChatObject]|>]

結果を比較する：

Wolfram Language code: res1 res2

分布を切断する前に最大累積確率を指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"TotalProbabilityCutoff" -> .5|>]

自動的に会話に追加するプロンプトを指定する：

Wolfram Language code: ChatSubmit[ChatObject[], "What's the plural of mouse?", LLMEvaluator -> <|"Prompts" -> LLMPrompt["ELI5"]|>]

アプリケーション  (1)

ツールの呼出し  (1)

LLMが呼び出せるツールを定義する：

Wolfram Language code: altimeter = LLMTool[{"altimeter", "gives the altitude at a location"}, {"where" -> "Location"}, GeoElevationData[#where]&]

このツールでチャットオブジェクトのインスタンスを作成する：

Wolfram Language code: chat = ChatObject[LLMEvaluator -> <|"Tools" -> altimeter, "ToolMethod" -> "Service"|>]

ツールを使って厳密な答が得られる質問をする：

Wolfram Language code: ChatSubmit[chat, "what's the altitude of mount Kilimanjaro?", HandlerFunctions -> <|"TaskFinished" -> Function[res = #ChatObject]|>]

生成された会話を調べる：

Wolfram Language code: res
Wolfram Research (2025), ChatSubmit, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChatSubmit.html.

テキスト

Wolfram Research (2025), ChatSubmit, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChatSubmit.html.

CMS

Wolfram Language. 2025. "ChatSubmit." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ChatSubmit.html.

APA

Wolfram Language. (2025). ChatSubmit. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChatSubmit.html

BibTeX

@misc{reference.wolfram_2026_chatsubmit, author="Wolfram Research", title="{ChatSubmit}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/ChatSubmit.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_chatsubmit, organization={Wolfram Research}, title={ChatSubmit}, year={2025}, url={https://reference.wolfram.com/language/ref/ChatSubmit.html}, note=[Accessed: 06-September-2026]}