WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DaubechiesWavelet[]

次数2のDaubechiesウェーブレットを表す．

DaubechiesWavelet[n]

次数 n のDaubechiesウェーブレットを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
ウェーブレット変換  
より高い次元  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DaubechiesWavelet

DaubechiesWavelet[]

次数2のDaubechiesウェーブレットを表す．

DaubechiesWavelet[n]

次数 n のDaubechiesウェーブレットを表す．

詳細

  • DaubechiesWaveletは直交ウェーブレット族を定義する．
  • DaubechiesWavelet[n]は任意の正の整数 n について定義される．
  • スケーリング関数()とウェーブレット関数()は長さ2n のコンパクトサポートを持つ．スケーリング関数は n 個のバニッシングモーメントを持つ．
  • DaubechiesWaveletはDiscreteWaveletTransform，WaveletPhi等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[4], x], {x, 0, 7}]
Wolfram Language code: WaveletPhi[DaubechiesWavelet[4], x]

ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[4], x], {x, -3, 4}, PlotRange -> All]
Wolfram Language code: WaveletPsi[DaubechiesWavelet[4], x]

フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]

スコープ  (14)

基本的な用法  (8)

主ローパスフィルタ係数を計算する：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"]

主ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"]

リフティングフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

関数を生成してリフティングウェーブレット変換を計算する：

Wolfram Language code: lf = WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]//Simplify
Wolfram Language code: lf["InverseLiftingFunction"][%]//Simplify

次数2のDaubechiesスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[2], x], {x, 0, 3}]

次数6のDaubechiesスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[6], x], {x, 0, 11}, PlotRange -> All]

異なる再帰のレベルでウェーブレット関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPhi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, 0, 3}, PlotLabel -> i], {i, 1, 8, 2}]

次数2のDaubechiesウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[2], x], {x, -1, 2}]

次数6のDaubechiesWavelet：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[6], x], {x, -5, 6}, PlotRange -> All]

異なる再帰のレベルでウェーブレット関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPsi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, -1, 2}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

ウェーブレット変換  (5)

DiscreteWaveletTransformを計算する：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[3], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

DiscreteWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, DaubechiesWavelet[4], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

StationaryWaveletTransformを計算する：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, DaubechiesWavelet[4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

StationaryWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, DaubechiesWavelet[4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

LiftingWaveletTransformを計算する：

Wolfram Language code: (data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];);
Wolfram Language code: lwt = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: lwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: lwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]

より高い次元  (1)

多変量スケーリング関数と多変量ウェーブレット関数はそれぞれの一変量関数の積である：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[3]]; ψ = WaveletPsi[DaubechiesWavelet[3]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ϕ[y]], {x, -2, 3}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ψ[y]], {x, -2, 3}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

アプリケーション  (3)

Daubechiesウェーブレット係数を使って関数を近似する：

Wolfram Language code: data = Table[Abs[Sin[2 π x]] + 1.5 Abs[Cos[2 π x - π]], {x, 0, 1, (1/2^6 - 1)}];

LiftingWaveletTransformを行う：

Wolfram Language code: dwd = LiftingWaveletTransform[data, DaubechiesWavelet[4]];

n 個の最大係数を保ちその他すべてを閾値化することでもとのデータを近似する：

Wolfram Language code: {data8, data16, data32} = Table[InverseWaveletTransform[WaveletThreshold[dwd, {"LargestCoefficients", n}, Automatic]], {n, {8, 16, 32}}];

他の近似と比較する：

Wolfram Language code: ListLinePlot[{data, data8, data16, data32}, PlotRange -> All]

インパルスを含む信号の多重解像度表現を計算する：

Wolfram Language code: data = Table[Sin[4 π t] + 2 Exp[-10^5 ((1/3) - t)^2], {t, 0, 1, (1/2^9)}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 4]
Wolfram Language code: WaveletListPlot[dwt, {{1}, {0, 1}, {0, 0, 1}, {0, 0, 0}}, PlotLayout -> "CommonXAxis", Method -> {"Inverse" -> True}]

信号の累積エネルギーをそのウェーブレット係数と比較する：

Wolfram Language code: data = Table[Sin[2 π t], {t, 0, 1, (1/63)}];
Wolfram Language code: ListPlot[data]

信号の順序化された累積エネルギーを計算する：

Wolfram Language code: cumulativeEnergy[data_] := Module[{c = Sort[Flatten[data]^2, Greater]}, (Accumulate[c]/Total[c])]
Wolfram Language code: ListPlot[cumulativeEnergy[data]]

