Enable JavaScript to interact with content and submit forms on Wolfram websites. Learn how

Wolfram 语言与系统参考资料中心

ClosenessCentrality

ClosenessCentrality

ClosenessCentrality[g]

给出图 g 中顶点的紧密中心度组成的列表.

ClosenessCentrality[{vw,…}]

使用规则 vw 来指定图 g.

更多信息

ClosenessCentrality 对于与每个其它可到达顶点处于较短平均距离的顶点，给出较高的中心度.
图的 ClosenessCentrality 由给出，其中是从顶点到所有与连通的顶点的平均距离.
如果是距离矩阵，那么从顶点到所有连通顶点的平均距离由给出，其中和在所有有限上求得，而是与相连的顶点数目.
孤立顶点的紧密中心度为0.
ClosenessCentrality 适用于无向图、有向图、加权图、多重图和混合图.

范例

打开所有单元关闭所有单元

基本范例 (2)

计算紧密中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: ClosenessCentrality[g]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

对顶点排序. 排得靠前的顶点到所有其他顶点的平均距离较短：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: Part[VertexList[g], Ordering[ClosenessCentrality[g], All, Greater]]

范围 (7)

ClosenessCentrality 可用于无向图：

Wolfram Language code: ClosenessCentrality[[image]]

有向图：

Wolfram Language code: ClosenessCentrality[[image]]

加权图：

Wolfram Language code: ClosenessCentrality[[image]]

多重图：

Wolfram Language code: ClosenessCentrality[[image]]

混合图：

Wolfram Language code: ClosenessCentrality[[image]]

使用规则来指定图：

Wolfram Language code: ClosenessCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

ClosenessCentrality 可用于大规模图：

Wolfram Language code: g = RandomGraph[{10000, 10005}];

Wolfram Language code: ClosenessCentrality[g]//Short//Timing

应用 (9)

根据顶点到其他顶点的相对紧密程度排序：

Wolfram Language code: g = [image];

Wolfram Language code: SortBy[{VertexList[g], ClosenessCentrality[g]}, Last]//Reverse

突出显示 CycleGraph 的紧密中心度：

Wolfram Language code:

HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];

Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree:

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];

Wolfram Language code: cc = ClosenessCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

计算机 ad hoc 网络可以使用 SpatialGraphDistribution 建模. 求可帮助电脑病毒在感染网络里迅速扩散的计算机：

Wolfram Language code: 𝒢 = SpatialGraphDistribution[50, 1.5, BinormalDistribution[{2, 1.5}, 0.3]];

Wolfram Language code: g = VertexReplace[RandomGraph[𝒢], Thread[Range[50] -> Table[Row[{"Computer", i}], {i, 50}]]];

重要计算机：

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Table[VertexList[g][[i]], {i, Ordering[c, -5]}]

Wolfram Language code: HighlightGraph[g, %, VertexSize -> 2]

在酵母的蛋白质作用网络中，求最可能成为重要蛋白质的前10位蛋白质：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ProteinInteraction"}];

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Table[VertexList[g][[i]], {i, Ordering[c, -10]}]

在一个基因管制网络中，如果两个基因之间有可复制的管制交互作用，则称这两个基因是连通的. 求最可能成为全局管制者的基因：

Wolfram Language code: g = [image];

Wolfram Language code: c = ClosenessCentrality[g];

Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

一个有向网络描述美国某中西部城市的社会福利相关的10个机构之间的信息流. 求能够与所有其他机构最有效沟通的机构：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = ClosenessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

一条公路网络连接芝加哥各个郊区. 求医院和消防队的最佳位置，以最小化急救车辆的行驶距离：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = ClosenessCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

一个功率网格网络表示美国 Western States Power Grid 的拓扑图. 证明紧密中心度服从正态分布：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];

Wolfram Language code: Shallow[c = ClosenessCentrality[g]]

假定正态分布，求最大似然参数估计：

Wolfram Language code: EstimatedDistribution[c, NormalDistribution[μ, σ]]

可视化比较原始分布和估计分布的概率密度函数：

Wolfram Language code: Histogram[c, Automatic, "PDF", Epilog -> First@Plot[PDF[%, x], {x, 0, 0.1}, PlotStyle -> Red]]

对于具有个顶点图，最中心顶点和所有其它顶点之间的紧密中心度的差值的最大和是的倒数：

Wolfram Language code:

n = 10;
g = StarGraph[n];
c = ClosenessCentrality[g];

Wolfram Language code: {Total[Max[c] - c], (n - 1)(n - 2) / (2n - 3.)}

测量最中心的顶点与其他顶点的相对中心度：

Wolfram Language code:

closeness[g_] := With[{c = ClosenessCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] * (2n - 3) / ((n - 1)(n - 2))]]

社交网络中心化处理：

Wolfram Language code: closeness[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]

Wolfram Language code: closeness[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

属性和关系 (4)

ClosenessCentrality 是到其他可到达顶点的平均距离的倒数：

Wolfram Language code: g = [image];

Wolfram Language code: ClosenessCentrality[g]

到其他可达到顶点的最大距离的倒数：

Wolfram Language code: d = GraphDistanceMatrix[g];

Wolfram Language code: 1. / Map[Mean, DeleteCases[d, 0 | ∞, {2}]]

紧密中心度位于0和1之间：

Wolfram Language code: Through[{Min, Max}[ClosenessCentrality [RandomGraph[{100, 200}]]]]

一个无向图的紧密中心度等同于每个分量的中心度：

Wolfram Language code: g = GraphDisjointUnion[CycleGraph[3], CycleGraph[3], GraphLayout -> {"PackingLayout" -> "LayeredLeft"}]

Wolfram Language code: ClosenessCentrality[g]

对每个分量计算中心度给出相同的结果：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]

Wolfram Language code: {ClosenessCentrality[g1], ClosenessCentrality[g2]}

Wolfram Language code: Join@@%

使用 VertexIndex 获得特定顶点的中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: ClosenessCentrality[g][[VertexIndex[g, "Anna"]]]

Top