WOLFRAM

Wolfram 语言与系统参考资料中心

Count[list,pattern]

给出 list 中匹配 pattern 的元素个数.

Count[expr,pattern,levelspec]

给出匹配 pattern 的子表达式的总个数，这些子表达式出现在 expr 中由 levelspec 指定的层上.

Count[pattern]

表示可以应用于表达式的 Count 的运算符形式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
选项  
Heads  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Count

Count[list,pattern]

给出 list 中匹配 pattern 的元素个数.

Count[expr,pattern,levelspec]

给出匹配 pattern 的子表达式的总个数，这些子表达式出现在 expr 中由 levelspec 指定的层上.

Count[pattern]

表示可以应用于表达式的 Count 的运算符形式.

更多信息和选项

  • Count 的第一个参数不需要具有头 List.
  • 当用在 Association 上时，Count 仅测试元素的值，而不是它们的键.
  • Count 使用标准的层指定：
  • n第 1 层到第 n 层
    Infinity第 1 层到 Infinity
    {n}第 n 层
    {n1,n2}第 n1 层到第 n2 曾
  • 在 Count 中，levelspec 的缺省值是 {1}.
  • 一个正层数 n 包含由 n 个索引指定的 expr 中的所有部分.
  • 一个负层数 -n 包含深度为 n 的 expr 的所有部分.
  • 层数 -1 由数字、符号和其它没有子部分的对象组成.
  • 层数 0 对应整个表达式.
  • 设置选项 Heads->True，Count 查看表达式头部及各部分.
  • Count[pattern][expr] 等价于 Count[expr,pattern].
  • Parallelize[Count[list,pattern]] 在所有子核上并行计算 Count[list,pattern]. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

计算 b 出现的次数：

Wolfram Language code: Count[{a, b, a, a, b, c, b}, b]

计算 Association 中 x 的幂次：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, x ^ _]

计算 x 在所有层上的幂次：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, x ^ _, Infinity]

计算符号的个数：

Wolfram Language code: Count[<|1 -> 1 + x ^ 2, 2 -> x ^ 4, 3 -> a + (1 + x ^ 2) ^ 2|>, _Symbol, Infinity]

范围  (5)

Count 对模式有效：

Wolfram Language code: Count[{a, 2, a, a, 1, c, b, 3, 3}, _Integer]

统计不匹配 b 的元素个数：

Wolfram Language code: Count[{a, b, a, a, b, c, b, a, a}, Except[b]]

统计 b 出现的次数，一直到第2层：

Wolfram Language code: Count[{{a, a, b}, b, {a, b, a}}, b, 2]

仅统计在第2层的出现次数：

Wolfram Language code: Count[{{a, a, b}, b, {a, b, a}}, b, {2}]

统计所有数值表达式作为更大表达式的一部分出现的次数：

Wolfram Language code: Count[x ^ 3 + 1.5x ^ 2 + Pi x + 7, _ ? NumericQ, -1]

数值层的规范不包括第零层：

Wolfram Language code: Count[5, _ ? NumericQ, -1]

使用两个元素的列表，以显式包括零层：

Wolfram Language code: Count[5, _ ? NumericQ, {0, -1}]

推广和延伸  (1)

Count 对任意头部起作用，不仅仅是 List：

Wolfram Language code: Count[f[a, b, b, a], b]

选项  (1)

Heads  (1)

默认情况下，作为头出现的表达式不计算在内：

Wolfram Language code: Count[Sin[x] + Cos[x] + Sin[x] ^ 2, Sin, -1]

使用选项 Heads->True 来包括它们：

Wolfram Language code: Count[Sin[x] + Cos[x] + Sin[x] ^ 2, Sin, -1, Heads -> True]

应用  (3)

统计表达式中的符号的数目：

Wolfram Language code: Count[a + b ^ 2 / (a + b), _Symbol, Infinity]

统计大于0.5的元素的总数：

Wolfram Language code: Count[RandomReal[1, {100}], u_ /; u > 0.5]

统计第一个元素为1的行数：

Wolfram Language code: Count[{{1, 2}, {2, 3}, {1, 5}}, {u_, _} /; u == 1]

属性和关系  (5)

Count 返回由 Cases 给出的结果的长度：

Wolfram Language code: Count[{1, "f", g, "h", "7"}, _ ? StringQ]
Wolfram Language code: Length[Cases[{1, "f", g, "h", "7"}, _ ? StringQ]]

Count 返回由 Position 给出的结果的长度：

Wolfram Language code: Count[{1, "f", g, "h", "7"}, _ ? StringQ]
Wolfram Language code: Length[Position[{1, "f", g, "h", "7"}, _ ? StringQ]]

在层 {0} 的计数等效于 MatchQ 的数值化版本：

Wolfram Language code: MatchQ[5, _Integer]
Wolfram Language code: Count[5, _Integer, {0}] == 1

对于大多数表达式，LeafCount 等于在层 {-1} 匹配 Blank[] 的计数：

Wolfram Language code: LeafCount[1 + a + b ^ 2]
Wolfram Language code: Count[1 + a + b ^ 2, _, {-1}, Heads -> True]

Count 将 Rational 和 Complex 视作原子式：

Wolfram Language code: AtomQ /@ {1 / 2, 1 + I}
Wolfram Language code: Count[{1 / 2, 1 + I}, _, {-1}, Heads -> True]

LeafCount 对 Rational 和 Complex 计数时使用它们的 FullForm：

Wolfram Language code: {1 / 2, 1 + I}//FullForm
Wolfram Language code: LeafCount[{1 / 2, 1 + I}]

并行计算 Count：

Wolfram Language code: Parallelize[Count[Range[10 ^ 6], _ ? PrimeQ]]

可能存在的问题  (1)

Count 查找基于模式的匹配，这可能不同于数值相等：

Wolfram Language code: Count[{0.9, .15 * 6, 1.8 / 2}, 0.9]

用 Condition 写一个模式，强制查询基于数值相等：

Wolfram Language code: Count[{0.9, .15 * 6, 1.8 / 2}, n_ /; n == 0.9]
Wolfram Research (1988)，Count，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Count.html （更新于 2014 年）.

文本

Wolfram Research (1988)，Count，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Count.html （更新于 2014 年）.

CMS

Wolfram 语言. 1988. "Count." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Count.html.

APA

Wolfram 语言. (1988). Count. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Count.html 年

BibTeX

@misc{reference.wolfram_2026_count, author="Wolfram Research", title="{Count}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Count.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_count, organization={Wolfram Research}, title={Count}, year={2014}, url={https://reference.wolfram.com/language/ref/Count.html}, note=[Accessed: 07-September-2026]}