WOLFRAM

Wolfram 语言与系统参考资料中心

CompositeQ[n]

如果 expr 是合数，给出 True，否则给出 False.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
GaussianIntegers  
应用  
基本应用  
数论  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CompositeQ

CompositeQ[n]

如果 expr 是合数，给出 True，否则给出 False.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验一个数是否为合数：

Wolfram Language code: CompositeQ[4]

数字 不是合数：

Wolfram Language code: CompositeQ[13]

范围  (4)

CompositeQ 作用于整数：

Wolfram Language code: CompositeQ[4]

高斯整数：

Wolfram Language code: CompositeQ[3 + I]
Wolfram Language code: CompositeQ[5, GaussianIntegers -> True]

检验大整数：

Wolfram Language code: CompositeQ[10 ^ 3000 + 1]

CompositeQ 遍历列表：

Wolfram Language code: CompositeQ[{1, 2, 3, 4, 5, 6}]

选项  (1)

GaussianIntegers  (1)

测试 是否为合数：

Wolfram Language code: CompositeQ[5]

高斯整数：

Wolfram Language code: CompositeQ[5, GaussianIntegers -> True]

应用  (9)

基本应用  (3)

高亮显示合数：

Wolfram Language code: Multicolumn[If[CompositeQ[#], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

生成第 个合数：

Wolfram Language code: composite[n_] := FixedPoint[n + PrimePi[#] + 1&, n];
Wolfram Language code: Table[composite[n], {n, 100}]
Wolfram Language code: AllTrue[%, CompositeQ]

生成随机合数：

Wolfram Language code: randomComposite[n_, m_ : 1] := composite[RandomInteger[{1, n}, m]];
Wolfram Language code: randomComposite[100, 10]
Wolfram Language code: AllTrue[%, CompositeQ]

高斯合数分布：

Wolfram Language code: ArrayPlot[Boole[Table[CompositeQ[a + b I, GaussianIntegers -> True], {a, 100}, {b, 100}]]]

数论  (6)

识别谢尔宾斯基数 k，其中 恒为合数：

Wolfram Language code: k = 78557; AllTrue[Table[CompositeQ[k * 2 ^ n + 1], {n, 1, 10000}], TrueQ]

识别幂数 n，其所有质因子均重复：

Wolfram Language code: powQ[n_] := AllTrue[Part[FactorInteger[n], All, 2], # > 1&];
Wolfram Language code: powQ[2 ^ 2 * 3 ^ 4]

所有次方数均为幂数：

Wolfram Language code: powQ[64]

识别基底为 b 的伪素数，合数 n，使得 ：

Wolfram Language code: bprimeQ[b_, n_] := PowerMod[b, n - 1, n] == 1 && CompositeQ[n];

求所有基底为 且小于 的伪素数：

Wolfram Language code: Select[Range[1000], bprimeQ[2, #]&]

求所有基底为 且小于 的伪素数：

Wolfram Language code: Select[Range[1000], bprimeQ[5, #]&]

求形式为 的大合数：

Wolfram Language code: Select[Table[2 ^ 2 ^ n + 1, {n, 10}], CompositeQ]

合数在整数上的分布：

Wolfram Language code: data = Select[Range[100], CompositeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

绘制分布：

Wolfram Language code: DiscretePlot[Evaluate[CDF[𝒟, x]], {x, 1, 100}, ExtentSize -> Right]

合数在高斯整数上的分布：

Wolfram Language code: data = {Re[#], Im[#]}& /@ Select[Flatten[Table[a + b I, {a, 500}, {b, 500}]], CompositeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

绘制分布：

Wolfram Language code: DiscretePlot3D[Evaluate[CDF[𝒟, {x, y}]], {x, 1, 5}, {y, 1, 5}, ExtentSize -> Right]

属性和关系  (6)

Primes 表示所有质数域：

Wolfram Language code: Element[8, Primes]

合数都不属于 Primes：

Wolfram Language code: CompositeQ[8]

对于所有合数，PrimeQ 返回 False：

Wolfram Language code: CompositeQ[12]
Wolfram Language code: PrimeQ[12]

对于所有质数，CompositeQ 返回 False：

Wolfram Language code: PrimeQ[67]
Wolfram Language code: CompositeQ[67]

合数不可能是 MersennePrimeExponent：

Wolfram Language code: CompositeQ[28]
Wolfram Language code: MersennePrimeExponentQ[28]

合数至少有两个包括重复度的质因子，：

Wolfram Language code: CompositeQ[60]
Wolfram Language code: FactorInteger[60]

质数的第 次幂的合数具有恰好 个除数：

Wolfram Language code: CompositeQ[5 ^ 11]
Wolfram Language code: Length[Divisors[5 ^ 11]]

巧妙范例  (2)

绘制作为三个平方之和的合数：

Wolfram Language code: ArrayMesh[Boole[Table[CompositeQ[a ^ 2 + b ^ 2 + c ^ 2], {a, 10}, {b, 10}, {c, 10}]]]

绘制乌岚螺旋，根据数的合数度对其进行着色：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[ulam[101]Boole[CompositeQ[ulam[101]]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White}]
Wolfram Research (2014)，CompositeQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CompositeQ.html.

文本

Wolfram Research (2014)，CompositeQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CompositeQ.html.

CMS

Wolfram 语言. 2014. "CompositeQ." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CompositeQ.html.

APA

Wolfram 语言. (2014). CompositeQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CompositeQ.html 年

BibTeX

@misc{reference.wolfram_2026_compositeq, author="Wolfram Research", title="{CompositeQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CompositeQ.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_compositeq, organization={Wolfram Research}, title={CompositeQ}, year={2014}, url={https://reference.wolfram.com/language/ref/CompositeQ.html}, note=[Accessed: 07-September-2026]}