WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Count[list,pattern]

list において pattern にマッチする要素の数を与える．

Count[expr,pattern,levelspec]

式 expr の levelspec で指定されたレベルに現れ，pattern にマッチする部分式の数を与える．

Count[pattern]

式に適用可能なCountの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
Heads  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Count

Count[list,pattern]

list において pattern にマッチする要素の数を与える．

Count[expr,pattern,levelspec]

式 expr の levelspec で指定されたレベルに現れ，pattern にマッチする部分式の数を与える．

Count[pattern]

式に適用可能なCountの演算子形を表す．

詳細とオプション

  • Countの第1引数が頭部Listを持つ必要はない．
  • Associationに用いられた場合，Countは要素の値のみを検定する．そのキーは検定しない．
  • Countは，標準的なレベル指定を使用する．
  • nレベル 1 からレベル n まで
    Infinityレベル 1 からInfinityまで
    {n}レベル n のみ
    {n1,n2}レベル n1から n2まで
  • Countにおける levelspec のデフォルト値は{1}である．
  • 正のレベル n は，n 個の指標によって指定された expr のすべての部分からなる．
  • 負のレベル -n は，expr の深さ n のすべての部分からなる．
  • レベル-1は，数，記号その他の下位区分を持たないオブジェクトからなる．
  • レベル0は式全体に相当する．
  • オプション設定がHeads->Trueのとき，Countは式の頭部とその部分を見る．
  • Count[pattern][expr]はCount[expr,pattern]に等しい．
  • Parallelize[Count[list,pattern]]はCount[list,pattern]をすべてのサブカーネルで並列に計算する． »

例題

すべて開く すべて閉じる

例  (4)

bが何回現れるか数える：

Wolfram Language code: Count[{a, b, a, a, b, c, b}, b]

Association中のxのベキを数える：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, x ^ _]

すべてのレベルにおけるxのベキを数える：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, x ^ _, Infinity]

記号を数える：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, _Symbol, Infinity]

スコープ  (5)

Countはパターンと使うことができる：

Wolfram Language code: Count[{a, 2, a, a, 1, c, b, 3, 3}, _Integer]

bにマッチしない要素数を数える：

Wolfram Language code: Count[{a, b, a, a, b, c, b, a, a}, Except[b]]

bの出現をレベル2まで数える：

Wolfram Language code: Count[{{a, a, b}, b, {a, b, a}}, b, 2]

レベル2での出現だけを数える：

Wolfram Language code: Count[{{a, a, b}, b, {a, b, a}}, b, {2}]

より大きい数式の一部として現れるすべての数式を数える：

Wolfram Language code: Count[x ^ 3 + 1.5x ^ 2 + Pi x + 7, _ ? NumericQ, -1]

数値によるレベル指定はレベル0を含まない：

Wolfram Language code: Count[5, _ ? NumericQ, -1]

要素が2つのリストを使って明示的にレベル0を含むようにする：

Wolfram Language code: Count[5, _ ? NumericQ, {0, -1}]

一般化と拡張  (1)

CountはListだけでなく任意の頭部に使うことができる：

Wolfram Language code: Count[f[a, b, b, a], b]

オプション  (1)

Heads  (1)

デフォルトで，頭部として現れる式は数えられない：

Wolfram Language code: Count[Sin[x] + Cos[x] + Sin[x] ^ 2, Sin, -1]

オプションHeads->Trueを使ってこれらが含まれるようにする：

Wolfram Language code: Count[Sin[x] + Cos[x] + Sin[x] ^ 2, Sin, -1, Heads -> True]

アプリケーション  (3)

式中の記号の総数を数える：

Wolfram Language code: Count[a + b ^ 2 / (a + b), _Symbol, Infinity]

0.5より大きい要素の総数を数える：

Wolfram Language code: Count[RandomReal[1, {100}], u_ /; u > 0.5]

最初の要素が1である行の数を数える：

Wolfram Language code: Count[{{1, 2}, {2, 3}, {1, 5}}, {u_, _} /; u == 1]

特性と関係  (5)

Countは，Casesが与える結果の長さを返す：

Wolfram Language code: Count[{1, "f", g, "h", "7"}, _ ? StringQ]
Wolfram Language code: Length[Cases[{1, "f", g, "h", "7"}, _ ? StringQ]]

Countは，Positionが与える結果の長さを返す：

Wolfram Language code: Count[{1, "f", g, "h", "7"}, _ ? StringQ]
Wolfram Language code: Length[Position[{1, "f", g, "h", "7"}, _ ? StringQ]]

レベル{0}における数は，事実上，MatchQを数値化したものである：

Wolfram Language code: MatchQ[5, _Integer]
Wolfram Language code: Count[5, _Integer, {0}] == 1

ほとんどの式について，LeafCountは，レベル{-1}におけるBlank[]にマッチする数に等しい：

Wolfram Language code: LeafCount[1 + a + b ^ 2]
Wolfram Language code: Count[1 + a + b ^ 2, _, {-1}, Heads -> True]

Countは，RationalおよびComplexを原子として扱う：

Wolfram Language code: AtomQ /@ {1 / 2, 1 + I}
Wolfram Language code: Count[{1 / 2, 1 + I}, _, {-1}, Heads -> True]

LeafCountは，RationalおよびComplexの数を，それぞれのFullFormを使って数える：

Wolfram Language code: {1 / 2, 1 + I}//FullForm
Wolfram Language code: LeafCount[{1 / 2, 1 + I}]

Countを並列に計算する：

Wolfram Language code: Parallelize[Count[Range[10 ^ 6], _ ? PrimeQ]]

考えられる問題  (1)

Countはパターンに基づいてマッチを探す．これは，数値等価性とは異なることがある：

Wolfram Language code: Count[{0.9, .15 * 6, 1.8 / 2}, 0.9]

Conditionを使ってパターンを書き，数値等価性に基づいた検索を強制する：

Wolfram Language code: Count[{0.9, .15 * 6, 1.8 / 2}, n_ /; n == 0.9]
Wolfram Research (1988), Count, Wolfram言語関数， https://reference.wolfram.com/language/ref/Count.html （2014年に更新）.

テキスト

Wolfram Research (1988), Count, Wolfram言語関数， https://reference.wolfram.com/language/ref/Count.html （2014年に更新）.

CMS

Wolfram Language. 1988. "Count." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Count.html.

APA

Wolfram Language. (1988). Count. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Count.html

BibTeX

@misc{reference.wolfram_2026_count, author="Wolfram Research", title="{Count}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Count.html}", note=[Accessed: 15-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_count, organization={Wolfram Research}, title={Count}, year={2014}, url={https://reference.wolfram.com/language/ref/Count.html}, note=[Accessed: 15-October-2026]}