WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Comap[{f1,f2,…},x]

{f1[x],f2[x],…}を与える．

Comap[fs,x,levelspec]

levelspec で指定された fs の部分を x に適用する．

Comap[fs]

式に適用可能なComapの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Heads  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Comap

Comap[{f1,f2,…},x]

{f1[x],f2[x],…}を与える．

Comap[fs,x,levelspec]

levelspec で指定された fs の部分を x に適用する．

Comap[fs]

式に適用可能なComapの演算子形を表す．

詳細とオプション

  • Comapは，リスト中の各関数を単一の共通引数に適用するためにしばしば使われる． »
  • Comapは標準的なレベル指定を使う．
  • nレベル1からレベル n まで
    Infinityレベル1からInfinityまで
    {n}レベルn のみ
    {n1,n2}レベル n1からレベル n2まで
  • Comapにおける levelspec のデフォルト値は{1}である．
  • 正のレベルは n 指標 n で指定される fsのすべての部分からなる．
  • 負のレベル-n は深さ n の fsのすべての部分からなる．
  • レベル–1は，数，シンボル，下位区分を持たないその他のオブジェクトからなる．
  • レベル0は式全体に相当する．
  • Comapは，オプション設定がHeads->Trueのときは式の頭部とその部分を含む． »
  • Comapは常に完全な新しい式を効率的に構築してこれを評価する． »
  • Comap[fs,x,…]の fs の頭部はListではなくてもよい．
  • fsがAssociationオブジェクトなら，Comap[fs,x]は連想の値を x に適用する． »
  • Comap[fs][x]はComap[fs,x]に等しい．
  • Parallelize[Comap[fs,x]]は，すべてのサブカーネルでComap[fs,x]の並列計算を行う． »

例題

すべて開く すべて閉じる

例  (4)

リストの各要素でxをラップする：

Wolfram Language code: Comap[{f, g, h}, x]

Comapの演算子形を使う：

Wolfram Language code: Comap[{Sin, Cos, Tan}][Pi / 3]

レベル2に共適用する：

Wolfram Language code: Comap[{{Sin, Cos, Tan}, {Csc, Sec, Cot}}, Pi / 3, {2}]

連想中の値の下の式に共適用する：

Wolfram Language code: Comap[<|"a" -> f, "b" -> g, "c" -> h|>, x]

スコープ  (6)

明示的な純関数を使う：

Wolfram Language code: Comap[{1 + f[#]&, 2 + g[#]&, 3 + h[#]&}, x]
Wolfram Language code: Comap[{x |-> x ^ 2, x |-> x ^ 3}, 2]

Comapは任意の頭部を持つ式に使うことができる：

Wolfram Language code: Comap[a + b + c + d, x]
Wolfram Language code: Comap[f ^ a + g ^ b, x, {2}]

ネストしたAssociationの第2レベルにComapする：

Wolfram Language code: Comap[<|"a" -> <|"x" -> f|>, "b" -> <|"y" -> g|>|>, x, {2}]

レベル-1にComapする：

Wolfram Language code: Comap[{Gamma, {Exp, Log}, {{Sin, ArcSin}, {Cos, ArcCos}}}, 0, {-1}]

正負のレベルを混ぜることができる：

Wolfram Language code: Comap[f[f[f[f[f[f]]]]], x, {2, -3}]

各レベルの頭部が異なる場合：

Wolfram Language code: Comap[h0[h1[h2[h3[h4[h5]]]]], x, {2, -3}]

オプション  (1)

Heads  (1)

デフォルトで，式は頭部には共適用されない：

Wolfram Language code: Comap[h[a, b, c], x]
Wolfram Language code: Comap[h[a, b, c], x, Heads -> True]

アプリケーション  (3)

個々の適用の和を形成することで関数の和を適用する：

Wolfram Language code: Comap[f + g + h, x]

微分演算子を適用する：

Wolfram Language code: Comap[(D[#, x]&) + (D[#, x, x]&), f[x]]

補助変数を使わずに値の平方根を表にする：

Wolfram Language code: TableForm[Comap[{Identity, Sqrt}] /@ {0, 1.0, 2.0, 3.0, 4.0}]

特性と関係  (9)

Comapは式の一部で別の式をラップする：

Wolfram Language code: Comap[{f, g, h}, x]

Mapは式で他の式の一部をラップする：

Wolfram Language code: Map[f, {x, y, z}]

Query[list]はComap[list]に等しい：

Wolfram Language code: Query[{Mean, Median, StandardDeviation}][{6, 2, 3, 4, 4, 4, 0}]
Wolfram Language code: Comap[{Mean, Median, StandardDeviation}][{6, 2, 3, 4, 4, 4, 0}]

Query[assoc]もまたComap[assoc]に等しい：

Wolfram Language code: Query[<|"a" -> f, "b" -> g, "c" -> h|>][x]
Wolfram Language code: Comap[<|"a" -> f, "b" -> g, "c" -> h|>][x]

Through[p[f,g,…][x]]はComap[p[f,g,…],x]に等しい：

Wolfram Language code: Through[{f, g, h}[x]]
Wolfram Language code: Comap[{f, g, h}, x]

これをComapの演算子形と比較する：

Wolfram Language code: Comap[{f, g, h}][x]

Comap[p[f,g,…],x]は，たとえ p[f,g,…][x]に値があっても使うことができる：

Wolfram Language code: Comap[<|"a" -> f, "b" -> g|>, x]

p[f,g,…][x]に値があるときは，Throughは使えない：

Wolfram Language code: <|"a" -> f, "b" -> g|>[x]
Wolfram Language code: Through[<|"a" -> f, "b" -> g|>[x]]

Comap[{f1,f2,…},x]は，fiに属性がなければMap[f|->f[x],{f1,f2,…}]に等しい：

Wolfram Language code: Comap[{f, g, h}, x]
Wolfram Language code: Map[e |-> e[x], {f, g, h}]

Comapはホールドされた式の中にある部分を評価せずに適用することができる：

Wolfram Language code: Comap[Hold[Length, Total], {a, b, c}]

ReleaseHoldを使って評価されるようにする：

Wolfram Language code: ReleaseHold[{%}]

ある引数だけがホールドされているなら，その引数だけがそれ以降評価されなくなる：

Wolfram Language code: SetAttributes[h, HoldRest]
Wolfram Language code: Comap[h[Length, Total], {a, b, c}]

Unevaluatedを使って式を評価することなしに関数のリストをこの式に適用する：

Wolfram Language code: Comap[{Hold, HoldComplete}, Unevaluated[2 3 4]]

デフォルトで，式はまず評価される：

Wolfram Language code: Comap[{Hold, HoldComplete}, 2 3 4]

Unevaluatedを使って式を評価することなしに式の各部分に共適用する：

Wolfram Language code: Comap[Unevaluated[f g f], x]

デフォルトで，式はまず評価される：

Wolfram Language code: Comap[f g f, x]

Comapは自動的に並列化できる：

Wolfram Language code: Parallelize[Comap[{f, g, h}, x]]

考えられる問題  (1)

Comapは，デフォルトで，レベル1から始めるので，式全体を式に適用することはない：

Wolfram Language code: Comap[f[g[h]], x, -1]
Wolfram Language code: Comap[f[g[h]], x, {0, -1}]
Wolfram Research (2024), Comap, Wolfram言語関数， https://reference.wolfram.com/language/ref/Comap.html.

テキスト

Wolfram Research (2024), Comap, Wolfram言語関数， https://reference.wolfram.com/language/ref/Comap.html.

CMS

Wolfram Language. 2024. "Comap." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Comap.html.

APA

Wolfram Language. (2024). Comap. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Comap.html

BibTeX

@misc{reference.wolfram_2026_comap, author="Wolfram Research", title="{Comap}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/Comap.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_comap, organization={Wolfram Research}, title={Comap}, year={2024}, url={https://reference.wolfram.com/language/ref/Comap.html}, note=[Accessed: 13-September-2026]}