WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Correlation[v,w]

ベクトル v とベクトル w の間の相関を与える．

Correlation[a,b]

行列 a と b の相互相関行列を与える．

Correlation[a]

行列 a の観測値についての自己相関行列与える．

Correlation[dist]

多変量記号分布 dist の相関行列を返す．

Correlation[dist,i,j]

多変量記号分布 dist の(i,j)番目の相関を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ  
分布と過程  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Correlation

Correlation[v,w]

ベクトル v とベクトル w の間の相関を与える．

Correlation[a,b]

行列 a と b の相互相関行列を与える．

Correlation[a]

行列 a の観測値についての自己相関行列与える．

Correlation[dist]

多変量記号分布 dist の相関行列を返す．

Correlation[dist,i,j]

多変量記号分布 dist の(i,j)番目の相関を返す．

詳細

  • Correlationは，一般に，共分散，つまり，一つの変数が他の変数と同じように変化する傾向があるかどうかを測定する．
  • ベクトルについて，相関推定Correlation[v,w]は で与えられる．ただし，σv w=Covariance[v,w]かつ σv=StandardDeviation[v]である．
  • 相関 はで正規化された共分散である．
  • 次元が と で列に と のインデックスが付いた行列 と について，Correlation[a,b]は要素が で与えられる 行列である．
  • ただし，Σa b=Covariance[a,b]かつ σa=StandardDeviation[a]等である．
  • 列の行列 a について，Correlation[a]はCorrelation[a, a]で与えられ 行列である．
  • CorrelationはVectorQである任意のベクトルとMatrixQである任意の行列に使うことができる．
  • Correlation[dist,i,j]はCovariance[dist,i,j]/(σi σj)を返す．ただし，σi=StandardDeviation[dist]〚i〛である．
  • Correlation[dist] は(i,j)番目の成分がCorrelation[dist,i,j]で与えられる相関行列を与える．

例題

すべて開く すべて閉じる

例  (3)

2つのベクトル間の相関：

Wolfram Language code: Correlation[{a, b}, {x, y}]

実数値：

Wolfram Language code: Refine[%, {a, b, x, y}∈Reals]

行列の相関行列：

Wolfram Language code: Correlation[{{a, b}, {c, d}}]

実数値：

Wolfram Language code: Refine[%, {a, b, c, d}∈Reals]

2つの行列の相関行列：

Wolfram Language code: Correlation[{{a, b}, {c, d}}, {{x}, {y}}]//MatrixForm

実数値：

Wolfram Language code: Refine[%, {a, b, c, d, x, y}∈Reals]

スコープ  (14)

データ  (8)

厳密な入力は厳密な出力を与える：

Wolfram Language code: Correlation[{5, 3 / 4, 1}, {2, 1 / 2, 1}]
Wolfram Language code: Correlation[{1, π, 2}, {2, 2, 1}]//Simplify

近似入力は近似出力を与える：

Wolfram Language code: Correlation[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: Correlation[N[{1, 2, 5, 6}, 20], N[{2, 3, 6, 8}, 20]]

複素ベクトル間の相関：

Wolfram Language code: Correlation[{2 + I, 3 - 2I, 5 + 4I}, {I, 1 + 2I, 10 - 5I}]

大規模配列に使うことができる：

Wolfram Language code: Correlation[RandomReal[1, 10 ^ 7], RandomReal[1, 10 ^ 7]]

構造化配列を使うことができる（ガイドを参照のこと）：

Wolfram Language code: Correlation[SparseArray[{{1, 2} -> 1.2, {2, 2} -> 1, {3, 1} -> 2}]]//MatrixForm
Wolfram Language code: Correlation[IdentityMatrix[2]]//MatrixForm
Wolfram Language code: Correlation[ToeplitzMatrix[4]]//MatrixForm
Wolfram Language code: Correlation[QuantityArray[RandomReal[1, {20, 2}], "Meters"]]//MatrixForm

数量を含むデータについての相関を求める：

Wolfram Language code: v = Quantity[{2, 3.5, 4, 5}, "Meters"]; w = Quantity[{10, 32, 19, 24.2}, "Pounds"];
Wolfram Language code: Correlation[v, w]

日付のリスト間の相関：

Wolfram Language code: v = RandomDate[4]
Wolfram Language code: w = RandomDate[4]
Wolfram Language code: Correlation[v, w]

時間の行列間の相関：

Wolfram Language code: Correlation[RandomTime[{4, 2}], RandomTime[{4, 3}]]//MatrixForm

分布と過程  (6)

多変量連続分布の相関：

Wolfram Language code: Correlation[BinormalDistribution[ρ]]//MatrixForm
Wolfram Language code: Correlation[BinormalDistribution[ρ], 2, 1]

多変量離散分布の相関：

Wolfram Language code: Correlation[MultivariatePoissonDistribution[μ, {2, 3}]]//MatrixForm
Wolfram Language code: Correlation[MultivariatePoissonDistribution[μ, {2, 3}], 2, 1]

相関は，多変量確率分布の方向と鮮明さを制御する：

Wolfram Language code: dists = { BinormalDistribution[-0.7], BinormalDistribution[0], BinormalDistribution[0.99] };
Wolfram Language code: colors = Table[ColorData[97, i], {i, 3}]; GraphicsRow[Table[ Plot3D[PDF[dists[[i]], {x, y}], {x, -3.5, 3.5}, {y, -3.5, 3.5}, PlotRange -> All, PlotStyle -> {colors[[i]]}, Ticks -> None, MeshStyle -> Opacity[.1], AxesLabel -> {"*x*", "*y*", None}, PlotLabel -> dists[[i]], ViewPoint -> {0, 2, 2} ] , {i, 3} ], ImageSize -> {500, 500 .3} ]

派生分布の相関：

Wolfram Language code: Correlation[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 2}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: Correlation[𝒟]//MatrixForm

データ分布の相関：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: Correlation[𝒟]//MatrixForm
Wolfram Language code: Correlation[BinormalDistribution[.75]]//MatrixForm

時点 s および t におけるランダム過程についての相関行列：

Wolfram Language code: Correlation[WienerProcess[][{s, t}]]//MatrixForm

時点およびにおけるTemporalDataの相関行列：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]
Wolfram Language code: Correlation[td[{0.2, 0.3}]]//MatrixForm