信号のエネルギーは比較的少ないウェーブレット係数で捉えられる：

Wolfram Language code: dwd1 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 1];
Wolfram Language code: dwd2 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];
Wolfram Language code: ListPlot[{cumulativeEnergy[data], cumulativeEnergy[Last /@ dwd1[Automatic]], cumulativeEnergy[Last /@ dwd2[Automatic]]}, PlotStyle -> {Red, Blue, Orange}]

特性と関係  (13)

DaubechiesWavelet[1]はHaarWaveletに等しい：

Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] === WaveletFilterCoefficients[DaubechiesWavelet[1]]

ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalLowpass"][[All, 2]]]]

ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]]]

スケーリング関数を積分すると単位元になる．：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[4]];
Wolfram Language code: Subsuperscript[∫, -∞, ∞]ϕ[x]ⅆx

とりわけ ：

Wolfram Language code: Table[NIntegrate[ϕ[(x/2^j)], {x, -∞, ∞}, AccuracyGoal -> 4] - 2^j, {j, 0, 3}]

ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Subsuperscript[∫, -∞, ∞]WaveletPsi[DaubechiesWavelet[4], x]ⅆx

ウェーブレット関数は同じスケールのスケーリング関数と直交する．：

Wolfram Language code: NIntegrate[WaveletPsi[DaubechiesWavelet[3], x] WaveletPhi[DaubechiesWavelet[3], x], {x, -∞, ∞}, AccuracyGoal -> 4]

ローパスフィルタ係数とハイパスフィルタ係数は直交する．：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[3]][[All, 2]].WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]

DaubechiesWavelet[n]は n 個のバニッシングモーメントを持つ．：

Wolfram Language code: ψ = WaveletPsi[DaubechiesWavelet[2]];
Wolfram Language code: Chop[Table[NIntegrate[x^k ψ[x], {x, -∞, ∞}, AccuracyGoal -> 5, MaxRecursion -> 0], {k, 0, 4}]]

これは，線形信号はそのようなスケーリング関数のパート({0})で完全に表される事を意味する：

Wolfram Language code: dwt = LiftingWaveletTransform[ArrayPad[{1, 2, 3, 4}, 2, "Extrapolated"], DaubechiesWavelet[2], 1];
Wolfram Language code: Take[InverseWaveletTransform[dwt, Automatic, {0}], 3 ;; -3]

二次，あるいはそれより高次の信号はそうではない：

Wolfram Language code: dwt = LiftingWaveletTransform[{1, 4, 9, 16}, DaubechiesWavelet[2], 1]
Wolfram Language code: InverseWaveletTransform[dwt, Automatic, {0}]

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[2]];
Wolfram Language code: a = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All], Plot[Total[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[2]];
Wolfram Language code: b = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2 Table[b[[i, 2]] ϕ[2 x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All], Plot[Total[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All]}

に対する周波数応答は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[h[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

次数 n が高くなるにつれ，最後の応答関数は平坦になる：

Wolfram Language code: Plot[{Abs[h[DaubechiesWavelet[2], ω]], Abs[h[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

のフーリエ(Fourier)変換はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Underoverscript[∏, i, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[fh[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]

フィルタはハイパスフィルタである：

Wolfram Language code: Plot[Abs[g[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

次数 n が高くなるにつれ，最後の応答関数は平坦になる：

Wolfram Language code: Plot[{Abs[g[DaubechiesWavelet[2], ω]], Abs[g[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)] Underoverscript[∏, i = 2, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[fg[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

おもしろい例題  (2)

スケーリング関数の平行移動と膨張をプロットする：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2 WaveletPhi[DaubechiesWavelet[4], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]

ウェーブレット関数の平行移動と膨張をプロットする：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2 WaveletPsi[DaubechiesWavelet[4], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, 2, k], {k, 0, 2^2 - 1}]], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), DaubechiesWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

テキスト

Wolfram Research (2010), DaubechiesWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

CMS

Wolfram Language. 2010. "DaubechiesWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

APA

Wolfram Language. (2010). DaubechiesWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DaubechiesWavelet.html

BibTeX

@misc{reference.wolfram_2026_daubechieswavelet, author="Wolfram Research", title="{DaubechiesWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/DaubechiesWavelet.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_daubechieswavelet, organization={Wolfram Research}, title={DaubechiesWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/DaubechiesWavelet.html}, note=[Accessed: 15-September-2026]}