WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CloudExport[expr,"format"]

新たな無名のクラウドオブジェクトに指定のフォーマットで expr をエキスポートする．

CloudExport[expr,"format","uri"]

指定されたURIのクラウドオブジェクトにエキスポートする．

CloudExport[expr,"format",CloudObject["uri"]]

指定されたクラウドオブジェクトにエキスポートする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AppearanceElements  
AutoCopy  
AutoRemove  
Show More Show More
CachePersistence  
CloudBase  
CloudObjectNameFormat  
CloudObjectURLType  
CloudRenderingMethod  
IconRules  
Magnification  
MetaInformation  
Permissions  
SourceLink  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

CloudExport

CloudExport[expr,"format"]

新たな無名のクラウドオブジェクトに指定のフォーマットで expr をエキスポートする．

CloudExport[expr,"format","uri"]

指定されたURIのクラウドオブジェクトにエキスポートする．

CloudExport[expr,"format",CloudObject["uri"]]

指定されたクラウドオブジェクトにエキスポートする．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

画像をクラウドにエキスポートする：

Wolfram Language code: CloudExport[[image], "PNG"]

名前付きのクラウドオブジェクトにエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot"]

スコープ  (1)

文字列で指定された名前付きのクラウドオブジェクトにエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot"]

CloudObjectで指定される名前付きのクラウドオブジェクトにエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", CloudObject["plot"]]

URLで指定される名前付きのクラウドオブジェクトにエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", URL["https://www.wolframcloud.com/obj/documentation/plot"]]

オプション  (13)

AppearanceElements  (1)

外観要素を含まないCSVファイルをエキスポートする：

Wolfram Language code: data = Map[{DateString[#[[1]]], QuantityMagnitude[#[[2]]]}&, Normal[FinancialData["NVDA", Today - Quantity[1, "Month"]]]]; CloudExport[data, "JSON", AppearanceElements -> None]

Web上でオブジェクトを表示する場合，ヘッダやフッタなしで内容のみが表示される：

AutoCopy  (1)

AutoCopyを有効にして式をエキスポートする：

Wolfram Language code: obj = CloudExport[TreeGraph[{12, 13, 14}], "NB", "treeGraph", AutoCopy -> True]

環境ビューURLを用いてCloudObjectを構築する：

Wolfram Language code: CloudObject[obj, CloudObjectURLType -> "Environment"]

URLをクリックしてノートブックを開き，リンク「Create a copy of this file」をクリックしてコピーを作成する：

AutoRemove  (1)

プロットを一時オブジェクトにエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", AutoRemove -> True]

CachePersistence  (1)

ブラウザー内でキャッシュされ，キャッシュのタイムアウトが1日である画像をエキスポートする：

Wolfram Language code: obj = CloudExport[RandomImage[1, {250, 250}, ColorSpace -> "RGB"], "PNG", CachePersistence -> Quantity[1, "Days"]]

応答の「cache-control」ヘッダの値をチェックする：

Wolfram Language code: Lookup[URLRead[obj]["Headers"], "cache-control"]

CloudBase  (1)

オブジェクトを別のクラウドにエキスポートする：

Wolfram Language code: CloudExport[WeatherData[$GeoLocation, "Temperature", "NonMetricValue"], "Text", "temperature", CloudBase -> "https://www.epc.example.com"]

CloudObjectNameFormat  (1)

クラウドオブジェクトをエキスポートして，ユーザUUID形式のURLを返す：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot", CloudObjectNameFormat -> "CloudUserUUID"]

CloudObjectURLType  (1)

クラウドオブジェクトに書き込み，クラウド環境内で開くような形式のURLを返す：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot", CloudObjectURLType -> "Environment"]

CloudRenderingMethod  (1)

自動選択が"Bitmap"であってもインタラクティブに描画されるように，CloudRenderingMethod"InteractiveBoxes"でノートブックをエキスポートする：　

Wolfram Language code: CloudExport[ Notebook[{Cell[BoxData[ToBoxes[DynamicModule[{x = 0}, Table[Slider[Dynamic[x]], 2]]]], "Output"]}], "NB", CloudRenderingMethod -> "InteractiveBoxes"]

IconRules  (1)

アイコンがない式をエキスポートする：

Wolfram Language code: obj = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", IconRules -> None]

式にアイコンがないことを確認する：

Wolfram Language code: Options[obj, IconRules]

Magnification  (1)

4倍の拡大率でノートブックをエキスポートする：

Wolfram Language code: CloudExport[Grid[Partition[Range[9], 3], Frame -> All], "NB", Magnification -> 4]

MetaInformation  (1)

現在の事象のウェブ検索をエキスポートし，現在地として特定された都市をメタ情報に保存する：

Wolfram Language code: obj = CloudExport[WebSearch["events near " <> CommonName[$GeoLocationCity]], "WL", MetaInformation -> {"City" -> $GeoLocationCity}]

後でメタ情報を取り出す：

Wolfram Language code: Options[obj, MetaInformation]

Permissions  (1)

アクセスするのに他のユーザのログインが必要なクラウドオブジェクトをエキスポートする：

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", Permissions -> {"Authenticated" -> "Read"}]

SourceLink  (1)

クラウドオブジェクトがソースの画像をエキスポートする：

Wolfram Language code: source = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plotOrig"]; obj = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "sinePlot", SourceLink -> source]

ソースリンクを見る：

Wolfram Language code: Options[CloudObject["sinePlot"], SourceLink]

アプリケーション  (1)

すべての国リストをCSVファイルとしてWolframクラウド上にエキスポートする：

Wolfram Language code: CloudExport[EntityClass["Country", "Countries"][{"Name", "Population"}] /. q_Quantity :> QuantityMagnitude[q], "CSV", "countriespopulation.csv"]

このデータはCloudImportを使ってインポートできる：

Wolfram Language code: CloudImport["countriespopulation.csv"]//Short

考えられる問題  (1)

クラウド内で特別な動作をするAPIFunctionのような式にCloudExportを使っても，その特別な動作はアクティベートされない：

Wolfram Language code: api = CloudExport[APIFunction[{"P" -> Number, "r" -> Number, "t" -> Number}, #P(1 + #r * #t)&], "WL"]

この式は単にテキストを使って表示されているだけなので，このクラウドオブジェクトを呼び出しても計算は行われない．計算はURLExecuteで可読な形式でインポートされた場合に行われる：

Wolfram Language code: URLExecute[api, {"P" -> 1000, "r" -> 2.3, "t" -> 72}]

使用可能なAPIFunctionを作成するためには，CloudDeployあるいはCloudPublishで配備しなければならない：

Wolfram Language code: api = CloudDeploy[APIFunction[{"P" -> Number, "r" -> Number, "t" -> Number}, #P(1 + #r * #t)&]]

これで，意図したように，呼び出されるとパラメータを読んで関数を評価するようになった：

Wolfram Language code: URLExecute[api, {"P" -> 1000, "r" -> 2.3, "t" -> 72}]
Wolfram Research (2014), CloudExport, Wolfram言語関数， https://reference.wolfram.com/language/ref/CloudExport.html （2019年に更新）.

テキスト

Wolfram Research (2014), CloudExport, Wolfram言語関数， https://reference.wolfram.com/language/ref/CloudExport.html （2019年に更新）.

CMS

Wolfram Language. 2014. "CloudExport." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/CloudExport.html.

APA

Wolfram Language. (2014). CloudExport. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CloudExport.html

BibTeX

@misc{reference.wolfram_2026_cloudexport, author="Wolfram Research", title="{CloudExport}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/CloudExport.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cloudexport, organization={Wolfram Research}, title={CloudExport}, year={2019}, url={https://reference.wolfram.com/language/ref/CloudExport.html}, note=[Accessed: 12-September-2026]}