ContinuousWaveletTransformはContinuousWaveletDataオブジェクトを与える．
ContinuousWaveletData cwd の特性は cwd["prop"]で得ることができる．使用可能な特性のリストは cwd["Properties"]で得られる．
結果のウェーブレット係数は入力データと同じ次元の配列である．
使用可能なウェーブレット wave

	MorletWavelet[…]	Morletコサイン x ガウスウェーブレット
	GaborWavelet[…]	複素Morletウェーブレット
	DGaussianWavelet[…]	ガウスウェーブレットの導関数
	MexicanHatWavelet[…]	ガウスウェーブレットの二次導関数
	PaulWavelet[…]	Paulウェーブレット

デフォルトの wave はMexicanHatWavelet[]である．
noct のデフォルト値は $TemplateBox[{{InterpretationBox[{log, _, DocumentationBuild`Utils`Private`Parenth[2]}, Log2, AutoDelete -> True], (, {n, /, 2}, )}}, Floor]$ で与えられる．ただし，は入力の長さである． »
nvoc のデフォルト値は4である．
関数の連続ウェーブレット変換は $w(u,s)=1/(sqrt(s))int_(-infty)^inftyx(t) TemplateBox[{psi}, Conjugate]((t-u)/s)dt$ で与えられる．
一様にサンプルされた数列の連続ウェーブレット変換は $w(u,s)=1/(sqrt(s))sum_(k=1)^nx_k TemplateBox[{psi}, Conjugate]((Delta (k-u))/s)$ で与えられる．
スケーリングパラメータは均等に調律されたスケールで与えられる．ただし，はオクターブの数，は音の数，は最小ウェーブレットスケールである．
各スケールにつき，ContinuousWaveletTransformはウェーブレット係数を計算する．
使用可能なオプション

Padding	None	データを境界範囲外にどのように延長するか
SampleRate	Automatic	単位あたりのサンプル
WaveletScale	Automatic	分割可能な最小スケール
WorkingPrecision	MachinePrecision	内部計算で使用する精度

Paddingは入力 data を次に大きい2のベキ乗まで充填して境界効果を減少させる．Paddingの設定値はArrayPadで使われる充填引数のそれに等しい．
InverseContinuousWaveletTransformは逆変換を行う．

例題

すべて開くすべて閉じる

例 (2)

MexicanHatWaveletを使って連続ウェーブレット変換を計算する：

Wolfram Language code: cwd = ContinuousWaveletTransform[{56, 40, 8, 24, 48, 48, 40, 16}]

係数をプロットする：

Wolfram Language code: ListLinePlot[cwd[All, "Values"]]

逆連続ウェーブレット変換を行う：

Wolfram Language code: InverseContinuousWaveletTransform[cwd]

サンプルのSoundオブジェクトを変換する：

Wolfram Language code: Play[Underoverscript[∑, n, 5]Sin[2000 2^t n t], {t, 2, 3}]

Wolfram Language code: cwd = ContinuousWaveletTransform[%]

スケログラムをプロットする：

Wolfram Language code: WaveletScalogram[cwd]

スコープ (18)

基本的な用法 (6)

連続ウェーブレット変換を計算する：

Wolfram Language code: data = Table[HeavisideLambda[x], {x, -2, 2, (4/1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data]

第8オクターブのすべての音を示す：

Wolfram Language code: ListLinePlot[Abs[cwt[{8, _}][[All, 2]]], PlotRange -> All]

Normalを使ってすべてのウェーブレット係数を明示的に得る：

Wolfram Language code: cwt = ContinuousWaveletTransform[{0, 0, 1, 0, 0}, MexicanHatWavelet[1]]

Wolfram Language code: Normal[cwt]

Allを引数として使ってすべての係数を得る：

Wolfram Language code: cwt[All]

"IndexMap"を使ってどのウェーブレット係数が使えるかを見る：

Wolfram Language code: cwt = ContinuousWaveletTransform[{0, 0, 1, 0, 0}, MexicanHatWavelet[1]];

Wolfram Language code: cwt["IndexMap"]

特定の係数配列を抽出する：

Wolfram Language code: cwt[{1, 1}]

Wolfram Language code: cwt[{1, 4}]

ウェーブレット指標指定のリストに対応するいくつかの係数配列を抽出する：

Wolfram Language code: cwt[{{1, 1}, {1, 3}}]

ウェーブレット指標がパターンにマッチするすべての係数を抽出する：

Wolfram Language code: cwt[{1, _}]

Wolfram Language code: cwt[{{_, 1}, {_, 4}}]

Wolfram Language code: cwt[{_, 1 | 4}]

WaveletScalogramはウェーブレット係数のタイムスケール表現を与える：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data];

Wolfram Language code: WaveletScalogram[cwt, AxesLabel -> {"time", "scale"}]

オクターブ中の音を多くするとスケールの解像度が増す：

Wolfram Language code: data = Table[Sin[x^2], {x, 0, 10, 0.02}];

Wolfram Language code: {cwt1, cwt2} = Table[ContinuousWaveletTransform[data, DGaussianWavelet[5], {Automatic, voc}], {voc, {4, 16}}];

Wolfram Language code: {WaveletScalogram[cwt1, PlotLabel -> "4 voices/octave"], WaveletScalogram[cwt2, PlotLabel -> "16 voices/octave"]}

オクターブの数が大きくなるとスケール範囲のスペクトルが広くなる：

Wolfram Language code: data = Function[x, x Sin[Exp[x] x]][Range[2, 5, 0.001]];

Wolfram Language code: {cwt1, cwt2} = Table[ContinuousWaveletTransform[data, Automatic, {oct, Automatic}], {oct, {5, 8}}];

Wolfram Language code: {WaveletScalogram[cwt1, PlotLabel -> "5 octaves"], WaveletScalogram[cwt2, PlotLabel -> "8 octaves"]}

タイムとスケールの特徴 (4)

同じスケールの水平帯として単調が現れる：

Wolfram Language code: data1 = Table[Cos[20 π x], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data1]

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data1, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt1, ColorFunction -> "SolarColors"]

同じスケールで多重周波数が複数帯として現れる：

Wolfram Language code: data2 = Table[Cos[20 π x] + Cos[Sqrt[2] 50 π x], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data2]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data2, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt2, ColorFunction -> "SolarColors"]

線形に周波数が増す正弦曲線：

Wolfram Language code: data3 = Block[{fr = 0}, Table[Sin[(fr += 0.5)x], {x, 0, 1, (1/1023)}]];

Wolfram Language code: ListLinePlot[data3]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data3, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt2, ColorFunction -> "SolarColors"]

ウェーブレット変換は特徴をうまく時間で局所化する：

Wolfram Language code: data = Table[Sin[4 π t] + 2 Exp[-10^5 ((1/3) - t)^2], {t, 0, 1, (1/511)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, PaulWavelet[5], {7, 12}, SampleRate -> 511];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "AvocadoColors"]

高い周波数は低いオクターブで分解され，低い周波数は高いオクターブで分解される：

Wolfram Language code:

data = Table[Piecewise[{{Sin[2 π 10 t], 0 ≤ t < (1/4)}, {Sin[2 π 25 t], (1/4) ≤ t < (1/2)}, {Sin[2 π 50 t], (1/2) ≤ t < (3/4)}, {Sin[2 π 100 t], (3/4) ≤ t ≤ 1}}], {t, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data, AspectRatio -> 0.2]

Wolfram Language code: cwd = ContinuousWaveletTransform[data, DGaussianWavelet[5], {Automatic, 12}];

Wolfram Language code: WaveletScalogram[cwd, ColorFunction -> "RustTones"]

信号の時間と周波数の特徴を分解する：

Wolfram Language code: data = Table[Cos[40 π x] Exp[-100 π (x - 0.7)^2] + Cos[140 π x] Exp[-50 π (x - 0.2)^2], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data, PlotRange -> All]

GaborWaveletを使って連続ウェーブレット変換を行う：

Wolfram Language code: cwd = ContinuousWaveletTransform[data, GaborWavelet[8], SampleRate -> 1023];

スケールの値と周波数の値は反比例する：

Wolfram Language code: freq = (#1[[1]] -> (1023/#1[[2]])&) /@ cwd["Scales"]

周波数を20Hzと70Hzに分解する{oct,voc}ペアを求める：

Wolfram Language code: Cases[freq, u_ /; 19 ≤ Last[u] ≤ 21]

Wolfram Language code: Cases[freq, u_ /; 69 ≤ Last[u] ≤ 71]

WaveletScalogramを使って確認する：

Wolfram Language code: WaveletScalogram[cwd, ColorFunction -> "BrassTones"]

ウェーブレット族 (6)

さまざまなウェーブレット族を使ってウェーブレット変換を計算する：

Wolfram Language code: data = Table[Sin[x^2] + Cos[x^3], {x, 0, 3 π, 0.01}];

Wolfram Language code: ListLinePlot[data]

狭いウェーブレット関数を使うと時間とスケールの分解がうまくいく：

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data, MexicanHatWavelet[1]];

Wolfram Language code: WaveletScalogram[cwt1]

広いウェーブレット関数では時間とスケールの分解がうまくいかない：

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data, GaborWavelet[3]]

Wolfram Language code: WaveletScalogram[cwt2]

ウェーブレットの別の族を使って別の特徴を捉える：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: ListLinePlot[data]

MexicanHatWavelet（デフォルト）：

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MexicanHatWavelet[]];

Wolfram Language code:

ListPlot3D[Re@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

DGaussianWavelet：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, DGaussianWavelet[]];

Wolfram Language code:

ListPlot3D[Re@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

GaborWavelet：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[3]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

MorletWavelet：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MorletWavelet[]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

PaulWavelet：

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, PaulWavelet[]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

サウンド (2)

ContinuousWaveletTransformは入力としてのSoundに使うことができる：

Wolfram Language code: sdata = Play[Sin[5000 t] + Sin[1000 t] + Cos[500 t] + Cos[200 t], {t, 0, 1}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata, DGaussianWavelet[5]];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "StarryNightColors"]

ContinuousWaveletTransformを使った音声分析：

Wolfram Language code: snd = ExampleData[{"Sound", "Apollo11ReturnSafely"}]

Wolfram Language code: cwd = ContinuousWaveletTransform[snd, GaborWavelet[6], {Automatic, 12}];

オレンジ色の部分は「You will return safely to Earth」の単語に対応する：

Wolfram Language code: WaveletScalogram[cwd, {4 | 5 | 6 | 7, _}]

オクターブ5と6を抽出する：

Wolfram Language code: cwd2 = WaveletMapIndexed[#1 0.0&, cwd, Except[{5 | 6, _}]]

Wolfram Language code: Sound[InverseContinuousWaveletTransform[cwd2], SoundVolume -> 2]

オプション (9)

Padding (3)

Paddingの設定値はArrayPadのメソッドのものと同じで"Periodic"を含む：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

"Reversed"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

"ReversedNegation"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

"Reflected"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

"ReflectedDifferences"：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]

"ReversedDifferences"：

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

"Extrapolated"：

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

Paddingはウェーブレット係数の長さには影響しない：

Wolfram Language code: cwd = ContinuousWaveletTransform[Range[16]];

Wolfram Language code: (Length[#1]&) /@ cwd[All][[All, 2]]

Paddingは入力データを次に大きい2のベキ乗まで充填して境界効果を弱める：

Wolfram Language code: data = Table[Sin[20 x], {x, 0, 1, (1/1023)}];

Wolfram Language code:

cwt1 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> None, WaveletScale -> Automatic];
rdata1 = InverseContinuousWaveletTransform[cwt1];

Wolfram Language code:

cwt2 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> "Reflected", WaveletScale -> Automatic];
rdata2 = InverseContinuousWaveletTransform[cwt2];

Wolfram Language code:

cwt3 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> "Extrapolated", WaveletScale -> Automatic];
rdata3 = InverseContinuousWaveletTransform[cwt3];

始点の境界効果：

Wolfram Language code:

ListLinePlot[{data[[1 ;; 50]], rdata1[[1 ;; 50]], rdata2[[1 ;; 50]], rdata3[[1 ;; 50]]}, PlotStyle -> {Red, Green, Blue, Orange}, BaseStyle -> Thick]

終点の境界効果：

Wolfram Language code:

ListLinePlot[{data[[-50 ;; -1]], rdata1[[-50 ;; -1]], rdata2[[-50 ;; -1]], rdata3[[-50 ;; -1]]}, PlotStyle -> {Red, Green, Blue, Orange}, BaseStyle -> Thick]

SampleRate (3)

リストの場合，SampleRateのAutomaticの値は1に設定されている：

Wolfram Language code: cwt1 = ContinuousWaveletTransform[Table[Sin[x^2], {x, 0, 1, 0.001}]];

Wolfram Language code: cwt1["SampleRate"]

サンプルレートを明示的に設定する：

Wolfram Language code: cwt2 = ContinuousWaveletTransform[Table[Sin[x^2], {x, 0, 1, 0.001}], SampleRate -> 1000];

Wolfram Language code: cwt2["SampleRate"]

Soundデータの場合は，SampleRateのAutomaticの値はSoundデータオブジェクトから抽出される：

Wolfram Language code: sdata = Sound[{Play[Sin[1000 t (1 + t^2)], {t, 0, .2}], Play[Sin[500 t (1 + t^3)], {t, 0, .5}]}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata];

Wolfram Language code: cwt["SampleRate"]

SampleRateを使ってウェーブレット変換係数が正規化される：

Wolfram Language code: sdata = Sound[{Play[Sin[1000 t (1 + t^2)], {t, 0, .2}], Play[Sin[500 t (1 + t^3)], {t, 0, .5}]}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata, Automatic, {Automatic, 16}]

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "BlueGreenYellow"]

WaveletScale (1)

WaveletScaleは変換に使われる最小の分解可能スケールを示す：

Wolfram Language code: data = Table[Sin[x^2], {x, 0, 3 π, (3 π/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[6], WaveletScale -> 1];

使われるスケールはで与えられる．はウェーブレットスケール，はオクターブ，は音である：

Wolfram Language code: {ws, oct, voc} = cwt[{"WaveletScale", "Octaves", "Voices"}];

Wolfram Language code: Table[ws 2^j / voc, {j, 1, oct voc}] == cwt["Scales"][[All, 2]]

WorkingPrecision (2)

デフォルトでWorkingPrecision->MachinePrecisionが使われる：

Wolfram Language code: data = RandomInteger[1, {10}];

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data, WorkingPrecision -> MachinePrecision]

Wolfram Language code: cwt1 == cwt2

より精度の高い計算を使う：

Wolfram Language code: data = RandomInteger[1, {8}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MexicanHatWavelet[], WorkingPrecision -> 35]

Wolfram Language code: cwt[{1, 1}]

Wolfram Language code: {Precision[cwt], Accuracy[cwt]}

アプリケーション (4)

同一性の特徴 (2)

実際のウェーブレット関数を使って峰や不連続箇所を分離することができる：

Wolfram Language code: data = Table[HeavisideTheta[x], {x, -2, 2, (4/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, DGaussianWavelet[4], {Automatic, 12}, Padding -> "Fixed"]

Wolfram Language code: WaveletScalogram[cwt]

複素ウェーブレットを使って振動運動を捉えることができる：

Wolfram Language code: f[t_, ϵ_] := Sqrt[t (1 - t)] Sin[(2 π (1 + ϵ)/t + ϵ)]

Wolfram Language code: data = Table[f[t, 0.05], {t, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[6], {Automatic, 16}]

ウェーブレット係数の振幅：

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "BlueGreenYellow"]

ウェーブレット係数の位相：

Wolfram Language code: WaveletScalogram[cwt, Automatic, Arg, ColorFunction -> "BlueGreenYellow"]

周波数のフィルタ (2)

ContinuousWaveletTransformを使って周波数をフィルタすることができる：

Wolfram Language code:

f[x_] := Sin[50 π x] Exp[-100 π (x - 0.5)^2] + (Sin[50 π x] + 2 Cos[140 π x]) Exp[-50 π (x - 0.2)^2] + 2 Sin[150 π x] Exp[-80 π (x - 0.8)^2]

Wolfram Language code: data = Table[f[x], {x, 0., 1, (1/2047)}];

Wolfram Language code: ListLinePlot[data, PlotRange -> All]

Wolfram Language code:

cwt = ContinuousWaveletTransform[data, GaborWavelet[6], {10, 16}, Padding -> 0.0, SampleRate -> 2047, WaveletScale -> Automatic];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "SolarColors"]

周波数のコサイン波をフィルタする：

Wolfram Language code:

vec = ConstantArray[1, Length[data]];
vec[[1 ;; 1000]] := 0.0

Wolfram Language code: cwtThresh = WaveletMapIndexed[#1 vec&, cwt, {{4 | 5, _}, {6, u_ /; u < 8}}];

Wolfram Language code: WaveletScalogram[cwtThresh, ColorFunction -> "SolarColors"]

InverseContinuousWaveletTransformを閾値データオブジェクトに対して実行する：

Wolfram Language code: rdata = InverseContinuousWaveletTransform[cwtThresh];

Wolfram Language code: ListLinePlot[{data[[1 ;; 800]], rdata[[1 ;; 800]]}, PlotRange -> All, PlotStyle -> {Blue, {Red, Thick}}]

フィルタされた最終信号：

Wolfram Language code: ListLinePlot[rdata, PlotRange -> All]

スカログラムを使って音符を同定する：

Wolfram Language code: Needs["Music`"]

300Hzに相当する平均律に調律された一連のピッチ生成する：

Wolfram Language code: m300 = MusicScale[TemperedChromatic, 300, 1]

Wolfram Language code: cwd = ContinuousWaveletTransform[m300, GaborWavelet[6], {7, 8}, SampleRate -> 8192];

オクターブと音に相当する分解された周波数を計算する：

Wolfram Language code: freq = (#1[[1]] -> (8192/#1[[2]])&) /@ cwd["Scales"];

周波数を300Hzに分解する{oct,voc}ペアを求める：

Wolfram Language code: Cases[freq, u_ /; 280 ≤ Last[u] ≤ 320]

Wolfram Language code: WaveletScalogram[cwd, {3 | 4 | 5 | 6 | 7, _}]

特性と関係 (1)

オクターブのデフォルト値は $TemplateBox[{{InterpretationBox[{log, _, DocumentationBuild`Utils`Private`Parenth[2]}, Log2, AutoDelete -> True], (, {n, /, 2}, )}}, Floor]$ で与えられる：

Wolfram Language code: data = RandomReal[1, {100}];

Wolfram Language code: oct = Floor[Log2[(Length[data]/2)]]

Wolfram Language code: ContinuousWaveletTransform[data] == ContinuousWaveletTransform[data, Automatic, {oct, Automatic}]

音のデフォルト値は4である：

Wolfram Language code: ContinuousWaveletTransform[data] == ContinuousWaveletTransform[data, Automatic, {Automatic, 4}]

考えられる問題 (1)

低周波数データは高オクターブで分解される：

Wolfram Language code: data = Cos[(Range[1000]/1000)];

入力データの長さに基づき，オクターブのAutomatic設定は8オクターブで分解する：

Wolfram Language code: cwd1 = ContinuousWaveletTransform[data, MorletWavelet[], Automatic]

Wolfram Language code: ListLinePlot[{InverseContinuousWaveletTransform[cwd1], data}]

オクターブの数を増して低周波数要素を分解する：

Wolfram Language code: cwd2 = ContinuousWaveletTransform[data, MorletWavelet[], {12, Automatic}]

Wolfram Language code: ListLinePlot[{InverseContinuousWaveletTransform[cwd2], data}]

おもしろい例題 (1)

Zeta関数のスカログラム：

Wolfram Language code: d = Re[Zeta[(1/2) + I Range[0, 100, 0.01]]];

Wolfram Language code: ListLinePlot[d]

Wolfram Language code: cwd = ContinuousWaveletTransform[d, GaborWavelet[6], {4, 12}, WaveletScale -> 100];

Wolfram Language code:

{WaveletScalogram[cwd, All, Re, ColorFunction -> "CherryTones"], WaveletScalogram[cwd, All, Abs, ColorFunction -> "CherryTones"]}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ContinuousWaveletTransform

詳細とオプション

例題

例 (2)

スコープ (18)

基本的な用法 (6)

タイムとスケールの特徴 (4)

ウェーブレット族 (6)

サウンド (2)

オプション (9)

Padding (3)

SampleRate (3)

WaveletScale (1)

WorkingPrecision (2)

アプリケーション (4)

同一性の特徴 (2)

周波数のフィルタ (2)

特性と関係 (1)

考えられる問題 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ContinuousWaveletTransform

詳細とオプション

例題

例 (2)

スコープ (18)

基本的な用法 (6)

タイムとスケールの特徴 (4)

ウェーブレット族 (6)

サウンド (2)

オプション (9)

Padding (3)

SampleRate (3)

WaveletScale (1)

WorkingPrecision (2)

アプリケーション (4)

同一性の特徴 (2)

周波数のフィルタ (2)

特性と関係 (1)

考えられる問題 (1)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX