WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CirclePoints[n]

単位円上に等間隔で置かれた n 個の点の位置を与える．

CirclePoints[r,n]

半径 r の円上に等間隔で置かれた n 個の点の位置を与える．

CirclePoints[{r,θ1},n]

軸に対して角度 θ1から始める．

CirclePoints[{x,y},rspec,n]

円の中心を{x,y}に置く．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CirclePoints

CirclePoints[n]

単位円上に等間隔で置かれた n 個の点の位置を与える．

CirclePoints[r,n]

半径 r の円上に等間隔で置かれた n 個の点の位置を与える．

CirclePoints[{r,θ1},n]

軸に対して角度 θ1から始める．

CirclePoints[{x,y},rspec,n]

円の中心を{x,y}に置く．

詳細

  • CirclePoints[n]は，正の整数 n について，底辺が水平の正 n 角形の頂点のリストを生成する．
  • CirclePoints[n]の n は厳密な整数ではなくてもよい．連続するベクトル間の角度は，常にである．
  • 明示的にQuantityオブジェクトとして与えられた場合以外は，角度 θ1は 軸から始めて反時計回りに進むラジアン単位であるとみなされる（Degreeをかけて度から変換することができる）．
  • 角度 θ1は，与えられていない場合にはベクトルが整数 n について底辺が水平な正多角形に対応するように π/n-π/2であるとみなされる．
  • CirclePointsの引数は，n 以外はすべて記号的なものでよい．また，Quantityオブジェクトでもよい．

例題

すべて開く すべて閉じる

例  (3)

正三角形の角：

Wolfram Language code: CirclePoints[3]

五角形を描く：

Wolfram Language code: Graphics[Polygon[CirclePoints[5]]]

正七角形の角に向かう単位ベクトルを描く：

Wolfram Language code: Graphics[Arrow[{{0, 0}, #}]& /@ CirclePoints[7]]

スコープ  (6)

水平と垂直の辺を持ち，中心のある正方形の角：

Wolfram Language code: CirclePoints[4]

サイズ の正方形の角：

Wolfram Language code: CirclePoints[s / Sqrt[2], 4]

軸と並んだ4つのユニタリベクトル：

Wolfram Language code: CirclePoints[{1, 0}, 4]

上記を別の点に移動させる：

Wolfram Language code: CirclePoints[{x, y}, {1, 0}, 4]

任意の点，任意のサイズあるいは方向の，任意の正方形の4つの角：

Wolfram Language code: CirclePoints[{x, y}, {s, θ}, 4]

Quantity半径を使う：

Wolfram Language code: CirclePoints[Quantity[2, "Meters"], 4]

初期角度をQuantityオブジェクトとして指定する：

Wolfram Language code: CirclePoints[{2, Quantity[90, "AngularDegrees"]}, 4]

デフォルトで最も下の辺が水平になった多角形を描く：

Wolfram Language code: Graphics /@ Polygon /@ CirclePoints /@ Range[3, 10]

不透明度を使ってこれら全部を一緒に描画する：

Wolfram Language code: Graphics[{Opacity[0.15], Table[Polygon[CirclePoints[n, n]], {n, 3, 10}]}]

特性と関係  (2)

CirclePointsは，1のベキ根の実部と虚部のペアとして再解釈できるペアを返す：

Wolfram Language code: With[{n = 7}, Exp[2Pi I Range[0, n - 1] / n]]
Wolfram Language code: ComplexExpand[ReIm /@ %]
Wolfram Language code: % == CirclePoints[{1, 0}, 7]

CirclePointsは，AngleVectorコールの集合に等しい：

Wolfram Language code: CirclePoints[{1, 0}, 6]
Wolfram Language code: % === AngleVector /@ Most@Range[0, 2Pi, Pi / 3]

インタラクティブな例題  (1)

大きさと辺の数が異なる多角形を構築する：

Wolfram Language code: Manipulate[Graphics[{Arrow[{{0, 0}, #}]& /@ CirclePoints[n], Opacity[0.7], Polygon[CirclePoints[r, n]]}, Axes -> True, PlotRange -> {{-1, 1}, {-1, 1}}], {{r, 0.5}, 0, 1}, {{n, 5}, 2, 10}]

おもしろい例題  (2)

FoldとCirclePointsを組み合せる：

Wolfram Language code: Manipulate[Graphics[Point[Fold[f[n], {{0, 0}}, {6k, 3k, k, 1}]]], {{k, 0.5}, 0, 1}, {{n, 4}, Range[3, 6]}, Initialization :> {f[n_][points_, d_] := Flatten[CirclePoints[#, d, n]& /@ points, 1]}]

CirclePointsとBezierCurveを組み合せる：

Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, #, {1, 0}}]& /@ CirclePoints[8], i Pi / 8], {i, 0, 16}]]
Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, ##, {2, 0}}]& /@ CirclePoints[24], i Pi / 2, {0, 0}], {i, 0, 3}]]
Wolfram Research (2015), CirclePoints, Wolfram言語関数， https://reference.wolfram.com/language/ref/CirclePoints.html.

テキスト

Wolfram Research (2015), CirclePoints, Wolfram言語関数， https://reference.wolfram.com/language/ref/CirclePoints.html.

CMS

Wolfram Language. 2015. "CirclePoints." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CirclePoints.html.

APA

Wolfram Language. (2015). CirclePoints. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CirclePoints.html

BibTeX

@misc{reference.wolfram_2026_circlepoints, author="Wolfram Research", title="{CirclePoints}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CirclePoints.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_circlepoints, organization={Wolfram Research}, title={CirclePoints}, year={2015}, url={https://reference.wolfram.com/language/ref/CirclePoints.html}, note=[Accessed: 10-August-2026]}