Wolfram 语言与系统参考资料中心

ContinuousMarkovProcess

ContinuousMarkovProcess[i₀,q]

表示连续时间有限状态的马尔可夫过程，其中转移率矩阵为 q，初始状态为 i₀.

ContinuousMarkovProcess[p₀,q]

表示初始状态概率向量为 p₀ 的马尔可夫过程.

ContinuousMarkovProcess[…,m,μ]

表示转移矩阵为 m、转移率为 μ 的马尔可夫过程.

ContinuousMarkovProcess[…,g]

表示图 g 的马尔可夫过程转移率矩阵.

ContinuousMarkovProcess

ContinuousMarkovProcess[i₀,q]

表示连续时间有限状态的马尔可夫过程，其中转移率矩阵为 q，初始状态为 i₀.

ContinuousMarkovProcess[p₀,q]

表示初始状态概率向量为 p₀ 的马尔可夫过程.

ContinuousMarkovProcess[…,m,μ]

表示转移矩阵为 m、转移率为 μ 的马尔可夫过程.

ContinuousMarkovProcess[…,g]

表示图 g 的马尔可夫过程转移率矩阵.

背景

ContinuousMarkovProcess 创建了一个连续马尔可夫过程，即有限状态连续时间的随机过程，其给定状态的转移概率只依赖于当前状态. 更确切的说，由 ContinuousMarkovProcess 定义的随机过程由有限多个状态组成且每个状态上的时间具备指数分布. 由 ContinuousMarkovProcess 定义的过程有时又被称为连续时间马尔可夫链（CTMC），它和由 DiscreteMarkovProcess 创建的，有离散时间参数的过程类似，只不过时间是连续的.
连续马尔可夫过程自然的出现在数学和物理科学的许多领域中，且被用于对队列、化学反应、电子故障和地质沉降这些现象建模. 此外，有大量的研究是关于从概率论角度理解连续马尔可夫过程的.
ContinuousMarkovProcess 可以接受许多种参数方案. 最典型的是 ContinuousMarkovProcess 可根据指定了初始状态和转移率矩阵的输入参数创建 CTMC. 初始状态可能是 1 到之间的单个整数或者是长度为且总和为 1 的非负元素组成的概率向量. 转移率矩阵是大小为 × 的方阵（或 SparseArray），它每行的和都是 0 且对满足且，而 ContinuousMarkovProcess 的状态是 1 和之间的整数. 对给定的 ContinuousMarkovProcess 在转移到状态之前处于状态的时间服从一个指数分布，即 t_iExponentialDistribution[-q_{i i}]，其中指的是矩阵的第项而是 Distributed 的缩写.
ContinuousMarkovProcess 也可以用一个转移矩阵和相关的转移率指定. 在这种情况下的项由条件转移概率组成，即给定后的概率，而相关的转移率指定了状态上事件间的时间分布是 ExponentialDistribution[μ_i]. 这里被定义成第次状态转移发生时的随机时刻，表示在时刻过程中的状态转移，是一个 × 的非负元素矩阵且每行之和都是 1，而是一个长度为且元素为正值的向量.
最后，ContinuousMarkovProcess 可以从输入的图产生 CTMC，图的边表示的是由顶点和代表的事件之间的转移率.
许多函数都可以和 ContinuousMarkovProcess 一起使用，包括 MarkovProcessProperties、PDF 及 Probability. RandomFunction 可被用于模拟 CTMC，其结果（一个 TemporalData 对象）之后可通过 ListLinePlot 可视化，可通过 TimeSeries 切分，还可用像 Mean、Variance、StandardDeviation 和 Moment 这样的函数分析——这些函数也可用于分析由 ContinuousMarkovProcess 定义的分布. ContinuousMarkovProcess 也可作为 FirstPassageTimeDistribution 的 mproc 参数输入，来分析一个 CTMC 从初始状态第一次到达最终状态所需时间的分布，而由 ContinuousMarkovProcess 创建的随机分布的统计性质可直接用诸如 CharacteristicFunction 和 CentralMomentGeneratingFunction 这样的函数来分析.
除了统计性质之外，由 ContinuousMarkovProcess 创建的过程可以通过 Graph 表示为图，这样就可以继承许多图论函数的用法. 像 QueueingProcess、QueueProperties 和 SurvivalFunction 这样的函数在建模和应用中利用了 CTMC 的性质. ContinuousMarkovProcess 也可通过 EstimatedProcess 作为近似工具使用，后者是一个可以用最适合给定数据集的个状态计算近似 CTMC 的函数.

