WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Covariance[v,w]

ベクトル v と w の間の共分散を与える．

Covariance[a,b]

行列 a と b の相互今日分散行列を与える．

Covariance[a]

行列 a の観測値についての自己共分散行列を与える．

Covariance[dist]

多変量記号分布 dist の自己共分散行列を与える．

Covariance[dist,i,j]

多変量記号分布 dist の(i,j)次共分散を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ  
分布と過程  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Covariance

Covariance[v,w]

ベクトル v と w の間の共分散を与える．

Covariance[a,b]

行列 a と b の相互今日分散行列を与える．

Covariance[a]

行列 a の観測値についての自己共分散行列を与える．

Covariance[dist]

多変量記号分布 dist の自己共分散行列を与える．

Covariance[dist,i,j]

多変量記号分布 dist の(i,j)次共分散を与える．

詳細

  • Covarianceは，しばしば，共変動，つまり，一つの変数が他の変数と同様に変化する傾向があるかどうかの測定に使われる．
  • Covariance[v,w]は v と w の間の共分散 の不偏推定値を返す．
  • 長さが のベクトル とベクトル について，共分散推定Covariance[v,w]は で与えられる．ただし mu^^_v=Mean[v]である．
  • 次元がそれぞれ と で列には および でインデックスが付けらた行列 と行列 について，Covariance[a,b]は成分がで与えられる 行列である．
  • ただし，は1の ベクトル，はMean[a]，はMean[b]である．
  • 列の行列 a について，Covariance[a]はCovariance[a, a]で与えられる 行列である．
  • Covarianceは，VectorQである任意のベクトルあるいはMatrixQである任意の行列に使うことができる．
  • Covariance[dist,i,j]はExpectation[(xi-μi)(xj-μj),{x1,x2,…}∈dist]を与える．ただし，μiは dist.の平均の i 番目の成分である． »
  • Covariance[dist]は(i,j)番目の成分がCovariance[dist,i,j]で与えられる共分散行列を与える．

例題

すべて開く すべて閉じる

例  (3)

2つのベクトル間の共分散：

Wolfram Language code: Covariance[{a, b}, {x, y}]

行列の共分散行列：

Wolfram Language code: Covariance[{{a, b}, {c, d}}]//MatrixForm

2つの行列の共分散行列：

Wolfram Language code: Covariance[{{a, b}, {c, d}}, {{x}, {y}}]//MatrixForm

スコープ  (13)

データ  (8)

厳密な入力は厳密な出力を与える：

Wolfram Language code: Covariance[{1, 3 / 2}, {2, 11}]
Wolfram Language code: Covariance[{1, π}, {E, 2}]//Simplify

近似入力は近似出力を与える：

Wolfram Language code: Covariance[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: Covariance[N[{1, 2, 5, 6}, 20], N[{2, 3, 6, 8}, 20]]

複素ベクトル間の共分散：

Wolfram Language code: Covariance[{2 + I, 3 - 2I, 5 + 4I}, {I, 1 + 2I, 10 - 5I}]

大規模配列に使うことができる：

Wolfram Language code: Covariance[RandomReal[1, 10 ^ 7], RandomReal[1, 10 ^ 7]]

構造化配列を使うことができる（ガイドを参照のこと）：

Wolfram Language code: Covariance[SparseArray[{{2, 2} -> 1, {5, 3} -> 2}]]//MatrixForm
Wolfram Language code: Covariance[IdentityMatrix[3]]//MatrixForm
Wolfram Language code: Covariance[ToeplitzMatrix[4]]//MatrixForm
Wolfram Language code: Covariance[QuantityArray[RandomReal[1, {20, 2}], "Meters"]]//MatrixForm

数量を含むデータの共分散を求める：

Wolfram Language code: v = Quantity[{2, 3.5, 4, 5}, "Meters"]; w = Quantity[{10, 32, 19, 24.2}, "Pounds"];
Wolfram Language code: Covariance[v, w]

日付のリストの間の共分散：

Wolfram Language code: v = RandomDate[4]
Wolfram Language code: w = RandomDate[4]
Wolfram Language code: Covariance[v, w]

時間の行列の間の共分散：

Wolfram Language code: Covariance[RandomTime[{4, 2}], RandomTime[{4, 3}]]//MatrixForm

分布と過程  (5)

多変量連続分布についての共分散：

Wolfram Language code: Covariance[BinormalDistribution[ρ]]//MatrixForm
Wolfram Language code: Covariance[BinormalDistribution[ρ], 2, 1]

多変量離散分布についての共分散：

Wolfram Language code: Covariance[MultivariatePoissonDistribution[μ, {2, 3, 7}]]//MatrixForm
Wolfram Language code: Covariance[MultivariatePoissonDistribution[μ, {2, 3, 7}], 2, 3]

派生分布についての共分散：

Wolfram Language code: Covariance[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 2}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: Covariance[𝒟]//MatrixForm
Wolfram Language code: Covariance[𝒟, 1, 2]
Wolfram Language code: Covariance[𝒟, 1, 1]

データ分布について：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: Covariance[𝒟]//MatrixForm
Wolfram Language code: Covariance[BinormalDistribution[.75]]//MatrixForm

時点sおよびtにおけるランダム過程についての共分散行列：

Wolfram Language code: Covariance[WienerProcess[][{s, t}]]//Simplify[#, s > 0 && t > 0]&//MatrixForm

時点およびにおけるTemporalDataについての共分散行列：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 1000]
Wolfram Language code: Covariance[td[{0.2, 0.3}]]//MatrixForm

