Wolfram 语言与系统参考资料中心

CoreNilpotentDecomposition

生成方阵 m 的核-幂零分解.

CoreNilpotentDecomposition[m,format]

根据指定 format 返回核心-零分解.

范例

打开所有单元关闭所有单元

基本范例 (2)

计算方阵的核-幂零分解：

Wolfram Language code:

CoreNilpotentDecomposition[(⁠|   |   |   |
| - | - | - |
| 1 | 2 | 0 |
| 5 | 1 | 3 |
| 0 | 0 | 0 |⁠)]

格式化结果：

Wolfram Language code: MatrixForm /@ %

4×4 矩阵的核-幂零分解：

Wolfram Language code: (m = {{-1, 0, 3, 2}, {2, 3, 3, -1}, {0, 0, -2, -1}, {0, 0, 4, 2}})//MatrixForm

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

验证与 m 的关系：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

范围 (12)

基本用法 (7)

机器精度矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{0.2, -0.32}, {0.1, -0.16}}]

复矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{-4 + 6 I, 8 - 10 I, 2}, {-2 + 3 I, 4 - 5 I, 1}, {1, -1, 1}}]

精确矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{14, -22, 2}, {7, -11, 1}, {0, 0, 0}}]

任意精度矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[RandomReal[4, {2, 2}, WorkingPrecision -> 9]]

符号矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[{{a, a, 1}, {0, 0, 0}, {2, 3, -1}}]//Simplify

有效进行大型机器精度矩阵的分解：

Wolfram Language code: r = RandomReal[{0, 1}, {500, 500}];

Wolfram Language code: AbsoluteTiming[CoreNilpotentDecomposition[r];]

CoreNilpotentDecomposition[m] 等价于 CoreNilpotentDecomposition[m,"SplitBlocks"]，其中核心部分和幂零部分保持分开：

Wolfram Language code: CoreNilpotentDecomposition[{{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}}, "SplitBlocks"]

CoreNilpotentDecomposition[m,"BlockDiagonal"] 将核心部分和幂零部分合并为一个块对角矩阵：

Wolfram Language code: CoreNilpotentDecomposition[{{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}}, "BlockDiagonal"]

特殊矩阵 (5)

稀疏矩阵的核-幂零分解：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {4, 4}]

Wolfram Language code: CoreNilpotentDecomposition[%]

结构化矩阵的核-幂零分解：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 0, {3, 1} -> -5}, {3, 3}, Symmetric[All]]

Wolfram Language code: CoreNilpotentDecomposition[%]

单位矩阵有一个平凡的核幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[IdentityMatrix[3]]

希尔伯特矩阵的核-幂零分解：

Wolfram Language code: CoreNilpotentDecomposition[HilbertMatrix[3]]

严格的上三角矩阵的核幂零分解：

Wolfram Language code:

CoreNilpotentDecomposition[(|   |   |   |
| - | - | - |
| 0 | a | b |
| 0 | 0 | c |
| 0 | 0 | 0 |)]

选项 (1)

TargetStructure (1)

设置 TargetStructure->"Dense"，CoreNilpotentDecomposition[m,"BlockDiagonal"] 返回两个矩阵的列表：

Wolfram Language code:

{t, b} = CoreNilpotentDecomposition[(⁠|    |    |    |    |
| -- | -- | -- | -- |
| -6 | -3 | -4 | 2  |
| 0  | -1 | 0  | 1  |
| 9  | 6  | 6  | -2 |
| 0  | 4  | 0  | 1  |⁠), "BlockDiagonal", TargetStructure -> "Dense"]

第二个矩阵是一个由核心部分和幂零部分组成的块对角矩阵：

Wolfram Language code: MatrixForm[b]

设置 TargetStructure->"Structured"，第二个矩阵会以 BlockDiagonalMatrix 的形式表示：

Wolfram Language code:

CoreNilpotentDecomposition[(⁠|    |    |    |    |
| -- | -- | -- | -- |
| -6 | -3 | -4 | 2  |
| 0  | -1 | 0  | 1  |
| 9  | 6  | 6  | -2 |
| 0  | 4  | 0  | 1  |⁠), "BlockDiagonal", TargetStructure -> "Structured"]

应用 (2)

用奇异系数求解矩阵微分方程 , ：

Wolfram Language code:

a = (|    |   |    |
| -- | - | -- |
| 1  | 0 | -2 |
| -1 | 0 | 2  |
| 2  | 3 | 2  |);b = (|     |     |     |
| --- | --- | --- |
| 0   | 1   | 2   |
| -27 | -22 | -17 |
| 18  | 14  | 10  |);v = {-1, -8, 13};

和都为奇异，所以方程不能写成标准形式：

Wolfram Language code: {Det[a], Det[b]}

计算的解的核幂零分解：

Wolfram Language code: {s, c, n} = CoreNilpotentDecomposition[LinearSolve[a + b, a]]

假使：

Wolfram Language code: d = s.PadRight[Inverse[c], Dimensions[a]].Inverse[s]

则解为，其中为的解：