范例

打开所有单元关闭所有单元

基本范例 (2)

定义一个连续时间马尔可夫过程：

Wolfram Language code:

𝒫 = ContinuousMarkovProcess[{1, 0, 0}, (⁠|    |    |    |
| -- | -- | -- |
| -2 | 1  | 1  |
| 1  | -2 | 1  |
| 1  | 1  | -2 |⁠)];

模拟这个过程：

Wolfram Language code: data = RandomFunction[𝒫, {0, 10}]

Wolfram Language code: ListStepPlot[data, PlotRange -> {0, 3}, Ticks -> {Automatic, {1, 2, 3}}]

求时刻 t 的状态下概率密度函数：

Wolfram Language code:

𝒫 = ContinuousMarkovProcess[{1, 0, 0}, (⁠|    |    |    |
| -- | -- | -- |
| -2 | 1  | 1  |
| 1  | -2 | 1  |
| 1  | 1  | -2 |⁠)];

Wolfram Language code: PDF[𝒫[t], k]//PiecewiseExpand

求过程在状态2的长期运行时间比例：

Wolfram Language code: PDF[𝒫[∞], 2]

范围 (12)

过程性质：

Wolfram Language code: MarkovProcessProperties[ContinuousMarkovProcess[1, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}]]

用图的形式对过程进行可视化，其中转移率作为工具提示条给出：

Wolfram Language code: Graph[ContinuousMarkovProcess[1, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}]]

将图表示转换回连续马尔可夫过程：

Wolfram Language code: ContinuousMarkovProcess[1, %]

求一个连续马尔可夫过程的常返类和瞬态类：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[1, {{-2, 1, 1, 0}, {2, -6, 2, 2}, {3, 3, -9, 3}, {0, 0, 0, 0}}];

Wolfram Language code: MarkovProcessProperties[𝒫, "RecurrentClasses"]

Wolfram Language code: MarkovProcessProperties[𝒫, "TransientClasses"]

生成具有默认机器精度的样本路径：

Wolfram Language code: RandomFunction[ContinuousMarkovProcess[1, {{-3, 3}, {2, -2}}], {0, 2}]//Normal

生成具有更高精度的样本路径：

Wolfram Language code: RandomFunction[ContinuousMarkovProcess[1, {{-3, 3}, {2, -2}}], {0, 2}, WorkingPrecision -> 20]//Normal

可视化样本路径：

Wolfram Language code:

𝒫 = With[{λ = 3, μ = 2, m = 10}, ContinuousMarkovProcess[1, SparseArray[{{1, 1} -> -λ, {m, m} -> -μ, Band[{1, 2}] -> λ, Band[{2, 1}] -> μ, Band[{2, 2}] -> -λ - μ}, {m, m}]]];

Wolfram Language code: BlockRandom[SeedRandom[1234];data = RandomFunction[𝒫, {0, 25}]]

Wolfram Language code: ListPlot[data, Filling -> Axis]

从样本数据估计过程参数：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}];

Wolfram Language code: data = RandomFunction[𝒫, {0, 10 ^ 2}, 10 ^ 3];

Wolfram Language code: estproc = EstimatedProcess[data, ContinuousMarkovProcess[4], WorkingPrecision -> MachinePrecision]//Normal

