WolframのWebサイトのコンテンツとインタラクトしたりフォームを送信したりするためには，JavaScriptを有効にしてください．有効にする方法

Wolfram言語＆システムドキュメントセンター

ClosenessCentrality

ClosenessCentrality

ClosenessCentrality[g]

グラフ g の頂点の接近中心性のリストを与える．

ClosenessCentrality[{vw,…}]

規則 vw を使ってグラフ g を指定する．

詳細

ClosenessCentralityは他の頂点への平均距離が短い頂点に高い中心性を与える．
グラフのClosenessCentralityは,として与えられる．は頂点からに接続している他のすべての頂点への距離平均である．
が距離行列なら頂点からに接続している他のすべての頂点へ平均距離はで与えられる．ただし，総和はすべての有限の上で取られ，はに接続している頂点の数である．
孤立した頂点の接近中心性は0であるとみなされる．
ClosenessCentralityは，無向グラフ，有向グラフ，重み付きグラフ，多重グラフ，混合グラフに用いることができる．

例題

すべて開くすべて閉じる

例 (2)

接近中心性を計算する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: ClosenessCentrality[g]

ハイライトする：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

頂点に順位を付ける．最も順位の高い頂点は他のすべての頂点への平均距離が短いものである：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: Part[VertexList[g], Ordering[ClosenessCentrality[g], All, Greater]]

スコープ (7)

ClosenessCentralityは無向グラフに使うことができる：

Wolfram Language code: ClosenessCentrality[[image]]

有向グラフ：

Wolfram Language code: ClosenessCentrality[[image]]

重み付きグラフ：

Wolfram Language code: ClosenessCentrality[[image]]

多重グラフ：

Wolfram Language code: ClosenessCentrality[[image]]

混合グラフ：

Wolfram Language code: ClosenessCentrality[[image]]

規則を使ってグラフを指定する：

Wolfram Language code: ClosenessCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

ClosenessCentralityは大きいグラフに使うことができる：

Wolfram Language code: g = RandomGraph[{10000, 10005}];

Wolfram Language code: ClosenessCentrality[g]//Short//Timing

アプリケーション (9)

他の頂点との相対的な近さによって頂点に順位を付ける：

Wolfram Language code: g = [image];

Wolfram Language code: SortBy[{VertexList[g], ClosenessCentrality[g]}, Last]//Reverse

CycleGraphの接近中心性をハイライトする：

Wolfram Language code:

HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];

Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

コンピュータのアドホックネットワークはSpatialGraphDistributionを使ってモデル化することができる．感染したネットワークの中でウィルスの拡散を助けるコンピュータを求める：

Wolfram Language code: 𝒢 = SpatialGraphDistribution[50, 1.5, BinormalDistribution[{2, 1.5}, 0.3]];

Wolfram Language code: g = VertexReplace[RandomGraph[𝒢], Thread[Range[50] -> Table[Row[{"Computer", i}], {i, 50}]]];

臨界コンピュータ：

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Table[VertexList[g][[i]], {i, Ordering[c, -5]}]

Wolfram Language code: HighlightGraph[g, %, VertexSize -> 2]

イーストのタンパク質相互作用ネットワークで最も重要であると思われる10のタンパク質を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ProteinInteraction"}];

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Table[VertexList[g][[i]], {i, Ordering[c, -10]}]

調整ネットワークで，遺伝子間に転写調節相互作用がある場合，その遺伝子は繋がっている．グローバルな調節遺伝子である確率が最も高い遺伝子を求める：

Wolfram Language code: g = [image];

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

合衆国中西部のある町における社会福祉問題に関心がある10の組織間の情報の流れを表す有向ネットワーク．他のすべての組織と最も有効に情報伝達することが可能な組織を求める：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = ClosenessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

シカゴ郊外を結ぶ道路網で，緊急車両の移動距離を最短にするのに最適な病院と消防署の位置を求める：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = ClosenessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

合衆国のWestern States Power Gridの位相を表す送電網．接近中心性が正規分布に従うことを示す：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];

Wolfram Language code: Shallow[c = ClosenessCentrality[g]]

正規分布を仮定して，最大尤度母数推定を求める：

Wolfram Language code: EstimatedDistribution[c, NormalDistribution[μ, σ]]

もとの分布と推定分布の確率密度関数を視覚的に比較する：

Wolfram Language code: Histogram[c, Automatic, "PDF", Epilog -> First@Plot[PDF[%, x], {x, 0, 0.1}, PlotStyle -> Red]]

頂点数がのグラフの場合，最も中心的な頂点と他のすべての頂点間の接近中心性の距離の差の総和はの逆数である：

Wolfram Language code:

n = 10;
g = StarGraph[n];
c = ClosenessCentrality[g];

Wolfram Language code: {Total[Max[c] - c], (n - 1)(n - 2) / (2n - 3.)}

最も中心の頂点がどれくらい中心であるかを他の頂点との関係で測る：

Wolfram Language code:

closeness[g_] := With[{c = ClosenessCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] * (2n - 3) / ((n - 1)(n - 2))]]

ソーシャルネットワークの集中化：

Wolfram Language code: closeness[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]

Wolfram Language code: closeness[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

特性と関係 (4)

ClosenessCentralityは他の接続可能な頂点への平均距離の逆である：

Wolfram Language code: g = [image];

Wolfram Language code: ClosenessCentrality[g]

接近可能な他の頂点との最大距離の逆：

Wolfram Language code: d = GraphDistanceMatrix[g];

Wolfram Language code: 1. / Map[Mean, DeleteCases[d, 0 | ∞, {2}]]

接近中心性は0から1までである：

Wolfram Language code: Through[{Min, Max}[ClosenessCentrality [RandomGraph[{100, 200}]]]]

無向グラフの接近中心性は各成分の中心性に等しい：

Wolfram Language code: g = GraphDisjointUnion[CycleGraph[3], CycleGraph[3], GraphLayout -> {"PackingLayout" -> "LayeredLeft"}]

Wolfram Language code: ClosenessCentrality[g]

各成分の中心性を計算しても同じ結果が得られる：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]

Wolfram Language code: {ClosenessCentrality[g1], ClosenessCentrality[g2]}

Wolfram Language code: Join@@%

VertexIndexを使って特定の頂点の中心性を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: ClosenessCentrality[g][[VertexIndex[g, "Anna"]]]

Top