過程のスライスの共分散と比較する：

Wolfram Language code: Covariance[WienerProcess[1, 1][{0.2, 0.3}]]

アプリケーション  (3)

2つの金融時系列の共分散を計算する：

Wolfram Language code: gspc = TemporalData[TimeSeries, {{{2058.2, 2020.58, 2002.61, 2025.9, 2062.14, 2044.81, 2028.26, 2023.03, 2011.27, 1992.67, 2019.42, 2022.55, 2032.12, 2063.15, 2051.82, 2057.09, 2029.55, 2002.16, 2021.25, 1994.99, 2020.85, 2050.03, 2041.51, 2062. ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: ndx = TemporalData[TimeSeries, {{{4230.2368, 4160.9644, 4110.8301, 4159.9995, 4240.5495, 4213.2758, 4169.9704, 4166.2025, 4145.8414, 4089.6482, 4142.1401, 4171.2143, 4192.0934, 4270.3628, 4278.1424, 4275.7154, 4165.5017, 4140.3756, 4181.3514, 4 ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: Covariance[gspc["Values"], ndx["Values"]]

Covarianceを使って線形関係を測ることができる：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 3000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"σ : ", Covariance[i][[1, 2]]}]], {i, data}], 3]]

Covarianceは単調関係しか検出しない：

Wolfram Language code: uni = RandomReal[{-3, 3}, 3000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"σ : ", Covariance[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingDを使ってさまざまな依存構造を検出することができる：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

特性と関係  (9)

共分散行列は，対称かつ半正定値の行列である：

Wolfram Language code: cov = Covariance[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[cov]
Wolfram Language code: PositiveSemidefiniteMatrixQ[cov]

標準偏差でスケールされた共分散行列は相関行列である：

Wolfram Language code: data = RandomReal[5, {20, 5}];
Wolfram Language code: s = DiagonalMatrix[1 / StandardDeviation[data]];
Wolfram Language code: Correlation[data] == s.Covariance[data].s

CovarianceおよびAbsoluteCorrelationは，ゼロ平均の分布について等しい：

Wolfram Language code: 𝒟 = BinormalDistribution[ρ];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: Covariance[𝒟]
Wolfram Language code: AbsoluteCorrelation[𝒟]

SpearmanRhoは順位に適用されたCovarianceに関連する：

Wolfram Language code: data = Transpose@RandomVariate[BinormalDistribution[.8], 100];
Wolfram Language code: SpearmanRho[data[[1]], data[[2]]]
Wolfram Language code: rnks = Ordering[Ordering[#]]& /@ data;
Wolfram Language code: Covariance[rnks[[1]], rnks[[2]]] / (StandardDeviation[rnks[[1]]] StandardDeviation[rnks[[2]]])//N

過程についてのCovarianceFunctionは，共分散行列の非対角項である：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: Covariance[𝒫[{s, t}], 1, 2]
Wolfram Language code: CovarianceFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

CovarianceおよびCorrelationは，標準化されたベクトルについては等しい：

Wolfram Language code: sample = RandomVariate[DiscreteUniformDistribution[{{2, 3}, {4, 5}}], 200];
Wolfram Language code: Covariance[sample] === Correlation[sample]
Wolfram Language code: Covariance[Standardize[sample]] === Correlation[sample]

リストの自身との共分散は分散である：

Wolfram Language code: Variance[{a, b, c}] == Covariance[{a, b, c}, {a, b, c}]//Simplify

共分散行列の対角は分散である：

Wolfram Language code: data = RandomReal[5, {20, 5}];
Wolfram Language code: Diagonal[Covariance[data]]
Wolfram Language code: Variance[data]

共分散はランダム行列の対角線上においてのみ大きくなる傾向がある：

Wolfram Language code: ArrayPlot[Covariance[RandomReal[{-1, 1}, {50, 50}]]]

おもしろい例題  (1)

最大公約数の配列の共分散を計算する：

Wolfram Language code: MatrixPlot[Covariance[Array[GCD, {50, 50}]]]
Wolfram Research (2007), Covariance, Wolfram言語関数， https://reference.wolfram.com/language/ref/Covariance.html （2024年に更新）.

テキスト

Wolfram Research (2007), Covariance, Wolfram言語関数， https://reference.wolfram.com/language/ref/Covariance.html （2024年に更新）.

CMS

Wolfram Language. 2007. "Covariance." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/Covariance.html.

APA

Wolfram Language. (2007). Covariance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Covariance.html

BibTeX

@misc{reference.wolfram_2026_covariance, author="Wolfram Research", title="{Covariance}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/Covariance.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_covariance, organization={Wolfram Research}, title={Covariance}, year={2024}, url={https://reference.wolfram.com/language/ref/Covariance.html}, note=[Accessed: 13-September-2026]}