Wolfram Language code: MatrixExp[-d.LinearSolve[a + b, b]t].v//FullSimplify

对比 DSolveValue 给出的结果：

Wolfram Language code: DSolveValue[{a.y'[t] + b.y[t] == 0, y[0] == v}, y[t]∈Vectors[3], t]

求矩阵差分方程与奇异系数矩阵的通解：

Wolfram Language code:

m = (⁠|    |    |    |
| -- | -- | -- |
| 4  | 2  | -2 |
| -8 | -3 | 1  |
| -6 | -2 | 0  |⁠);

矩阵为奇异矩阵：

Wolfram Language code: Det[m]

使用核-幂零分解，假使：

Wolfram Language code:

{t, c, n} = CoreNilpotentDecomposition[m];
d = t.PadRight[Inverse[c], Dimensions[m]].Inverse[t]

解为，其中为任意向量：

Wolfram Language code: x[k_] = Simplify[MatrixPower[d, k + 1].m.{C[1], C[2], C[3]}, k > 0]

验证该解：

Wolfram Language code: m.x[k + 1] == x[k]//Simplify

属性和关系 (4)

CoreNilpotentDecomposition 返回三元组 {t,c,n}：

Wolfram Language code: (m = {{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}})//MatrixForm

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

矩阵 c 是非奇异的：

Wolfram Language code: c//MatrixForm

Wolfram Language code: Det[c] != 0

矩阵 n 是幂零的：

Wolfram Language code: n

Wolfram Language code: MatrixPower[n, 2]

原始矩阵 m 可以用其核-幂零分解表示：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

可逆矩阵分解的核心部分等于矩阵：

Wolfram Language code: m = {{3, 4}, {5, 7}};

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

Wolfram Language code: c == m

分解的幂零部分是一个空矩阵：

Wolfram Language code: n

相似性矩阵 t 被视为单位矩阵：

Wolfram Language code: t//MatrixForm

尽管如此，使用 BlockDiagonalMatrix 表示的恒等式仍然成立：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

幂零矩阵分解的幂零部分等于矩阵：

Wolfram Language code: m = {{2, 2, -2}, {5, 1, -3}, {1, 5, -3}};

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

Wolfram Language code: n == m

分解的核心部分是一个空列表：

Wolfram Language code: c

相似性矩阵 t 被视为单位矩阵：

Wolfram Language code: t//MatrixForm

尽管如此，使用 BlockDiagonalMatrix 表达的恒等式仍然成立：

Wolfram Language code: m == t.BlockDiagonalMatrix[{c, n}].Inverse[t]

可用 CoreNilpotentDecomposition 进行计算 DrazinInverse：

Wolfram Language code: m = {{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}};

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

Wolfram Language code: d = DrazinInverse[m];

验证相等 $m^D=t.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{t}, Inverse]$ ：

Wolfram Language code: d === t.PadRight[Inverse[c], Dimensions[m]].Inverse[t]

可能存在的问题 (2)

核-幂零分解不是唯一的：

Wolfram Language code:

bd = (|   |   |   |    |   |
| - | - | - | -- | - |
| 2 | 1 | 0 | 0  | 0 |
| 1 | 2 | 0 | 0  | 0 |
| 0 | 0 | 0 | 0  | 0 |
| 0 | 0 | 1 | 0  | 0 |
| 0 | 0 | 0 | -1 | 0 |);
tm = (⁠|    |    |    |    |    |
| -- | -- | -- | -- | -- |
| 1  | -1 | 1  | 0  | 0  |
| -1 | 0  | 0  | 1  | 1  |
| 0  | 0  | -1 | 0  | -1 |
| 0  | 0  | -1 | -1 | 1  |
| 0  | 0  | 0  | 0  | -1 |⁠);

Wolfram Language code: MatrixForm /@ CoreNilpotentDecomposition[tm.bd.Inverse[tm], "BlockDiagonal", TargetStructure -> "Dense"]

或都可能等于 {}，但不会两个都等于 {}：

Wolfram Language code: m = {{3, 4}, {5, 7}};

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];

Wolfram Language code: n === {}

MatrixQ[{}] 给出 False：

Wolfram Language code: MatrixQ[{}]

用 BlockDiagonalMatrix 重新构建原始矩阵，因为它将 {} 解释为 0×0 的矩阵：

Wolfram Language code: BlockDiagonalMatrix[{c, n}]//Normal

Top

Method	Automatic	要使用的方法
TargetStructure	Automatic	返回的矩阵的结构
Tolerance	Automatic	计算中允许的容差

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CoreNilpotentDecomposition

更多信息和选项

范例

基本范例 (2)

范围 (12)

基本用法 (7)

特殊矩阵 (5)

选项 (1)

TargetStructure (1)

应用 (2)

属性和关系 (4)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

CoreNilpotentDecomposition

更多信息和选项

范例

基本范例 (2)

范围 (12)

基本用法 (7)

特殊矩阵 (5)

选项 (1)

TargetStructure (1)

应用 (2)

属性和关系 (4)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX