WOLFRAM

Wolfram 语言与系统参考资料中心

Circle[{x,y},r]

表示半径为 r、圆心在 {x,y} 的圆.

Circle[{x,y}]

给出半径为1的圆.

Circle[{x,y},{rx,ry}]

给出半轴长度为 rx 和 ry，取向平行于坐标轴的椭圆.

Circle[{x,y},…,{θ1,θ2}]

给出从角 θ1 到 θ2 的圆弧或椭圆弧.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Circle

Circle[{x,y},r]

表示半径为 r、圆心在 {x,y} 的圆.

Circle[{x,y}]

给出半径为1的圆.

Circle[{x,y},{rx,ry}]

给出半轴长度为 rx 和 ry，取向平行于坐标轴的椭圆.

Circle[{x,y},…,{θ1,θ2}]

给出从角 θ1 到 θ2 的圆弧或椭圆弧.

更多信息

背景

  • Circle 是一个图形和几何图元，表示一个圆、椭圆或平面上的圆弧、椭圆弧. 特殊的是， Circle[{x,y},r] 表示中心在 {x,y} 的 中半径为 r 圆，Circle[{x,y},{rx,ry}] 表示在 中轴对齐填充的椭圆，中心为 {x,y}，半轴长度为 rx 和 ry，Circle[{x,y},…,{θ1,θ2}] 表示（潜在的椭圆）弧，中心在 {x,y}，范围在角度 θ1 与 θ2 之间，在正 轴逆时针度量的弧度. 缩写形式 Circle[{x,y}] 等价于 Circle[{x,y},1]，其中 Circle[] 自动计算为 Circle[{0,0},1].
  • Circle 对象的格式化可以通过把他们放在 Graphics 表达式中进行. 注意，当抽象圆有维度 1 和 0 厚度，方便起见，格式化后的 Circle 对象默认被渲染为有限厚度. 图形中 Circle 对象的外观可通过指定厚度指令，例如，Thickness、AbsoluteThickness、Thick 和 Thin；虚线指令，例如：Dashing、AbsoluteDashing、Dashed、Dotted 和 DotDashed；色彩指令，例如：Red；透明指令 Opacity；以及样式选项 Antialiasing.
  • Circle 还可用于执行计算的区域规范. 例如，Integrate[1,{x, y}∈Circle[{0,0},r]] 和 ArcLength[Circle[{x,y},r]] 均返回周长 .
  • CirclePoints 可用于给定圆上等间隔点的位置.
  • Circle 也与其他符号相关. Circle 表示圆盘的边界，可以用 RegionBoundary[Disk[{x,y},r]] 计算. Cylinder 和 Sphere 可被认为是更高维数圆的类似. Circle[{x,y},r] 也可以使用 Sphere[{x,y},r]、ImplicitRegion[(x-u)2+(y-v)2r2,{u,v}] 或 ParametricRegion[{x+r Cos[t],y+r Sin[t]},{t,0,2π}] 表示. 圆的预计算属性以及标准位置中的变体可使用 PlaneCurveData["entity","property"] 或 EntityValue[Entity["PlaneCurve","entity"],"property"]，其中 "entity" 是 "Circle"、 "CircularArc"、"Ellipse"、"Semicircle" 等其中之一.

范例

打开所有单元 关闭所有单元

基本范例  (5)

一个单位圆：

Wolfram Language code: Graphics[Circle[]]

一段圆弧：

Wolfram Language code: Graphics[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

一个椭圆：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 4}]]

不同风格的圆：

Wolfram Language code: {Graphics[{Red, Circle[]}], Graphics[{Thick, Circle[]}], Graphics[{Dashed, Circle[]}], Graphics[{Red, Thick, Dashed, Circle[]}]}

圆的 ArcLength：

Wolfram Language code: ArcLength[Circle[]]

长度或圆弧：

Wolfram Language code: ArcLength[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

范围  (23)

图形  (13)

规范  (6)

指定半径：

Wolfram Language code: Graphics[{Circle[{0, 0}, 1], Circle[{0, 0}, 3], Circle[{0, 0}, 5]}]

指定圆心：

Wolfram Language code: Graphics[{Circle[{0, 0}, 1], Circle[{1, 1}, 1], Circle[{2, 2}, 1]}]

一段圆弧：

Wolfram Language code: Graphics[Circle[{0, 0}, 1, {0, 4Pi / 3}]]
Wolfram Language code: Graphics[Circle[{0, 0}, 1, {4Pi / 3, 2Pi}]]

一个椭圆：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 2}]]

一段椭圆弧：

Wolfram Language code: Graphics[Circle[{0, 0}, {3, 2}, {0, 4Pi / 3}]]

中心在原点的单位圆的简写形式：

Wolfram Language code: Graphics[Circle[], Axes -> True]

样式化  (3)

具有不同粗细度的圆：

Wolfram Language code: Table[Graphics[{Thickness[i], Circle[]}], {i, {Tiny, Small, Medium, Large}}]

尺度缩放的粗细度：

Wolfram Language code: Table[Graphics[{Thickness[i], Circle[]}], {i, {.05, .1, .2}}]

以打印机点为单位的粗细度：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], Circle[]}], {i, {1, 5, 10}}]

虚线或点划线圆：

Wolfram Language code: {Graphics[{Dashed, Circle[]}], Graphics[{Dotted, Circle[]}], Graphics[{DotDashed, Circle[]}]}

彩色圆：

Wolfram Language code: Table[Graphics[{c, Circle[]}], {c, {Red, Green, Blue, Yellow}}]

坐标  (4)

利用 Scaled 调整坐标和半径：

Wolfram Language code: Graphics[Circle[Scaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, Scaled[.25]], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, Scaled[{.5, .25}]], Frame -> True]

利用 ImageScaled 调整坐标和半径：

Wolfram Language code: Graphics[Circle[ImageScaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Circle[{0, 0}, ImageScaled[{.5, .25}]], Frame -> True]

利用 Offset 调整坐标：

Wolfram Language code: Graphics[Circle[Offset[{10, 10}, {0, 0}], .5], Frame -> True]

利用 Offset 指明打印机打印点的半径：

Wolfram Language code: Graphics[Circle[{0, 0}, Offset[{10, 40}]], Frame -> True]

区域  (10)

嵌入维数：

Wolfram Language code: RegionEmbeddingDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

几何维数：

Wolfram Language code: RegionDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

点成员检验：

Wolfram Language code: {RegionMember[Circle[], {0, 1}], RegionMember[Circle[], {0, 0}]}

得到点成员的条件：

Wolfram Language code: RegionMember[Circle[{Subscript[c, 1], Subscript[c, 2]}, {Subscript[r, 1], Subscript[r, 2]}], {x, y}]

弧长：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {ArcLength[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Gray, ℛ}, {Red, Point[c]}}]

从一个点的距离：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {1, 0}]}

到单位圆上最近点的距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

从一个点的有符号距离：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1}], SignedRegionDistance[ℛ, {1, 0}]}

到单位圆的有符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

区域上最近的点：

Wolfram Language code: ℛ = Circle[{0, 0}, {3, 2}];
Wolfram Language code: {RegionNearest[ℛ, {0, 3}], RegionNearest[ℛ, {3, 0}]}

最近的点：

Wolfram Language code: pts = Join[Table[4{Cos[k 2 π / 10], Sin[k 2π / 10]}, {k, 0., 9}], Table[{k, 0}, {k, -3., 3, 0.6}]]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{ℛ, {Thin, StandardGray, Line[Transpose[{pts, nst}]]}, {StandardRed, Point[pts]}, {StandardCyan, Point[nst]}}], PointLegend[{StandardRed, StandardCyan}, {"start", "nearest"}]]

圆是有界的：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: BoundedRegionQ[ℛ]

得到它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

在圆上进行 Integrate：

Wolfram Language code: ℛ = Circle[{Subscript[c, 1], Subscript[c, 2]}, r];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在圆上进行最优化：

Wolfram Language code: ℛ = Circle[{1, 2}, 3];
Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]//Simplify

求解圆上的方程：

Wolfram Language code: ℛ = Circle[{1, 2}, 3];
Wolfram Language code: Solve[y == 2x + 1 && {x, y}∈Circle[], {x, y}]
Wolfram Language code: Graphics[{{StandardBlue, Circle[]}, {Gray, InfiniteLine[{0, 1}, {1, 2}]}, {Red, PointSize[Medium], Point[{x, y} /. %]}}, Frame -> True]

应用  (8)

圆的方形堆垛：

Wolfram Language code: Graphics[Table[Circle[{i, j}, 1 / 2], {i, 7}, {j, 5}]]

圆的六方堆垛：

Wolfram Language code: Graphics[Table[Circle[{i + ((-1) ^ j + 1) / 4, Sqrt[3] / 2j}, 1 / 2], {i, 7}, {j, 5}]]

椭圆齿轮的模拟：

Wolfram Language code: Animate[Module[{a = 4, b = 3, f, r}, f = Sqrt[a ^ 2 - b ^ 2];r = b ^ 2 / (a + f Cos[θ]);Graphics[{Point[{{0, 0}, {2a, 0}}], Rotate[Circle[{-f, 0}, {a, b}], θ, {0, 0}], Translate[Rotate[Circle[{-f, 0}, {a, b}], -ArcTan[ 2 f + r Cos[θ], r Sin[θ]], {0, 0}], {2a, 0}]}, PlotRange -> {{-2a, 4a}, {-2a, 2a}}, ImageSize -> 250]], {θ, 0, 2Pi}, AnimationRunning -> False]

求 Line 和 Circle 的交点：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-2, -1}, {5, 6}}]; Subscript[ℛ, 2] = Circle[{1, 2}, 3];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

求两个圆的交点：

Wolfram Language code: Subscript[ℛ, 1] = Circle[{-1, 0}, 3]; Subscript[ℛ, 2] = Circle[{1, 0}, 3];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

说明函数的曲率半径：

Wolfram Language code: y[x_] := Sin[x ^ 2]; r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / y''[x]; c[x_] := Circle[{x, y[x]} + r[x]Normalize[{-y'[x], 1}], Abs[r[x]]];
Wolfram Language code: Show[{Plot[y[x], {x, -2, 2}], Graphics[{c[-1.2], c[0], c[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

外接圆是由三个非共线点所确定的平面上的圆：

Wolfram Language code: pts = {{0, 1}, {-2 / 3, -1 / 3}, {3 / 4, 0}}; circ = Circumsphere[pts];
Wolfram Language code: Graphics[{circ, StandardBlue, Triangle[pts]}]

半径和外接圆圆心可以从 Circumsphere 提取：

Wolfram Language code: {c, r} = {First[circ], Last[circ]}
Wolfram Language code: Graphics[{circ, StandardBlue, Triangle[pts], Red, Point[c], Dashed, Line[{c, c + r * Normalize[{1, 1}]}]}]

DelaunayMesh 的限定属性是在网格中任何 Triangle 的外接圆中不含有输入点：

Wolfram Language code: SeedRandom[1234]; ℛ = DelaunayMesh[RandomReal[1, {8, 2}]]; circles = Circumsphere@@@Normal@GraphicsComplex[MeshCoordinates[ℛ], MeshCells[ℛ, 2]];
Wolfram Language code: Show[HighlightMesh[ℛ, Style[{0, All}, Directive[Red, PointSize[Medium]]]], Graphics[{Gray, circles}], PlotRange -> {{0, 1}, {0, 1}}]

已知沿着圆形线圈的电荷密度，使用 Integrate 求总电荷：

Wolfram Language code: charge[x_, y_] := x ^ 4 + y ^ 2;
Wolfram Language code: ParametricPlot3D[{Cos[θ], Sin[θ], charge[Cos[θ], Sin[θ]]z}, {θ, 0, 2π}, {z, 0, 1}, Mesh -> None]
Wolfram Language code: Integrate[charge[x, y], {x, y}∈Circle[]]

属性和关系  (10)

利用 Rotate 得出所有可能的椭圆：

Wolfram Language code: Graphics[Rotate[Circle[{0, 0}, {4, 2}], Pi / 6], Axes -> True]

利用 Disk 生成一个实心圆：

Wolfram Language code: Graphics[{Pink, Disk[]}]

三维化通则是 Sphere：

Wolfram Language code: Graphics3D[Sphere[]]

一个圆的隐式说明可以由 ContourPlot 生成：

Wolfram Language code: ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1, 1}, {y, -1, 1}]

一个圆的参数式说明可以由 ParametricPlot 生成：

Wolfram Language code: ParametricPlot[{Cos[θ], Sin[θ]}, {θ, 0, 2π}]

Sphere 可以表示任意 Circle：

Wolfram Language code: Subscript[ℛ, 1] = Sphere[{x, y}, r]; Subscript[ℛ, 2] = Circle[{x, y}, r];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Circumsphere可以表示任意 Circle：

Wolfram Language code: Subscript[ℛ, 1] = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}]; Subscript[ℛ, 2] = Circle[{0, 0}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 可以表示任意 Circle：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{{1 + 3Cos[t], 2 + 4 Sin[t]}, 0 ≤ t ≤ 2π}, {t}]; Subscript[ℛ, 2] = Circle[{1, 2}, {3, 4}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任意 Circle：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 == 1, {x, y}]; Subscript[ℛ, 2] = Circle[{0, 0}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Circle 是欧几里德范数的范数圆：

Wolfram Language code: ℛ = Circle[{0, 0}, 1];
Wolfram Language code: Reduce[{x, y}∈ℛ⧦Norm[{x, y}] == 1, {x, y}, Reals]

可能存在的问题  (2)

Scaled 半径的使用取决于 PlotRange：

Wolfram Language code: Table[Graphics[Circle[{0, 0}, Scaled[.25]], PlotRange -> {{-n, n}, {-1, 1}}, Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-n, n}, None}}], {n, {1, 2, 3}}]

ImageScaled 尺寸的使用取决于 ImageSize 和 AspectRatio：

Wolfram Language code: Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> n], {n, {50, 70, 100}}]
Wolfram Language code: Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> 100, AspectRatio -> n], {n, {1, 1 / 2, 1 / 3}}]

巧妙范例  (4)

随机圆：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Circle[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

生命的种子：

Wolfram Language code: Graphics[{Thick, Orange, Circle[], Table[Circle[{Cos[2 Pi i / 6], Sin[2Pi i / 6]}, 1], {i, 6}]}]

圆的家族：

Wolfram Language code: Graphics[Table[{Hue[t / 20], Circle[{Cos[2Pi t / 20], Sin[2Pi t / 20]}, 1]}, {t, 20}]]

阴与阳：

Wolfram Language code: Animate[Graphics[{Thick, Circle[{0, 0}, 2, {0, Pi}], Circle[{0, 0}, 2, {Pi, 2Pi}], Circle[{-1, 0}, 1, {Pi, 2Pi}], Circle[{1, 0}, 1, {0, Pi}]}, PlotRange -> 2.1, ImageSize -> 150] /. Circle[x__] :> Rotate[Circle[x], d Degree, {0, 0}], {d, 0, 360}, AnimationRunning -> False]
Wolfram Research (1991)，Circle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Circle.html （更新于 2014 年）.

文本

Wolfram Research (1991)，Circle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Circle.html （更新于 2014 年）.

CMS

Wolfram 语言. 1991. "Circle." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Circle.html.

APA

Wolfram 语言. (1991). Circle. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Circle.html 年

BibTeX

@misc{reference.wolfram_2026_circle, author="Wolfram Research", title="{Circle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Circle.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_circle, organization={Wolfram Research}, title={Circle}, year={2014}, url={https://reference.wolfram.com/language/ref/Circle.html}, note=[Accessed: 13-September-2026]}