切片分布：

Wolfram Language code:

𝒫 = With[{λ = 3, μ = 2, m = 10}, ContinuousMarkovProcess[1, SparseArray[{{1, 1} -> -λ, {m, m} -> -μ, Band[{1, 2}] -> λ, Band[{2, 1}] -> μ, Band[{2, 2}] -> -λ - μ}, {m, m}]]];

Wolfram Language code: PDF[𝒫[4.], 3]

Wolfram Language code: DiscretePlot[PDF[𝒫[4.], x], {x, 0, 10}]

求吸收时间的分布：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[1, {{-2, 1, 1, 0}, {1, -6, 2, 3}, {3, 2, -8, 3}, {0, 0, 0, 0}}];

Wolfram Language code: 𝒟 = FirstPassageTimeDistribution[𝒫, 4];

Wolfram Language code: Plot[PDF[𝒟, t], {t, 0, 10}, Evaluated -> True, PlotRange -> All]

分布的均值：

Wolfram Language code: Mean[𝒟]

Wolfram Language code: N[%]

与过程仿真得到的值进行比较：

Wolfram Language code: paths = RandomFunction[𝒫, {0, 20}, 10 ^ 4]["Paths"];

Wolfram Language code: Mean[Part[#, LengthWhile[#, Last[#] ≠ 4&] + 1, 1]& /@ paths]

特征函数：

Wolfram Language code: CharacteristicFunction[𝒟, s]

计算事件的概率：

Wolfram Language code: Probability[time > Mean[𝒟], time𝒟]

Wolfram Language code: N[%]

求稳态分布：

Wolfram Language code: StationaryDistribution[ContinuousMarkovProcess[1, {{-a, a}, {b, -b}}]]

对稳态分布进行操作：

Wolfram Language code: Mean[%]//Simplify

求从状态1开始到状态4结束的全部转移的条件平均数：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}];

Wolfram Language code: n = 30.;

Wolfram Language code: MarkovProcessProperties[𝒫, "TransitionCount"][[4]][n] / Probability[x[n] == 4, x𝒫]

与仿真结果进行比较：

Wolfram Language code: data = RandomFunction[𝒫, {0, n}, 4 * 10 ^ 4, Method -> {Automatic, "StoppingFunction" -> (#3 =!= 4&)}]["ValueList"];

Wolfram Language code: N[Mean[Length[#] - 1& /@ data]]

求从状态2到状态3的转移的条件平均数：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}];

Wolfram Language code: MarkovProcessProperties[𝒫, {"TransitionCount", {{2, 3}}}][[4]][n] / Probability[x[n] == 4, x𝒫]

与仿真结果进行比较：

Wolfram Language code: data = RandomFunction[𝒫, {0, n}, 10 ^ 4, Method -> {Automatic, "StoppingFunction" -> (#3 =!= 4&)}]["ValueList"];

Wolfram Language code: N[Mean[Count[Partition[data[[#]], 2, 1], {2, 3}]& /@ Range[Length[data]]]]

计算概率：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0}, {{-2, 1, 1}, {1, -2, 1}, {1, 1, -2}}];

Wolfram Language code: Probability[x ^ 2 + x < 6, x𝒫[t]]//Simplify

Wolfram Language code: N[% /. t -> 3]

Wolfram Language code: NProbability[x ^ 2 + x < 6, x𝒫[3]]

矩和母函数：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0}, {{-2, 1, 1}, {1, -2, 1}, {1, 1, -2}}];

Wolfram Language code: Moment[𝒫[t], r]//Simplify

Wolfram Language code: CharacteristicFunction[𝒫[t], w]//Simplify

Wolfram Language code: CentralMomentGeneratingFunction[𝒫[t], w]//Simplify

推广和延伸 (2)

用图表示连续马尔可夫过程：

Wolfram Language code: proc = ContinuousMarkovProcess[{1, 0, 0, 0}, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}];

Wolfram Language code: Graph[proc]

将图转换成连续马尔可夫过程：

Wolfram Language code:

gr = Graph[{12, 21}, AnnotationRules -> {1 -> {"InitialProbability" -> 0.6}, 2 -> {"InitialProbability" -> 0.4}, 12 -> {"TransitionRate" -> 3}, 21 -> {"TransitionRate" -> 2}}];

Wolfram Language code: MatrixForm /@ ContinuousMarkovProcess[gr]

使用离散的马尔可夫过程图建立一个相应的连续马尔可夫过程：

Wolfram Language code:

gr = Graph[DiscreteMarkovProcess[3, {{1 / 2, 1 / 2, 0, 0}, {1 / 2, 1 / 2, 0, 0}, {1 / 4, 1 / 4, 1 / 4, 1 / 4}, {0, 0, 0, 1}}]]

Wolfram Language code: ContinuousMarkovProcess[3, gr, {2, 3, 5, 7}]

应用 (9)

人们每年从波士顿移居到剑桥的速度被估计为每年六人：

Wolfram Language code: migrationProcess = ContinuousMarkovProcess[1, {{-6, 6}, {0, 0}}];

求在两个月的时间内移居的人的百分比：

Wolfram Language code: Probability[x[t + 2 / 12] == 2x[t] == 1, xmigrationProcess]

Wolfram Language code: N[%]

一家医院拥有两个相同且独立的发电机. 每个发电机的无故障运行时间服从参数为的指数分布，故障发电机的维修时间服从参数为的指数分布. 假设两个发电机在正常运行，求两个发电机在时刻仍正常运行的概率. 正常运行的发电机个数可以用连续马尔可夫链模拟，其中状态数表示1加上正常运行的发电机个数：

Wolfram Language code: proc = ContinuousMarkovProcess[3, {{-2μ, 2μ, 0}, {λ, -λ - μ, μ}, {0, 2λ, -2λ}}];

Wolfram Language code: Probability[workinggenerators[t] == 3, workinggeneratorsproc]//FullSimplify

一种易燃品被存储在填充站的特殊储罐中. 需要这种产品的客户的到达服从速率为的泊松过程. 每个客户需要一个单位的该产品. 发生缺货的任何需求都将丢失. 重新补充库存的机会服从参数为的泊松过程. 假定这两个泊松过程是相互独立的. 为安全起见，只能当储罐全空时补充库存. 在这些机会发生时，补充库存个单位：

Wolfram Language code:

proc = With[{n = 5, λ = 4, μ = 2}, ContinuousMarkovProcess[n + 1, SparseArray[{{1, 1} -> -μ, {1, n + 1} -> μ, {i_, i_} -> -λ, {i_, j_} /; i > 1 && j == i - 1 -> λ}, {n + 1, n + 1}]]];

Wolfram Language code: proc[Infinity]

长期来看，储罐的平均库存：

Wolfram Language code: PDF[proc[Infinity], Range[6]].Range[0, 5]

长期来看，需求丢失的比例：

Wolfram Language code: PDF[proc[Infinity], 1]

一个路由器接收来自一组用户的数据包，并将它们通过一条单一传输线传输. 假设数据包的到达是根据速率为每4毫秒一个数据包的泊松过程，数据包的传输时间为均值为3毫秒的指数分布. 求一个无限路由器的容量近似：

Wolfram Language code:

qm = With[{λ = 1 / 4, μ = 1 / 3, m = 100}, SparseArray[Join[Table[{i, i + 1} -> λ, {i, m}], Table[{i + 1, i} -> μ, {i, m}], Table[{i, i} -> -λ - μ, {i, 2, m}], {{1, 1} -> -λ, {m + 1, m + 1} -> -μ}]]];

Wolfram Language code: dist = StationaryDistribution[ContinuousMarkovProcess[1, qm]];

平均延迟：

Wolfram Language code: With[{λ = 1 / 4}, (Mean[dist] - 1) / (λ * (1 - PDF[dist, 100]))]//N

有多于5个数据包等待路由器传输的概率：

Wolfram Language code: NProbability[k > 6, kdist]

在一个抛光镜面表面出现缺陷的数目是一个泊松随机变量. 对于面积为的一面镜子，没有缺陷的概率是0.91. 求面积为、使用相同工艺制造的另一面镜子表面没有任何瑕疵的概率：

Wolfram Language code:

proc = ContinuousMarkovProcess[1, With[{vec = {-λ, λ, 0, 0}}, Append[RotateRight[vec, #]& /@ Range[0, Length[vec] - 2], ConstantArray[0, Length[vec]]]]];

Wolfram Language code: proc = proc /. First@Quiet@NSolve[Chop@Probability[flaws[8.54] == 1, flawsproc] == 0.91, λ, Reals];

Wolfram Language code: NProbability[flaws[17.5] == 1, flawsproc]

车抵达换油中心的模式服从泊松过程，抵达率为4辆/小时. 只有一名可用机械师，换油所花费的时间服从指数分布，平均需要12分钟. 近似无限的汽车空间：

Wolfram Language code:

𝒫 = With[{λ = 4, μ = 60 / 12, m = 10 ^ 2}, ContinuousMarkovProcess[1, SparseArray[Join[Table[{i, i + 1} -> λ, {i, m}], Table[{i + 1, i} -> μ, {i, m}], Table[{i, i} -> -λ - μ, {i, 2, m}], {{1, 1} -> -λ, {m + 1, m + 1} -> -μ}]]]];

模拟队列中的汽车数：

Wolfram Language code: BlockRandom[SeedRandom[1234];data = RandomFunction[𝒫, {0, 25}]];

Wolfram Language code: ListPlot[data, Filling -> Axis]

Wolfram Language code: 𝒟 = StationaryDistribution[𝒫];

有多于三辆汽车在排队的概率：

Wolfram Language code: NProbability[x > 4, x𝒟]

Wolfram Language code: NProbability[x > 3, xStationaryDistribution[QueueingProcess[4, 5]]]

系统中汽车数目的均值和方差：

Wolfram Language code: {Mean[𝒟] - 1, Variance[𝒟]}//N

Wolfram Language code: With[{𝒟 = StationaryDistribution[QueueingProcess[4, 5]]}, {Mean[𝒟], Variance[𝒟]}]

系统中汽车数目的分布：

Wolfram Language code: DiscretePlot[PDF[𝒟, k], {k, 1, 20}, ExtentSize -> 0.5, PlotRange -> All]

在某一个国家，车辆每年都需要进行评估，以鉴定是否适宜在道路上行驶. 在一个车辆评估中心，司机平均需要等候15分钟，才能开始对他们的车辆是否适宜在道路上行驶进行评估. 评估需要平均20分钟就可以完成. 在评估结束之后，80％的汽车可以通过评估，允许司机把车开回家. 另外15％的车辆被归类为“轻度失败”，这些车需要平均30分钟的维修，然后司机可以把车开回家. 其余5％的车辆被归类为“重大失败”，需要对这些车辆进行平均3个小时的维修，然后才能把车开回家. 使用连续时间马尔可夫模型对车辆评估中心的运作进行建模，其中状态 W（等待评估），A（评估进行），M（轻度维修），S（重度维修）和 H（回家）：

Wolfram Language code: states = {"W", "A", "M", "S", "H"};

转移率：

Wolfram Language code:

transrates = {statetransition["W", "A"] -> 1 / 15, Sequence@@Thread[statetransition["A", #]& /@ {"M", "S", "H"} -> 1 / 20 * {15 / 100, 5 / 100, 80 / 100}], statetransition["M", "H"] -> 1 / 30, statetransition["S", "H"] -> 1 / (3 * 60)};

将对角线元素设置为非对角线元素的总和的相反数，使各行总和为零：

Wolfram Language code:

qm = SparseArray[Join[transrates, statetransition[#, #] -> -Total[Cases[transrates, (statetransition[#, _] -> r_) :> r]]& /@ states] /. Thread[states -> Range[5]] /. statetransition -> List, {5, 5}];

模拟评估和维修的过程：

Wolfram Language code: proc = ContinuousMarkovProcess[1, qm];

车辆在时刻进行重度维修的概率：

Wolfram Language code: Probability[x[5 / 2] == 4, xproc]//Simplify

Wolfram Language code: N[%]

车辆评估和维修所花的平均时间（以分钟计）：

Wolfram Language code: Mean[FirstPassageTimeDistribution[proc, 5]]//N

考虑一个指数型时间间隔和服务时间的系统. 为两个客户提供一台服务器和房间：一个正在服务期间，另一个正在等待. 令在时刻，房间中的客户数目为 . 这是一个M/M/1/2的队列模型；将它作为一个生死过程，用以下的转换率矩阵进行建模，其中状态编号为：

Wolfram Language code: qm = {{-λ, λ, 0}, {μ, -λ - μ, λ}, {0, μ, -μ}};

Wolfram Language code: proc = ContinuousMarkovProcess[1, qm];

Wolfram Language code: Graph[proc, GraphLayout -> Automatic, ImageSize -> Small]

转移率矩阵式是不可约的：

Wolfram Language code: MarkovProcessProperties[proc, "Irreducible"]

因此，稳态分布是唯一存在的：

Wolfram Language code: dist = StationaryDistribution[proc]

这与 QueueingProcess 的稳态分布相一致：

Wolfram Language code: PDF[dist, Range[3]] == PDF[StationaryDistribution[QueueingProcess[λ, μ, 1, 2]], Range[0, 2]]//Simplify

这是一个被截断的几何分布：

Wolfram Language code: PDF[dist, Range[3]] - Table[(1 - λ / μ) / (1 - (λ / μ) ^ (n + 1))(λ / μ) ^ j, {j, 0, 2}] /. n -> 2//Simplify

服务器忙碌时间的比例：

Wolfram Language code: utilfactor = 1 - PDF[dist, 1]//Together

这与 QueueProperties 的结果一致：

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ, 1, 2], "UtilizationFactor"]

从长远来看在房间内客户的平均数量：

Wolfram Language code: avcust = Mean[dist] - 1//Simplify

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ, 1, 2], "MeanSystemSize"]//Simplify

队列的平均大小：

Wolfram Language code: queuesize = PDF[dist, 3]//Simplify

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ, 1, 2], "MeanQueueSize"]//Simplify

Wolfram Language code: avcust - queuesize - utilfactor//Simplify

从长远来看潜在客户进入房间的比例：

Wolfram Language code: CDF[dist, 2]//Simplify

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ, 1, 2], "Throughput"] / λ//Simplify

平均等候时间：

Wolfram Language code: avcust / (λ * (1 - PDF[dist, 3]))//Together

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ, 1, 2], "MeanSystemTime"]//Simplify

如果服务器的工作速度是现在的两倍，客户数量的增加：

Wolfram Language code: (Mean[StationaryDistribution[ContinuousMarkovProcess[1, qm /. μ -> 2μ]]] - 1) / avcust//Simplify

哈勃太空望远镜携带6个陀螺仪，要求至少有三个以达到完全准确度. 陀螺仪的运行时间是独立的指数分布，故障率为 . 如果第四个陀螺仪出现故障，望远镜将进入睡眠模式，在这种模式下将暂停进一步观察. 它需要一个均值为 1/ 的指数时间分布以进入睡眠模式. 在此之后，在地球上的基地台接收睡眠信号，将准备执行航天飞机飞行任务. 维修人员到达望远镜，并维修陀螺仪稳定的稳定单元，需要一个均值为1/ 的指数时间. 同时，其他两个陀螺仪可能会出现故障. 如果最后一个陀螺仪出现故障，该望远镜将崩溃. 假设，，以及，并全部以年的倒数为单位：

Wolfram Language code:

proc = ContinuousMarkovProcess[1, {{-6λ, 6λ, 0, 0, 0, 0, 0, 0, 0}, {0, -5λ, 5λ, 0, 0, 0, 0, 0, 0}, {0, 0, -4λ, 4λ, 0, 0, 0, 0, 0}, {0, 0, 0, -3λ, 3λ, 0, 0, 0, 0}, {0, 0, 0, 0, -2λ - μ, 2λ, μ, 0, 0}, {0, 0, 0, 0, 0, -λ - μ, 0, μ, λ}, {η, 0, 0, 0, 0, 0, -2λ - η, 2λ, 0}, {η, 0, 0, 0, 0, 0, 0, -λ - η, λ}, {ν, 0, 0, 0, 0, 0, 0, 0, -ν}}] /. {λ -> 1 / 10, μ -> 100, η -> 5};

可视化此过程，用整数表示正常运行的陀螺仪的数目：

Wolfram Language code:

Graph[MapThread[Style, {{"6", "5", "4", "3", "2", "1", "Sleep2", "Sleep1", "Crash"}, {StandardGreen, StandardGreen, StandardGreen, StandardGreen, StandardOrange, StandardOrange, StandardBlue, StandardBlue, StandardRed}}], proc /. {ν -> 0}, GraphLayout -> {"SpringElectricalEmbedding", "Rotation" -> Pi}, ImageSize -> Medium]

该望远镜将在未来10年内崩溃的概率：

Wolfram Language code: CDF[FirstPassageTimeDistribution[proc, 9], 10.]

在10年没有达到睡眠模式（不需要执行航天飞机任务）的概率：

Wolfram Language code: SurvivalFunction[FirstPassageTimeDistribution[proc, {7, 8}], 10] /. ν -> 1.

Wolfram Language code: Plot[SurvivalFunction[FirstPassageTimeDistribution[proc /. ν -> 1, {7, 8}], x], {x, 0, 20}, Filling -> Axis]

属性和关系 (1)

利用转移率矩阵定义一个连续马尔可夫过程：

Wolfram Language code: 𝒫 = ContinuousMarkovProcess[{1, 0, 0, 0}, {{-3, 1, 2, 0}, {3, -6, 2, 1}, {4, 2, -9, 3}, {0, 0, 0, 0}}];

获取转移率向量：

Wolfram Language code: μ = MarkovProcessProperties[𝒫, "TransitionRateVector"]

嵌入式离散马尔可夫过程的转移矩阵：

Wolfram Language code: m = MarkovProcessProperties[𝒫, "TransitionMatrix"]

用 m 和 μ 恢复原始的马尔可夫过程：

Wolfram Language code: ContinuousMarkovProcess[{1, 0, 0, 0}, m, μ]

Wolfram Language code: % === 𝒫

可能存在的问题 (2)

如果转移矩阵行的总和不等于零，则对矩阵对角线作相应调整：

Wolfram Language code: ContinuousMarkovProcess[1, {{-1, 2}, {4, -3}}]

如果初始概率之和不等于1，则对其进行归一化：

Wolfram Language code: ContinuousMarkovProcess[{1, 2}, {{-2, 2}, {3, -3}}]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ContinuousMarkovProcess

更多信息

背景

范例

基本范例 (2)

范围 (12)

推广和延伸 (2)

应用 (9)

属性和关系 (1)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

ContinuousMarkovProcess

更多信息

背景

范例

基本范例 (2)

范围 (12)

推广和延伸 (2)

应用 (9)

属性和关系 (1)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX