ConvolutionLayerは，入力にたたみ込み演算を適用するネットワーク層の一種である．
ConvolutionLayer は，一般に画像パターン認識に用いられるが，空間データ解析，コンピュータビジョン，自然言語処理などにも利用される．
n 個の出力チャンネルを持つ層を，m 個の入力チャンネルおよび一つ以上の空間次元を持つ入力配列に適用した場合，空間次元全体で実質的に n×m 種類の異なるたたみ込みが実行され，その結果として n 個のチャンネルを持つ出力配列が生成される．
ConvolutionLayer[…][input]は，層を input に適用した結果の出力を明示的に計算する
ConvolutionLayer[…][{input₁,input₂,…}]は，各 input_iについて明示的に出力を計算する．
ConvolutionLayer[n,s]では，たたみ込み層の次元性は層がNetChainやNetGraph等の中で接続されたときに推測される．
次の任意のパラメータを含むことができる．

"Biases"	Automatic	カーネルのバイアスの初期ベクトル
"ChannelGroups"	1	チャンネルグループ数
"Dilation"	1	拡大因子
"Dimensionality"	Automatic	たたみ込みの空間次元数
Interleaving	False	チャンネル次元の位置
LearningRateMultipliers	Automatic	カーネルの重みおよび／またはバイアスの学習率乗数
PaddingSize	0	入力に適用するゼロ充填の量
"Stride"	1	使用するたたみ込みの刻み幅
"Weights"	Automatic	カーネルの重みの初期テンソル

PaddingSizeの設定は，次の形式でよい．

	n	全次元の始まりと終りを n 個のゼロで充填する
	{n₁,n₂,…}	第 i 次元の始まりと終りを n 個のゼロで充填する
	{{n₁,m₁},{n₂,m₂},…}	第 i 次元の始まりを n_i個のゼロで，終りを m_i個のゼロで充填する
	"Same"	出力サイズが入力サイズをストライドで割った値（切上げ）と等しくなるように，すべての次元を充填する

"Dilation"と"Stride"の設定は次の形式でよい．
n 全次元に値 n を使う

{…,n_i,…} 第 i 次元に値 n_iを使う
"ChannelGroups"g と設定することで，m 個の入力チャンネルと n 個の出力チャンネルが，それぞれ m/g チャンネルと n/g チャンネルの g 個のグループに分割される．m と n は g で割り切れなければならない．入力チャンネルの i 番目のグループを出力チャンネルの i 番目のグループと接続するために別々のたたみ込みが行われる．結果は出力に連結される．入出力グループの各ペアは n/g×m/g たたみ込みで接続されるので，"ChannelGroups"g という設定は，事実上，明確なたたみ込みの数を n×m から n×m/g に減らす．
"Biases"Noneの設定はバイアスを使わないように指定する．
InterleavingFalseの設定のときは，チャンネル次元は入出力配列の最初の次元であるとみなされる．
InterleavingTrue設定のときは，チャンネル次元は入出力配列の最後の次元であるとみなされる．
重みとバイアスが加えられると，ConvolutionLayer[…][input]は層を適用して明示的に出力を計算する．
ConvolutionLayer[…][{input₁,input₂,…}]は，各 input_iについて明示的に出力を計算する．
NetExtractを使ってConvolutionLayerオブジェクトから重みとバイアスを抽出することができる．
ConvolutionLayerは，NetChain，NetGraph等の中で使われることが多い．
ConvolutionLayerは，NetGraph等で使われる次のポートを開放する．
"Input" 階数が2，3，または4の配列

"Output" 階数が2，3，または4の配列
ConvolutionLayerは，"Varying"次元を含む配列に使うことができる．
より大きいネット中の他の層から推測できない場合は，オプション"Input"{d₁,…,d_n}を使ってConvolutionLayerの入力次元を固定することができる．
次元 d₁×…×d_i×…の入力配列を与えられた場合，出力配列の次元は ×…××…になる．ただし，チャンネル次元 =n で，サイズ d_iはに従って変換される．/は軸の始点／終点の充填サイズ，はカーネルサイズ，はストライドサイズ，は各次元についての拡張因子である．
Options[ConvolutionLayer]は層を構築する際のデフォルトオプションのリストを与える．Options[ConvolutionLayer[…]]はデータについて層を評価する際のデフォルトオプションのリストを与える．
Information[ConvolutionLayer[…]]は層についてのレポートを与える．
Information[ConvolutionLayer[…],prop]はConvolutionLayer[…]の特性 prop の値を与える．使用可能な特性はNetGraphと同じである．

例題

すべて開くすべて閉じる

例 (2)

2個の出力チャンネルとサイズ4のカーネルを持つ，一次元ConvolutionLayerを作る：

Wolfram Language code: ConvolutionLayer[2, {4}]

初期化された3次元ConvolutionLayerを作る：

Wolfram Language code: conv = NetInitialize@ConvolutionLayer[1, {2, 3, 4}, "Input" -> {1, 10, 10, 10}]

この層を入力行列に適用する：

Wolfram Language code: conv[RandomReal[1, {1, 10, 10, 10}]]//Short

スコープ (13)

引数 (3)

3つの出力チャンネルおよび2×2カーネルサイズを持つConvolutionLayerを作成する：

Wolfram Language code: ConvolutionLayer[3, {2, 2}]

3つの出力チャンネルおよび2×2×2のカーネルサイズを持つConvolutionLayerを作成する：

Wolfram Language code: ConvolutionLayer[3, {2, 2, 2}]

5つの出力チャンネル，7つの入力チャンネル，2×2のカーネルサイズを持つConvolutionLayerを作成する：

Wolfram Language code: ConvolutionLayer[5, 2, "Input" -> {7, Automatic, Automatic}]

層を初期化する：

Wolfram Language code: conv = NetInitialize@ConvolutionLayer[5, 2, "Input" -> {7, Automatic, Automatic}]

この層を3×3入力サイズの入力に適用する：

Wolfram Language code: conv[RandomReal[1, {7, 3, 3}]]//Dimensions

6×6入力サイズの入力にこの層を適用する：

Wolfram Language code: conv[RandomReal[1, {7, 6, 6}]]//Dimensions

ポート (3)

初期化された二次元ConvolutionLayerを作る：

Wolfram Language code: conv = NetInitialize@ConvolutionLayer[1, 2, "Input" -> {1, 4, 4}]

この層を入力配列に適用する：

Wolfram Language code: conv[RandomInteger[1, {1, 4, 4}]]

出力も階数3の配列である：

Wolfram Language code: Dimensions[%]

カーネルサイズ2で，初期化された三次元ConvolutionLayerを作る：

Wolfram Language code: conv = NetInitialize@ConvolutionLayer[1, 2, "Input" -> {1, 3, 3}]

この層を入力配列に適用する：

Wolfram Language code: conv[{{{1, 1, 0}, {0, 0, 1}, {1, 1, 0}}}]

RGB画像を取ってRGB画像を返す，初期化された二次元ConvolutionLayerを作る：

Wolfram Language code:

conv = NetInitialize@ConvolutionLayer[3, 10, "Dilation" -> 3, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

ConvolutionLayerは自動的に入力バッチに縫い込まれる：

Wolfram Language code: conv[{[image], [image]}]

パラメータ (7)

"Biases" (3)

バイアスなしで二次元ConvolutionLayerを作成する：

Wolfram Language code: conv = ConvolutionLayer[2, {4, 4}, "Biases" -> None, "Input" -> {1, 40, 40}]

唯一のチャンネルにバイアスを適用する恒等カーネルで一次元ConvolutionLayerを作成する：

Wolfram Language code: conv = ConvolutionLayer["Weights" -> {{{1}}}, "Biases" -> {0.5}]

この層を入力に適用する：

Wolfram Language code: conv[{{1, 2, 3, 4, 5}}]

各チャンネルにバイアスを適用する恒等カーネルで二次元ConvolutionLayerを作成する：

Wolfram Language code:

kernel = ArrayReshape[IdentityMatrix[3], {3, 3, 1, 1}];
conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> {0.5, -0.5, 0.}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

"Weights" (4)

入力配列のペアを平均化するカーネルで一次元ConvolutionLayerを作成する：

Wolfram Language code: conv = ConvolutionLayer["Weights" -> {{{0.5, 0.5}}}, "Biases" -> None]

この層を入力に適用する：

Wolfram Language code: conv[{{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}}] // Normal

3つの入力チャンネルとガウスぼかしを適用する1つの出力チャンネルで二次元 ConvolutionLayerを作成する：

Wolfram Language code:

kernel = Table[GaussianMatrix[5], 1, 3];
conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

チャンネルごとのガウスカーネルで二次元ConvolutionLayerを作成する．まず，カーネルを作成する：

Wolfram Language code:

zero = ConstantArray[0, {19, 19}];
kernel = Table[If[i == j, GaussianMatrix[{9, 6 - 3i}], zero], {i, 0, 2}, {j, 0, 2}];

カーネルを可視化する：

Wolfram Language code: Map[ArrayPlot[#, ImageSize -> 30]&, kernel, {2}]//GraphicsGrid

カーネルを使ってネットを初期化する：

Wolfram Language code:

conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

ランダムなカーネルで二次元ConvolutionLayerを作成する：

Wolfram Language code:

kernel = RandomVariate[NormalDistribution[], {3, 3, 5, 5}];
conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

オプション (12)

"ChannelGroups" (2)

3つのチャンネルグループで二次元のConvolutionLayerを作る：

Wolfram Language code: conv = NetInitialize@ConvolutionLayer[6, {2, 2}, "ChannelGroups" -> 3, "Input" -> {9, 30, 30}]

チャンネルグループを使うことでたたみ込みの重み数がグループ数の割合で削減できる．重みの次元をチェックする：

Wolfram Language code: Dimensions@NetExtract[conv, "Weights"]

類推層の重みの次元を1チャンネルグループと比較する：

Wolfram Language code: conv2 = NetInitialize@ConvolutionLayer[6, {2, 2}, "Input" -> {9, 30, 30}]

Wolfram Language code: Dimensions@NetExtract[conv2, "Weights"]

ランダムな二次元ConvolutionLayerをチャンネルグループを3として作成する：

Wolfram Language code:

conv = NetInitialize@ConvolutionLayer[3, {4, 4}, "ChannelGroups" -> 3, "Input" -> NetEncoder[ "Image"], "Output" -> NetDecoder["Image"]]

"Weights"パラメータの次元をチェックする：

Wolfram Language code: Dimensions@NetExtract[conv, "Weights"]

たたみ込み層を画像に適用する：

Wolfram Language code: conv[[image]]//ImageAdjust

"Dilation" (2)

指定された次元におけるサイズ n の拡張因子は，事実上，距離 n 分だけ離れている入力配列からの要素にカーネルを適用する．

拡張因子が2の一次元ConvolutionLayerを作る：

Wolfram Language code: conv = ConvolutionLayer["Weights" -> {{{0.5, 0.5}}}, "Biases" -> None, "Dilation" -> 2]

この層を入力に適用する：

Wolfram Language code: conv[{{0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}] // Normal

拡張因子が5のランダムな二次元ConvolutionLayerを作る：

Wolfram Language code:

conv = NetInitialize@ConvolutionLayer[3, {3, 3}, "Dilation" -> 5, "Input" -> NetEncoder[ "Image"], "Output" -> NetDecoder["Image"]]

拡張たたみ込み層を画像に適用する：

Wolfram Language code: conv[[image]]

Interleaving (1)

InterleavingFalseと1つの入力チャンネルでConvolutionLayerを作る：

Wolfram Language code: ConvolutionLayer[1, 5, "Input" -> {1, 25, 25}, Interleaving -> False]

InterleavingTrueと1つの入力チャンネルでConvolutionLayerを作る：

Wolfram Language code: ConvolutionLayer[1, 5, "Input" -> {25, 25, 1}, Interleaving -> True]

PaddingSize (4)

隣接要素を平均し各側を4個の0で充填する，一次元ConvolutionLayerを作る：

Wolfram Language code: conv = ConvolutionLayer["Weights" -> {{{0.5, 0.5}}}, "Biases" -> None, PaddingSize -> 4]

この層を入力に適用する：

Wolfram Language code: conv[{{1, 2, 3, 4, 5}}] // Normal

第1次元の各側を10個のゼロで，第2次元の各側を25個のゼロで充填する，ランダムな二次元ConvolutionLayerを作る：

Wolfram Language code:

conv = NetInitialize[ConvolutionLayer[3, {3, 3}, PaddingSize -> {10, 25}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]], RandomSeeding -> Automatic]

Wolfram Language code: conv[[image]]

第1次元の始まりを10個のゼロで，終りを20個のゼロで充填する，ランダムな二次元ConvolutionLayerを作る：

Wolfram Language code:

conv = NetInitialize[ConvolutionLayer[3, {3, 3}, PaddingSize -> {{10, 20}, {0, 0}}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]], RandomSeeding -> Automatic]

Wolfram Language code: conv[[image]]

充填を使って出力次元を入力次元と等しくする：

Wolfram Language code: conv = ConvolutionLayer[1, 5, "Input" -> {1, 25, 25}, PaddingSize -> 2 ]

これを使うと，1に近い入力の幅や高さがなくても，深いネットワークを任意数のたたみ込みで定義することができる．

"Stride" (3)

指定された次元におけるサイズ n のストライドは，事実上，カーネルが出力配列を生成するために入力配列上を移動する刻み幅を制御する．

隣接ペアの平均を取るカーネルを持つ，一次元ConvolutionLayerを作る：

Wolfram Language code:

kernel = {{{0.5, 0.5}}};
conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None]

この層を入力に適用する：

Wolfram Language code: conv[{{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}}] // Normal

ストライド2を使うとカーネルが重なり合ないペアに適用される：

Wolfram Language code:

conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None, "Stride" -> 2];
conv[{{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}}] // Normal

ストライド4を使うとカーネルが1つおきのペアに適用される：

Wolfram Language code:

conv = ConvolutionLayer["Weights" -> kernel, "Biases" -> None, "Stride" -> 4];
conv[{{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}}] // Normal

非対称スライドでランダムな二次元ConvolutionLayerを作る：

Wolfram Language code:

conv = ConvolutionLayer["Weights" -> RandomReal[0.1, {3, 3, 4, 4}], "Biases" -> None, "Stride" -> {3, 1}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]

この層を画像に適用する：

Wolfram Language code: conv[[image]]

より大きいストライドを使って出力次元を減ずる：

Wolfram Language code: conv1 = ConvolutionLayer[30, 7, "Input" -> {3, 500, 500}, "Stride" -> 1 ]

Wolfram Language code: conv2 = ConvolutionLayer[30, 7, "Input" -> {3, 500, 500}, "Stride" -> 7 ]

より大きいストライドは計算時間も減ずることができる：

Wolfram Language code:

data = RandomReal[1, {3, 500, 500}];
conv1 = NetInitialize@conv1;
conv2 = NetInitialize@conv2;
conv1[data];//AbsoluteTiming
conv2[data];//AbsoluteTiming

特性と関係 (2)

次の関数は，入力サイズとパラメータが与えられた際に，非チャンネル次元のサイズを計算する：

Wolfram Language code:

outputSize[inputSize_List, kernSize_, stride_, pad_, dilate_] := Floor[(inputSize + 2 * pad - (dilate * (kernSize - 1) + 1)) / stride] + 1

入力サイズ{256,252}，カーネルサイズ{2,3}，ストライド2，拡張因子{3,4}，充填サイズ{1,2}のときの出力サイズ：

Wolfram Language code: outputSize[{256, 252}, {2, 3}, 2, {1, 2}, {3, 4}]

ConvolutionLayerを使って二次元たたみ込みを計算することができる：

Wolfram Language code:

kernel = {{10, 1}, {1, 3}};
data = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
ConvolutionLayer[1, "Weights" -> {{kernel}}, "Biases" -> {0}][{data}]//First // Normal

これは，カーネルの向きを逆にした後のListConvolveに等しい：

Wolfram Language code: ListConvolve[Reverse[kernel, {1, 2}], data]

考えられる問題 (5)

すべての入出力次元が分かるまでConvolutionLayerは初期化できない：

Wolfram Language code: NetInitialize@ConvolutionLayer[3, {2, 2}]

Wolfram Language code: NetInitialize@ConvolutionLayer[3, 2, "Input" -> {5, 23, 25}]

ConvolutionLayerは記号入力を受け付けない：

Wolfram Language code:

conv = NetInitialize@ConvolutionLayer[1, {1, 1}, "Input" -> {1, 1, 1}];
conv[{{{1}}}]

Wolfram Language code: conv[{{{x}}}]

カーネルサイズが入力次元より大きくてはならない：

Wolfram Language code: ConvolutionLayer[3, {15, 15}, "Input" -> {3, 10, 10}]

"ChannelGroups"は入力チャネル数の約数でなければならない：

Wolfram Language code: ConvolutionLayer[6, 2, "ChannelGroups" -> 3, "Input" -> {3, Automatic, Automatic}]

Wolfram Language code: ConvolutionLayer[6, 2, "ChannelGroups" -> 4, "Input" -> {3, Automatic, Automatic}]

ConvolutionLayer は，入力サイズが異なる入力のバッチには適用することができない：

Wolfram Language code:

conv = NetInitialize@ConvolutionLayer[3, {2, 2}, "Input" -> {2, Automatic, Automatic}];
conv[RandomReal[1, {2, 2, 3, 3}]]

Wolfram Language code: conv@{RandomReal[1, {2, 3, 3}], RandomReal[1, {2, 4, 4}]}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ConvolutionLayer

詳細とオプション

例題

例 (2)

スコープ (13)

引数 (3)

ポート (3)

パラメータ (7)

"Biases" (3)

"Weights" (4)

オプション (12)

"ChannelGroups" (2)

"Dilation" (2)

Interleaving (1)

PaddingSize (4)

"Stride" (3)

特性と関係 (2)

考えられる問題 (5)

テキスト

CMS

APA

BibTeX

BibLaTeX

	n	全次元に値 n を使う
	{…,n_i,…}	第 i 次元に値 n_iを使う

	"Input"	階数が2，3，または4の配列
	"Output"	階数が2，3，または4の配列

ConvolutionLayer

詳細とオプション

例題

例 (2)

スコープ (13)

引数 (3)

ポート (3)

パラメータ (7)

"Biases" (3)

"Weights" (4)

オプション (12)

"ChannelGroups" (2)

"Dilation" (2)

Interleaving (1)

PaddingSize (4)

"Stride" (3)

特性と関係 (2)

考えられる問題 (5)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX