WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoreNilpotentDecomposition[m]

正方行列 m のコアベキ零分解を与える．

CoreNilpotentDecomposition[m,format]

指定の format に従ってコアベキ零分解を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特殊行列  
オプション  
TargetStructure  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CoreNilpotentDecomposition

CoreNilpotentDecomposition[m]

正方行列 m のコアベキ零分解を与える．

CoreNilpotentDecomposition[m,format]

指定の format に従ってコアベキ零分解を返す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

正方行列のコアベキ零分解を計算する：

Wolfram Language code: CoreNilpotentDecomposition[(⁠| | | | | - | - | - | | 1 | 2 | 0 | | 5 | 1 | 3 | | 0 | 0 | 0 |⁠)]

結果をフォーマットする：

Wolfram Language code: MatrixForm /@ %

4×4行列のコアベキ零分解：

Wolfram Language code: (m = {{-1, 0, 3, 2}, {2, 3, 3, -1}, {0, 0, -2, -1}, {0, 0, 4, 2}})//MatrixForm
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

m との関係を検証する：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

スコープ  (12)

基本的な用法  (7)

機械精度行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{0.2, -0.32}, {0.1, -0.16}}]

複素行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{-4 + 6 I, 8 - 10 I, 2}, {-2 + 3 I, 4 - 5 I, 1}, {1, -1, 1}}]

厳密行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{14, -22, 2}, {7, -11, 1}, {0, 0, 0}}]

任意精度行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[RandomReal[4, {2, 2}, WorkingPrecision -> 9]]

記号行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{a, a, 1}, {0, 0, 0}, {2, 3, -1}}]//Simplify

大きい機械精度行列の分解は効率的に行われる：

Wolfram Language code: r = RandomReal[{0, 1}, {500, 500}];
Wolfram Language code: AbsoluteTiming[CoreNilpotentDecomposition[r];]

CoreNilpotentDecomposition[m]はCoreNilpotentDecomposition[m,"SplitBlocks"]に等しい．ただし，コア部分とベキ零部分は分離されている：

Wolfram Language code: CoreNilpotentDecomposition[{{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}}, "SplitBlocks"]

CoreNilpotentDecomposition[m,"BlockDiagonal"]は，ブロック対角行列中にコア部分とベキ零部分をまとめる：

Wolfram Language code: CoreNilpotentDecomposition[{{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}}, "BlockDiagonal"]

特殊行列  (5)

疎な行列のコアベキ零分解：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {4, 4}]
Wolfram Language code: CoreNilpotentDecomposition[%]

構造化行列のコアベキ零分解：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 0, {3, 1} -> -5}, {3, 3}, Symmetric[All]]
Wolfram Language code: CoreNilpotentDecomposition[%]

恒等行列は自明なコアベキ零分解を持つ：

Wolfram Language code: CoreNilpotentDecomposition[IdentityMatrix[3]]

ヒルベルト(Hilbert)行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[HilbertMatrix[3]]

厳密な上三角行列のコアベキ零分解：

Wolfram Language code: CoreNilpotentDecomposition[(| | | | | - | - | - | | 0 | a | b | | 0 | 0 | c | | 0 | 0 | 0 |)]

オプション  (1)

TargetStructure  (1)

TargetStructure->"Dense"のとき，CoreNilpotentDecomposition[m,"BlockDiagonal"]は2つの行列のリストを返す：

Wolfram Language code: {t, b} = CoreNilpotentDecomposition[(⁠| | | | | | -- | -- | -- | -- | | -6 | -3 | -4 | 2 | | 0 | -1 | 0 | 1 | | 9 | 6 | 6 | -2 | | 0 | 4 | 0 | 1 |⁠), "BlockDiagonal", TargetStructure -> "Dense"]

2番目の行列は，コア部分とベキ零部分からなるブロック対角行列である：

Wolfram Language code: MatrixForm[b]

TargetStructure->"Structured"のとき，2番目の行列はBlockDiagonalMatrixとして表される：

Wolfram Language code: CoreNilpotentDecomposition[(⁠| | | | | | -- | -- | -- | -- | | -6 | -3 | -4 | 2 | | 0 | -1 | 0 | 1 | | 9 | 6 | 6 | -2 | | 0 | 4 | 0 | 1 |⁠), "BlockDiagonal", TargetStructure -> "Structured"]

アプリケーション  (2)

特異係数を持つ行列微分方程式 , を解く：

Wolfram Language code: a = (| | | | | -- | - | -- | | 1 | 0 | -2 | | -1 | 0 | 2 | | 2 | 3 | 2 |);b = (| | | | | --- | --- | --- | | 0 | 1 | 2 | | -27 | -22 | -17 | | 18 | 14 | 10 |);v = {-1, -8, 13};

と はどちらも特異なので，この方程式は標準形 にすることはできない：

Wolfram Language code: {Det[a], Det[b]}

の解のコアベキ零分解を計算する：

Wolfram Language code: {s, c, n} = CoreNilpotentDecomposition[LinearSolve[a + b, a]]

d=s.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{s}, Inverse]とする：

Wolfram Language code: d = s.PadRight[Inverse[c], Dimensions[a]].Inverse[s]

そうすると，解は になる．ただし， は の解である：

Wolfram Language code: MatrixExp[-d.LinearSolve[a + b, b]t].v//FullSimplify

DSolveValueの結果と比較する：

Wolfram Language code: DSolveValue[{a.y'[t] + b.y[t] == 0, y[0] == v}, y[t]∈Vectors[3], t]

特異係数行列 を持つ行列微分方程式 の一般解を求める：

Wolfram Language code: m = (⁠| | | | | -- | -- | -- | | 4 | 2 | -2 | | -8 | -3 | 1 | | -6 | -2 | 0 |⁠);

行列 は特異行列である：

Wolfram Language code: Det[m]

コアベキ零分解を使ってt d=t.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{t}, Inverse]とする：

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m]; d = t.PadRight[Inverse[c], Dimensions[m]].Inverse[t]

解は である．ただし， は任意のベクトルである：

Wolfram Language code: x[k_] = Simplify[MatrixPower[d, k + 1].m.{C[1], C[2], C[3]}, k > 0]

解を確認する：

Wolfram Language code: m.x[k + 1] == x[k]//Simplify

特性と関係  (4)

CoreNilpotentDecompositionはトリプル{t,c,n}を返す：

Wolfram Language code: (m = {{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}})//MatrixForm
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

行列 c は非特異である：

Wolfram Language code: c//MatrixForm
Wolfram Language code: Det[c] != 0

行列 n はベキ零である：

Wolfram Language code: n
Wolfram Language code: MatrixPower[n, 2]

もとの行列 m はそのコアベキ零分解によって表すことができる：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

可逆行列の分解のコア部分はその行列に等しい：

Wolfram Language code: m = {{3, 4}, {5, 7}};
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: c == m

分解のベキ零部分は空リストである：

Wolfram Language code: n

相似行列 t は恒等行列であるとみなされる：

Wolfram Language code: t//MatrixForm

それにもかかわらず，BlockDiagonalMatrixを使って表された恒等式は成立する：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

ベキ零行列の分解のベキ零部分はその行列に等しい：

Wolfram Language code: m = {{2, 2, -2}, {5, 1, -3}, {1, 5, -3}};
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: n == m

分解のコア部分は空リストである：

Wolfram Language code: c

相似行列 t は恒等行列であるとみなされる：

Wolfram Language code: t//MatrixForm

それにもかかわらず，BlockDiagonalMatrixを使って表された恒等式は成立する：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

DrazinInverseはCoreNilpotentDecompositionで計算できる：

Wolfram Language code: m = {{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}};
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: d = DrazinInverse[m];

等式 m^D=t.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{t}, Inverse]を確認する：

Wolfram Language code: d === t.PadRight[Inverse[c], Dimensions[m]].Inverse[t]

考えられる問題  (2)

コアベキ零分解は一意的ではない：

Wolfram Language code: bd = (| | | | | | | - | - | - | -- | - | | 2 | 1 | 0 | 0 | 0 | | 1 | 2 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 | 0 | | 0 | 0 | 1 | 0 | 0 | | 0 | 0 | 0 | -1 | 0 |); tm = (⁠| | | | | | | -- | -- | -- | -- | -- | | 1 | -1 | 1 | 0 | 0 | | -1 | 0 | 0 | 1 | 1 | | 0 | 0 | -1 | 0 | -1 | | 0 | 0 | -1 | -1 | 1 | | 0 | 0 | 0 | 0 | -1 |⁠);
Wolfram Language code: MatrixForm /@ CoreNilpotentDecomposition[tm.bd.Inverse[tm], "BlockDiagonal", TargetStructure -> "Dense"]

または は{}でもよいが，両方がそうであってはならない：

Wolfram Language code: m = {{3, 4}, {5, 7}};
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: n === {}

MatrixQ[{}]はFalseを与える：

Wolfram Language code: MatrixQ[{}]

BlockDiagonalMatrixは{}を0×0行列と解釈するので，この関数を使ってもとの行列を再構築する：

Wolfram Language code: BlockDiagonalMatrix[{c, n}]//Normal
Wolfram Research (2021), CoreNilpotentDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html （2023年に更新）.

テキスト

Wolfram Research (2021), CoreNilpotentDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CoreNilpotentDecomposition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html.

APA

Wolfram Language. (2021). CoreNilpotentDecomposition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html

BibTeX

@misc{reference.wolfram_2026_corenilpotentdecomposition, author="Wolfram Research", title="{CoreNilpotentDecomposition}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_corenilpotentdecomposition, organization={Wolfram Research}, title={CoreNilpotentDecomposition}, year={2023}, url={https://reference.wolfram.com/language/ref/CoreNilpotentDecomposition.html}, note=[Accessed: 11-September-2026]}