WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConstantArray[c,n]

要素 c を n 個複製したリストを生成する．

ConstantArray[c,{n1,n2,…}]

要素 c の複製を含むネストされたリストの 配列を生成する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ConstantArray

ConstantArray[c,n]

要素 c を n 個複製したリストを生成する．

ConstantArray[c,{n1,n2,…}]

要素 c の複製を含むネストされたリストの 配列を生成する．

詳細

例題

すべて開く すべて閉じる

例  (3)

10個の c のベクトルを作成する：

Wolfram Language code: ConstantArray[c, 10]

c の3×4配列を作成する：

Wolfram Language code: ConstantArray[c, {3, 4}]

ブロックから配列を作る：

Wolfram Language code: ArrayFlatten[ConstantArray[{{1, 2}, {3, 4}}, {3, 3}]]

スコープ  (4)

機械ゼロのベクトル：

Wolfram Language code: ConstantArray[0., 10]

厳密なゼロのベクトル：

Wolfram Language code: ConstantArray[0, 10]

機械ゼロの行列：

Wolfram Language code: zm = ConstantArray[0., {3, 3}]

厳密なゼロの行列：

Wolfram Language code: ConstantArray[0, {3, 3}]

1のベクトル：

Wolfram Language code: ConstantArray[1, 10]

1の機械数ベクトル：

Wolfram Language code: ConstantArray[1., 10]

深くネストした定数配列：

Wolfram Language code: ConstantArray[x, {2, 1, 2, 1, 2}]

アプリケーション  (3)

プログラムの中の保管場所として使う配列を設定する：

Wolfram Language code: esteps[f_, x0_, h_, n_] := Module[{res = ConstantArray[x0, {n + 1}], x = x0}, Do[x += h f[i h, x];res[[i + 1]] = x, {i, n}];res]

オイラー(Euler)法を使って x'[t]==1/(t+x[t]^2)を数値的に解く：

Wolfram Language code: sol = esteps[Function[{t, x}, 1 / (t + x ^ 2)], 1, .01, 100];
Wolfram Language code: ListPlot[sol, DataRange -> {0, 1}]

リスト中の要素の和を求める：

Wolfram Language code: list = RandomInteger[9, 20]
Wolfram Language code: list.ConstantArray[1, Length[list]]

これはTotalを使っても求められる：

Wolfram Language code: Total[list]

1のベクトルを使って線形系の解に対する条件の効果を見る：

Wolfram Language code: ones = ConstantArray[1, 10]
Wolfram Language code: m = HilbertMatrix[10]; b = m.ones;

機械精度の解には重大な誤差が含まれている：

Wolfram Language code: x = LinearSolve[N[m], b]
Wolfram Language code: Norm[x - ones]

高精度にすると，解ははるかによくなる：

Wolfram Language code: x30 = LinearSolve[N[m, 30], b]; Norm[Block[{$MaxPrecision = 30, $MinPrecision = 30}, x30 - ones]]

特性と関係  (3)

ConstantArray[c,dims]はDimensions[dims]を持つ：

Wolfram Language code: dims = RandomInteger[{1, 4}, 5]
Wolfram Language code: Dimensions[ConstantArray[c, dims]]

ConstantArray[c,dims]はSparseArray[{},dims,c]に等しい：

Wolfram Language code: dims = RandomInteger[{1, 4}, 5];
Wolfram Language code: s = SparseArray[{}, dims, c]
Wolfram Language code: ConstantArray[c, dims] == s

Normal[s]はConstantArray[c,dims]に等しい：

Wolfram Language code: ConstantArray[c, dims] === Normal[s]

ConstantArray[c,dims]はApply[Table[c,##]&,Map[List,dims]]と等しい：

Wolfram Language code: dims = RandomInteger[{1, 4}, 5];
Wolfram Language code: ConstantArray[c, dims] === Apply[Table[c, ##]&, Map[List, dims]]
Wolfram Research (2007), ConstantArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConstantArray.html （2008年に更新）.

テキスト

Wolfram Research (2007), ConstantArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConstantArray.html （2008年に更新）.

CMS

Wolfram Language. 2007. "ConstantArray." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/ConstantArray.html.

APA

Wolfram Language. (2007). ConstantArray. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConstantArray.html

BibTeX

@misc{reference.wolfram_2026_constantarray, author="Wolfram Research", title="{ConstantArray}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/ConstantArray.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_constantarray, organization={Wolfram Research}, title={ConstantArray}, year={2008}, url={https://reference.wolfram.com/language/ref/ConstantArray.html}, note=[Accessed: 10-September-2026]}