WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Circle[{x,y},r]

半径 r で{x,y}を中心とする円を表す．

Circle[{x,y}]

半径1の円を与える．

Circle[{x,y},{rx,ry}]

半軸の長さが rx と ry の，座標軸と平行である楕円を与える．

Circle[{x,y},…,{θ1,θ2}]

角 θ1と θ2で与えられる円状のもの，つまり楕円の円弧を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Circle

Circle[{x,y},r]

半径 r で{x,y}を中心とする円を表す．

Circle[{x,y}]

半径1の円を与える．

Circle[{x,y},{rx,ry}]

半軸の長さが rx と ry の，座標軸と平行である楕円を与える．

Circle[{x,y},…,{θ1,θ2}]

角 θ1と θ2で与えられる円状のもの，つまり楕円の円弧を与える．

詳細

  • パラメータ設定の異なるCircleは，弧，円弧，半円，楕円等としても知られている．
  • Circleは，幾何学領域として，またグラフィックスプリミティブとして使うことができる．
  • Circle[]はCircle[{0,0}]に等しい． »
  • Circleは曲線を表す．
  • 角は，正の x 方向から反時計回りにラジアン単位で測られる．
  • CircleはGraphicsで使うことができる．
  • グラフィックスでは，点{x,y}と半径 r および{rx,ry}はScaled，Offset，ImageScaled，Dynamicの各式でよい．
  • グラフィックスの描画は，Thickness，Dashing，色等の指示子の影響を受ける．
  • CircleはGeometricSceneの記号的な点や数量と一緒に使うことができる，

予備知識

  • Circleは，平面上の円，楕円，あるいは円／楕円の円弧を表すグラフィックスおよび幾何のプリミティブである．Circle[{x,y},r]はにおける{x,y}を中心とする半径 r の円を，Circle[{x,y},{rx,ry}]はにおける中心が{x,y}で半軸の長さが rxと ryの軸と平行な楕円を，Circle[{x,y},…,{θ1,θ2}]は（楕円である可能性が高い）{x,y}を中心とした正の 軸から時計回りにラジアン単位で測った角度が θ1から θ2までの円弧を表す．略記形式のCircle[{x,y}]はCircle[{x,y},1]に等しく，Circle[] を評価すると自動的にCircle[{0,0},1]になる．
  • CircleオブジェクトはGraphics式の中に置いてフォーマットすることができる．理論的な円の次元は1で太さは0であるが，便宜上，フォーマットされたCircleオブジェクトは，デフォルトで，有限の太さを持って描画される点に注意のこと．グラフィックス内のCircleオブジェクトの外観は，Thickness，AbsoluteThickness，Thick，Thin等の太さの指示子，Dashing，AbsoluteDashing，Dashed，Dotted，DotDashed等の破線指示子，Red等の色指示子，不透明度／透明度の指示子Opacity，スタイルオプションAntialiasingを使って変更することができる．
  • Circleは，計算を行うべき領域指定としても使うことができる．例えば，Integrate[1,{x, y}∈Circle[{0,0},r]]とArcLength[Circle[{x,y},r]]はどちらも円周 を返す．
  • CirclePointsを使って円周上の等間隔に並んだ位置を与えることができる．
  • Circleは他の数多くのシンボルに関係している．CircleはRegionBoundary[Disk[{x,y},r]]を使って計算できるような円板の境界を表す．CylinderおよびSphereは，より高次元における円の相似形と考えることができる．Circle[{x,y},r]は，Sphere[{x,y},r]，ImplicitRegion[(x-u)2+(y-v)2r2,{u,v}]，あるいはParametricRegion[{x+r Cos[t],y+r Sin[t]},{t,0,2π}]を使って表すことができる．PlaneCurveData["entity","property"]あるいはEntityValue[Entity["PlaneCurve","entity"],"property"]を使って標準位置にある円およびその異形の計算済みの特性を得ることができる．"entity"には，"Circle"，"CircularArc"，"Ellipse"，"Semicircle"等の一つを使う．

例題

すべて開く すべて閉じる

例  (5)

単位円：

Wolfram Language code: Graphics[Circle[]]

円弧：

Wolfram Language code: Graphics[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

楕円：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 4}]]

さまざまなスタイルの円：

Wolfram Language code: {Graphics[{Red, Circle[]}], Graphics[{Thick, Circle[]}], Graphics[{Dashed, Circle[]}], Graphics[{Red, Thick, Dashed, Circle[]}]}

円のArcLength：

Wolfram Language code: ArcLength[Circle[]]

長さ，すなわち円弧：

Wolfram Language code: ArcLength[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

スコープ  (23)

グラフィックス  (13)

指定  (6)

半径を指定する：

Wolfram Language code: Graphics[{Circle[{0, 0}, 1], Circle[{0, 0}, 3], Circle[{0, 0}, 5]}]

中心を指定する：

Wolfram Language code: Graphics[{Circle[{0, 0}, 1], Circle[{1, 1}, 1], Circle[{2, 2}, 1]}]

円弧：

Wolfram Language code: Graphics[Circle[{0, 0}, 1, {0, 4Pi / 3}]]
Wolfram Language code: Graphics[Circle[{0, 0}, 1, {4Pi / 3, 2Pi}]]

楕円：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 2}]]

楕円弧：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 2}, {0, 4Pi / 3}]]

原点における単位円の短縮形：

Wolfram Language code: Graphics[Circle[], Axes -> True]

スタイリング  (3)

太さが異なる円：

Wolfram Language code: Table[Graphics[{Thickness[i], Circle[]}], {i, {Tiny, Small, Medium, Large}}]

スケールされたサイズによる太さ：

Wolfram Language code: Table[Graphics[{Thickness[i], Circle[]}], {i, {.05, .1, .2}}]

印刷用ポイント数による太さ：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], Circle[]}], {i, {1, 5, 10}}]

破線による円：

Wolfram Language code: {Graphics[{Dashed, Circle[]}], Graphics[{Dotted, Circle[]}], Graphics[{DotDashed, Circle[]}]}

彩色された円：

Wolfram Language code: Table[Graphics[{c, Circle[]}], {c, {Red, Green, Blue, Yellow}}]

座標  (4)

スケールされた(Scaled)座標と半径を使う：

Wolfram Language code: Graphics[Circle[Scaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, Scaled[.25]], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, Scaled[{.5, .25}]], Frame -> True]

画像がスケールされた(ImageScaled)座標と半径を使う：

Wolfram Language code: Graphics[Circle[ImageScaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, ImageScaled[{.5, .25}]], Frame -> True]

Offset座標を使う：

Wolfram Language code: Graphics[Circle[Offset[{10, 10}, {0, 0}], .5], Frame -> True]

Offsetを使って半径を印刷用ポイント数で指定する：

Wolfram Language code: Graphics[Circle[{0, 0}, Offset[{10, 40}]], Frame -> True]

領域  (10)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

幾何次元：

Wolfram Language code: RegionDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

点の帰属判定：

Wolfram Language code: {RegionMember[Circle[], {0, 1}], RegionMember[Circle[], {0, 0}]}

点の帰属条件を求める：

Wolfram Language code: RegionMember[Circle[{Subscript[c, 1], Subscript[c, 2]}, {Subscript[r, 1], Subscript[r, 2]}], {x, y}]

円弧長：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {ArcLength[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Gray, ℛ}, {Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {1, 0}]}

単位円についての最近点までの距離：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1}], SignedRegionDistance[ℛ, {1, 0}]}

単位円までの符号付き距離：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

領域内の最近点：

Wolfram Language code: ℛ = Circle[{0, 0}, {3, 2}];
Wolfram Language code: {RegionNearest[ℛ, {0, 3}], RegionNearest[ℛ, {3, 0}]}

最近点：

Wolfram Language code: pts = Join[Table[4{Cos[k 2 π / 10], Sin[k 2π / 10]}, {k, 0., 9}], Table[{k, 0}, {k, -3., 3, 0.6}]]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{ℛ, {Thin, StandardGray, Line[Transpose[{pts, nst}]]}, {StandardRed, Point[pts]}, {StandardCyan, Point[nst]}}], PointLegend[{StandardRed, StandardCyan}, {"start", "nearest"}]]

円は有界である：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: BoundedRegionQ[ℛ]

領域を求める：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

円上でIntegrate：

Wolfram Language code: ℛ = Circle[{Subscript[c, 1], Subscript[c, 2]}, r];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

円上で最適化する：

Wolfram Language code: ℛ = Circle[{1, 2}, 3];
Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]//Simplify

円内で方程式を解く：

Wolfram Language code: ℛ = Circle[{1, 2}, 3];
Wolfram Language code: Solve[y == 2x + 1 && {x, y}∈Circle[], {x, y}]
Wolfram Language code: Graphics[{{StandardBlue, Circle[]}, {Gray, InfiniteLine[{0, 1}, {1, 2}]}, {Red, PointSize[Medium], Point[{x, y} /. %]}}, Frame -> True]

アプリケーション  (8)

円の四方充填：

Wolfram Language code: Graphics[Table[Circle[{i, j}, 1 / 2], {i, 7}, {j, 5}]]

円の六方充填：

Wolfram Language code: Graphics[Table[Circle[{i + ((-1) ^ j + 1) / 4, Sqrt[3] / 2j}, 1 / 2], {i, 7}, {j, 5}]]

楕円歯車のシミュレーション：

Wolfram Language code: Animate[Module[{a = 4, b = 3, f, r}, f = Sqrt[a ^ 2 - b ^ 2];r = b ^ 2 / (a + f Cos[θ]);Graphics[{Point[{{0, 0}, {2a, 0}}], Rotate[Circle[{-f, 0}, {a, b}], θ, {0, 0}], Translate[Rotate[Circle[{-f, 0}, {a, b}], -ArcTan[ 2 f + r Cos[θ], r Sin[θ]], {0, 0}], {2a, 0}]}, PlotRange -> {{-2a, 4a}, {-2a, 2a}}, ImageSize -> 250]], {θ, 0, 2Pi}, AnimationRunning -> False]

LineとCircleの交点を求める：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-2, -1}, {5, 6}}]; Subscript[ℛ, 2] = Circle[{1, 2}, 3];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

2つの円の交点を求める：

Wolfram Language code: Subscript[ℛ, 1] = Circle[{-1, 0}, 3]; Subscript[ℛ, 2] = Circle[{1, 0}, 3];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

関数の曲率の半径を示す：

Wolfram Language code: y[x_] := Sin[x ^ 2]; r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / y''[x]; c[x_] := Circle[{x, y[x]} + r[x]Normalize[{-y'[x], 1}], Abs[r[x]]];
Wolfram Language code: Show[{Plot[y[x], {x, -2, 2}], Graphics[{c[-1.2], c[0], c[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

外接円とは，平面上の同一線上にはない3点によって定義される円のことである：

Wolfram Language code: pts = {{0, 1}, {-2 / 3, -1 / 3}, {3 / 4, 0}}; circ = Circumsphere[pts];
Wolfram Language code: Graphics[{circ, StandardBlue, Triangle[pts]}]

Circumsphereから半径と外心を抽出することができる：

Wolfram Language code: {c, r} = {First[circ], Last[circ]}
Wolfram Language code: Graphics[{circ, StandardBlue, Triangle[pts], Red, Point[c], Dashed, Line[{c, c + r * Normalize[{1, 1}]}]}]

DelaunayMeshを定義する特性は，どの入力点もメッシュ中の任意のTriangleの外接円には含まれないということである：

Wolfram Language code: SeedRandom[1234]; ℛ = DelaunayMesh[RandomReal[1, {8, 2}]]; circles = Circumsphere@@@Normal@GraphicsComplex[MeshCoordinates[ℛ], MeshCells[ℛ, 2]];
Wolfram Language code: Show[HighlightMesh[ℛ, Style[{0, All}, Directive[Red, PointSize[Medium]]]], Graphics[{Gray, circles}], PlotRange -> {{0, 1}, {0, 1}}]

円状のケーブルに沿って電荷密度を与え，Integrateを使って全電荷を求める：

Wolfram Language code: charge[x_, y_] := x ^ 4 + y ^ 2;
Wolfram Language code: ParametricPlot3D[{Cos[θ], Sin[θ], charge[Cos[θ], Sin[θ]]z}, {θ, 0, 2π}, {z, 0, 1}, Mesh -> None]
Wolfram Language code: Integrate[charge[x, y], {x, y}∈Circle[]]

特性と関係  (10)

Rotateを使って可能なすべての楕円を得る：

Wolfram Language code: Graphics[Rotate[Circle[{0, 0}, {4, 2}], Pi / 6], Axes -> True]

Diskを使って塗り潰された円を作成する：

Wolfram Language code: Graphics[{Pink, Disk[]}]

円の3Dにおける一般化はSphereである：

Wolfram Language code: Graphics3D[Sphere[]]

円の陰的な指定はContourPlotで生成できる：

Wolfram Language code: ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1, 1}, {y, -1, 1}]

円のパラメータ的な指定はParametricPlotで生成できる：

Wolfram Language code: ParametricPlot[{Cos[θ], Sin[θ]}, {θ, 0, 2π}]

Sphereは任意のCircleを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = Sphere[{x, y}, r]; Subscript[ℛ, 2] = Circle[{x, y}, r];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Circumsphereは任意のCircleを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}]; Subscript[ℛ, 2] = Circle[{0, 0}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegionは任意のCircleを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{{1 + 3Cos[t], 2 + 4 Sin[t]}, 0 ≤ t ≤ 2π}, {t}]; Subscript[ℛ, 2] = Circle[{1, 2}, {3, 4}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは任意のCircleを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 == 1, {x, y}]; Subscript[ℛ, 2] = Circle[{0, 0}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Circleはユークリッドノルムのノルム円である：

Wolfram Language code: ℛ = Circle[{0, 0}, 1];
Wolfram Language code: Reduce[{x, y}∈ℛ⧦Norm[{x, y}] == 1, {x, y}, Reals]

考えられる問題  (2)

スケールされた(Scaled)半径の使用はPlotRangeに依存する：

Wolfram Language code: Table[Graphics[Circle[{0, 0}, Scaled[.25]], PlotRange -> {{-n, n}, {-1, 1}}, Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-n, n}, None}}], {n, {1, 2, 3}}]

ImageScaledのサイズの使用はImageSizeとAspectRatioに依存する：

Wolfram Language code: Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> n], {n, {50, 70, 100}}]
Wolfram Language code: Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> 100, AspectRatio -> n], {n, {1, 1 / 2, 1 / 3}}]

おもしろい例題  (4)

ランダムな円：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Circle[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

生命の種：

Wolfram Language code: Graphics[{Thick, Orange, Circle[], Table[Circle[{Cos[2 Pi i / 6], Sin[2Pi i / 6]}, 1], {i, 6}]}]

一群の円：

Wolfram Language code: Graphics[Table[{Hue[t / 20], Circle[{Cos[2Pi t / 20], Sin[2Pi t / 20]}, 1]}, {t, 20}]]

陰陽：

Wolfram Language code: Animate[Graphics[{Thick, Circle[{0, 0}, 2, {0, Pi}], Circle[{0, 0}, 2, {Pi, 2Pi}], Circle[{-1, 0}, 1, {Pi, 2Pi}], Circle[{1, 0}, 1, {0, Pi}]}, PlotRange -> 2.1, ImageSize -> 150] /. Circle[x__] :> Rotate[Circle[x], d Degree, {0, 0}], {d, 0, 360}, AnimationRunning -> False]
Wolfram Research (1991), Circle, Wolfram言語関数， https://reference.wolfram.com/language/ref/Circle.html （2014年に更新）.

テキスト

Wolfram Research (1991), Circle, Wolfram言語関数， https://reference.wolfram.com/language/ref/Circle.html （2014年に更新）.

CMS

Wolfram Language. 1991. "Circle." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Circle.html.

APA

Wolfram Language. (1991). Circle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Circle.html

BibTeX

@misc{reference.wolfram_2026_circle, author="Wolfram Research", title="{Circle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Circle.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_circle, organization={Wolfram Research}, title={Circle}, year={2014}, url={https://reference.wolfram.com/language/ref/Circle.html}, note=[Accessed: 13-September-2026]}