WOLFRAM

Wolfram 语言与系统参考资料中心

CirclePoints[n]

给出在单位圆周上均匀分布的 n 个点的位置.

CirclePoints[r,n]

给出在半径为 r 的圆周上均匀分布的 n 个点的位置.

CirclePoints[{r,θ1},n]

从相对于 轴的角度 θ1 开始.

CirclePoints[{x,y},rspec,n]

把圆的中心置于 {x,y}.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CirclePoints

CirclePoints[n]

给出在单位圆周上均匀分布的 n 个点的位置.

CirclePoints[r,n]

给出在半径为 r 的圆周上均匀分布的 n 个点的位置.

CirclePoints[{r,θ1},n]

从相对于 轴的角度 θ1 开始.

CirclePoints[{x,y},rspec,n]

把圆的中心置于 {x,y}.

更多信息

  • 对正整数 n，CirclePoints[n] 生成正 n 边形的顶点列表，该正多边形的底边是水平的.
  • 在 CirclePoints[n] 中，n 不必是精确的整数. 相邻向量间的夹角总是 .
  • 除非显式的以 Quantity 对象的形式给出，角度 θ1 假设是以弧度为单位，正方向为从 轴开始的逆时针方向.（乘以 Degree 就可以转换为角度制单位.）
  • 若没有指定角度 θ1，则它被假设是 π/n-π/2，这样对整数 n 那些向量对应的正多边形底边是水平的.
  • 除了 n 以外 CirclePoints 的其它所有参数都可以是符号. 它们也可以是 Quantity 对象.

范例

打开所有单元 关闭所有单元

基本范例  (3)

等边三角形的角：

Wolfram Language code: CirclePoints[3]

绘制正五边形：

Wolfram Language code: Graphics[Polygon[CirclePoints[5]]]

绘制指向正七边形各角的单位向量：

Wolfram Language code: Graphics[Arrow[{{0, 0}, #}]& /@ CirclePoints[7]]

范围  (6)

横平竖直的正方形各角：

Wolfram Language code: CirclePoints[4]

边长为 的正方形各角：

Wolfram Language code: CirclePoints[s / Sqrt[2], 4]

与坐标轴重合的四个单位向量：

Wolfram Language code: CirclePoints[{1, 0}, 4]

把它们移到另一个起点处：

Wolfram Language code: CirclePoints[{x, y}, {1, 0}, 4]

在任意位置任意大小或朝向的任意正方形的四角：

Wolfram Language code: CirclePoints[{x, y}, {s, θ}, 4]

使用 Quantity 半径：

Wolfram Language code: CirclePoints[Quantity[2, "Meters"], 4]

将初始角度指定为 Quantity 对象：

Wolfram Language code: CirclePoints[{2, Quantity[90, "AngularDegrees"]}, 4]

绘制一系列多边形，底边默认都是水平的：

Wolfram Language code: Graphics /@ Polygon /@ CirclePoints /@ Range[3, 10]

将它们全部绘制在一起，并保持不透明度：

Wolfram Language code: Graphics[{Opacity[0.15], Table[Polygon[CirclePoints[n, n]], {n, 3, 10}]}]

属性和关系  (2)

CirclePoints 返回的数对可以重新被解释为单位根的实部和虚部：

Wolfram Language code: With[{n = 7}, Exp[2Pi I Range[0, n - 1] / n]]
Wolfram Language code: ComplexExpand[ReIm /@ %]
Wolfram Language code: % == CirclePoints[{1, 0}, 7]

CirclePoints 等价于一组 AngleVector 调用：

Wolfram Language code: CirclePoints[{1, 0}, 6]
Wolfram Language code: % === AngleVector /@ Most@Range[0, 2Pi, Pi / 3]

互动范例  (1)

构建不同大小和边数的多边形：

Wolfram Language code: Manipulate[Graphics[{Arrow[{{0, 0}, #}]& /@ CirclePoints[n], Opacity[0.7], Polygon[CirclePoints[r, n]]}, Axes -> True, PlotRange -> {{-1, 1}, {-1, 1}}], {{r, 0.5}, 0, 1}, {{n, 5}, 2, 10}]

巧妙范例  (2)

将 Fold 与 CirclePoints 合用：

Wolfram Language code: Manipulate[Graphics[Point[Fold[f[n], {{0, 0}}, {6k, 3k, k, 1}]]], {{k, 0.5}, 0, 1}, {{n, 4}, Range[3, 6]}, Initialization :> {f[n_][points_, d_] := Flatten[CirclePoints[#, d, n]& /@ points, 1]}]

将 CirclePoints 与 BezierCurve 合用：

Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, #, {1, 0}}]& /@ CirclePoints[8], i Pi / 8], {i, 0, 16}]]
Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, ##, {2, 0}}]& /@ CirclePoints[24], i Pi / 2, {0, 0}], {i, 0, 3}]]
Wolfram Research (2015)，CirclePoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CirclePoints.html.

文本

Wolfram Research (2015)，CirclePoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CirclePoints.html.

CMS

Wolfram 语言. 2015. "CirclePoints." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CirclePoints.html.

APA

Wolfram 语言. (2015). CirclePoints. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CirclePoints.html 年

BibTeX

@misc{reference.wolfram_2026_circlepoints, author="Wolfram Research", title="{CirclePoints}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CirclePoints.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_circlepoints, organization={Wolfram Research}, title={CirclePoints}, year={2015}, url={https://reference.wolfram.com/language/ref/CirclePoints.html}, note=[Accessed: 04-September-2026]}