アプリケーション  (3)

2つの金融時系列の相関関係を計算する：

Wolfram Language code: gspc = TemporalData[TimeSeries, {{{2058.2, 2020.58, 2002.61, 2025.9, 2062.14, 2044.81, 2028.26, 2023.03, 2011.27, 1992.67, 2019.42, 2022.55, 2032.12, 2063.15, 2051.82, 2057.09, 2029.55, 2002.16, 2021.25, 1994.99, 2020.85, 2050.03, 2041.51, 2062. ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: ndx = TemporalData[TimeSeries, {{{4230.2368, 4160.9644, 4110.8301, 4159.9995, 4240.5495, 4213.2758, 4169.9704, 4166.2025, 4145.8414, 4089.6482, 4142.1401, 4171.2143, 4192.0934, 4270.3628, 4278.1424, 4275.7154, 4165.5017, 4140.3756, 4181.3514, 4 ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: Correlation[gspc["Values"], ndx["Values"]]

Correlationを使った線形関係を測ることができる：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 3000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", Correlation[i][[1, 2]]}]], {i, data}], 3]]

Correlationは単調関係しか検出できない：

Wolfram Language code: uni = RandomReal[{-3, 3}, 3000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", Correlation[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingDを使ってさまざまな依存構造を検出することができる：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

特性と関係  (7)

相関行列は対称かつ半正定値の行列である：

Wolfram Language code: corr = Correlation[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[corr]
Wolfram Language code: PositiveSemidefiniteMatrixQ[corr]

相関行列は標準偏差でスケールされた共分散行列である：

Wolfram Language code: data = RandomReal[5, {20, 5}];
Wolfram Language code: s = DiagonalMatrix[1 / StandardDeviation[data]];
Wolfram Language code: Correlation[data] == s.Covariance[data].s
Wolfram Language code: {a, b} = RandomReal[1, {2, 3, 2}];
Wolfram Language code: invS = TensorProduct@@((StandardDeviation /@ {a, b}) ^ -1);
Wolfram Language code: Covariance[a, b] invS == Correlation[a, b]

CorrelationおよびAbsoluteCorrelationは，ゼロ平均および単位周辺分散について一致する：

Wolfram Language code: 𝒟 = BinormalDistribution[ρ];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]
Wolfram Language code: Correlation[𝒟]
Wolfram Language code: AbsoluteCorrelation[𝒟]

SpearmanRhoは，順位に適用されたCorrelationである：

Wolfram Language code: data = Transpose@RandomVariate[BinormalDistribution[.8], 100];
Wolfram Language code: SpearmanRho[data[[1]], data[[2]]]
Wolfram Language code: rnks = Ordering[Ordering[#]]& /@ data;
Wolfram Language code: Correlation[rnks[[1]], rnks[[2]]]//N

過程についてのCorrelationFunctionは，相関行列における非対角要素である：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: Correlation[𝒫[{s, t}], 1, 2]
Wolfram Language code: CorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

CorrelationおよびCovarianceは，標準化ベクトルについて等しい：

Wolfram Language code: sample = RandomVariate[DiscreteUniformDistribution[{{2, 3}, {4, 5}}], 200];
Wolfram Language code: Covariance[sample] === Correlation[sample]
Wolfram Language code: Covariance[Standardize[sample]] === Correlation[sample]

相関行列の対角要素は1に等しい：

Wolfram Language code: Diagonal[Correlation[RandomReal[10, {100, 4}]]]
Wolfram Research (2007), Correlation, Wolfram言語関数， https://reference.wolfram.com/language/ref/Correlation.html （2024年に更新）.

テキスト

Wolfram Research (2007), Correlation, Wolfram言語関数， https://reference.wolfram.com/language/ref/Correlation.html （2024年に更新）.

CMS

Wolfram Language. 2007. "Correlation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/Correlation.html.

APA

Wolfram Language. (2007). Correlation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Correlation.html

BibTeX

@misc{reference.wolfram_2026_correlation, author="Wolfram Research", title="{Correlation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/Correlation.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_correlation, organization={Wolfram Research}, title={Correlation}, year={2024}, url={https://reference.wolfram.com/language/ref/Correlation.html}, note=[Accessed: 15-September-2026]}