WOLFRAM

Wolfram 语言与系统参考资料中心

DaubechiesWavelet[]

表示阶数为 2 的 Daubechies （多贝西）小波.

DaubechiesWavelet[n]

表示阶数为 n 的 Daubechies 小波.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
小波变换  
高维度  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

DaubechiesWavelet

DaubechiesWavelet[]

表示阶数为 2 的 Daubechies （多贝西）小波.

DaubechiesWavelet[n]

表示阶数为 n 的 Daubechies 小波.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

尺度函数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[4], x], {x, 0, 7}]
Wolfram Language code: WaveletPhi[DaubechiesWavelet[4], x]

小波函数：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[4], x], {x, -3, 4}, PlotRange -> All]
Wolfram Language code: WaveletPsi[DaubechiesWavelet[4], x]

滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]

范围  (14)

基本用途  (8)

计算原低通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"]

原高通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"]

提升滤波器数据：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

生成一个函数来计算提升小波变换：

Wolfram Language code: lf = WaveletFilterCoefficients[DaubechiesWavelet[2], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]//Simplify
Wolfram Language code: lf["InverseLiftingFunction"][%]//Simplify

阶数为2的 Daubechies 尺度函数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[2], x], {x, 0, 3}]

阶数为6的 Daubechies 尺度函数：

Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[6], x], {x, 0, 11}, PlotRange -> All]

使用不同递推级，绘制尺度函数：

Wolfram Language code: Table[Plot[WaveletPhi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, 0, 3}, PlotLabel -> i], {i, 1, 8, 2}]

阶数为2的 Daubechies 小波函数：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[2], x], {x, -1, 2}]

阶数为6的 DaubechiesWavelet：

Wolfram Language code: Plot[WaveletPsi[DaubechiesWavelet[6], x], {x, -5, 6}, PlotRange -> All]

使用不同递推级，绘制小波函数：

Wolfram Language code: Table[Plot[WaveletPsi[DaubechiesWavelet[2], x, MaxRecursion -> i], {x, -1, 2}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

小波变换  (5)

计算一个 DiscreteWaveletTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[3], 2]

查看小波系数组成的树：

Wolfram Language code: dwt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

计算一个 DiscreteWaveletPacketTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, DaubechiesWavelet[4], 2]

查看小波系数组成的树：

Wolfram Language code: dwpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

计算一个 StationaryWaveletTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, DaubechiesWavelet[4], 2];

查看小波系数组成的树：

Wolfram Language code: swt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

计算一个 StationaryWaveletPacketTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, DaubechiesWavelet[4], 2];

查看小波系数组成的树：

Wolfram Language code: swpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

计算一个 LiftingWaveletTransform：

Wolfram Language code: (data = Table[Sinc[t^2], {t, -3 π, 3 π, (6 π/1023)}];);
Wolfram Language code: lwt = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];

查看小波系数组成的树：

Wolfram Language code: lwt["TreeView"]

获取小波系数的维度：

Wolfram Language code: lwt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]

高维度  (1)

多变量尺度函数和小波函数是单变量的积：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[3]]; ψ = WaveletPsi[DaubechiesWavelet[3]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x] ψ[y]], {x, 0, 5}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ϕ[y]], {x, -2, 3}, {y, 0, 5}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x] ψ[y]], {x, -2, 3}, {y, -2, 3}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

应用  (3)

使用 Daubechies 小波系数，对一个函数求近似：

Wolfram Language code: data = Table[Abs[Sin[2 π x]] + 1.5 Abs[Cos[2 π x - π]], {x, 0, 1, (1/2^6 - 1)}];

执行一个 LiftingWaveletTransform：

Wolfram Language code: dwd = LiftingWaveletTransform[data, DaubechiesWavelet[4]];

通过保持 n 个最大的系数以及对其它进行阈值限制，对原始数据求近似：

Wolfram Language code: {data8, data16, data32} = Table[InverseWaveletTransform[WaveletThreshold[dwd, {"LargestCoefficients", n}, Automatic]], {n, {8, 16, 32}}];

比较不同的近似：

Wolfram Language code: ListLinePlot[{data, data8, data16, data32}, PlotRange -> All]

计算包含一个脉冲的信号的多分辨率表示：

Wolfram Language code: data = Table[Sin[4 π t] + 2 Exp[-10^5 ((1/3) - t)^2], {t, 0, 1, (1/2^9)}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, DaubechiesWavelet[4], 4]
Wolfram Language code: WaveletListPlot[dwt, {{1}, {0, 1}, {0, 0, 1}, {0, 0, 0}}, PlotLayout -> "CommonXAxis", Method -> {"Inverse" -> True}]

比较信号中的累积能量和它的小波系数：

Wolfram Language code: data = Table[Sin[2 π t], {t, 0, 1, (1/63)}];
Wolfram Language code: ListPlot[data]

计算信号中的有序累积能量：

Wolfram Language code: cumulativeEnergy[data_] := Module[{c = Sort[Flatten[data]^2, Greater]}, (Accumulate[c]/Total[c])]
Wolfram Language code: ListPlot[cumulativeEnergy[data]]

信号中的能量由相对较少的小波系数捕获：

Wolfram Language code: dwd1 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 1];
Wolfram Language code: dwd2 = LiftingWaveletTransform[data, DaubechiesWavelet[4], 2];
Wolfram Language code: ListPlot[{cumulativeEnergy[data], cumulativeEnergy[Last /@ dwd1[Automatic]], cumulativeEnergy[Last /@ dwd2[Automatic]]}, PlotStyle -> {Red, Blue, Orange}]

属性和关系  (13)

DaubechiesWavelet[1] 等价于 HaarWavelet：

Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] === WaveletFilterCoefficients[DaubechiesWavelet[1]]

低通滤波器系数的和为1；：

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalLowpass"][[All, 2]]]]

高通滤波器系数的和为0；：

Wolfram Language code: Chop[Total[WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]]]

尺度函数的积分为1；：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[4]];
Wolfram Language code: Subsuperscript[∫, -∞, ∞]ϕ[x]ⅆx

特别地，：

Wolfram Language code: Table[NIntegrate[ϕ[(x/2^j)], {x, -∞, ∞}, AccuracyGoal -> 4] - 2^j, {j, 0, 3}]

小波函数的积分为0；：

Wolfram Language code: Subsuperscript[∫, -∞, ∞]WaveletPsi[DaubechiesWavelet[4], x]ⅆx

小波函数与尺度函数在相同的尺度上是正交的；：

Wolfram Language code: NIntegrate[WaveletPsi[DaubechiesWavelet[3], x] WaveletPhi[DaubechiesWavelet[3], x], {x, -∞, ∞}, AccuracyGoal -> 4]

低通滤波器和高通滤波器系数是正交的；：

Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[3]][[All, 2]].WaveletFilterCoefficients[DaubechiesWavelet[3], "PrimalHighpass"][[All, 2]]

DaubechiesWavelet[n] 具有 n 个消失矩；：

Wolfram Language code: ψ = WaveletPsi[DaubechiesWavelet[2]];
Wolfram Language code: Chop[Table[NIntegrate[x^k ψ[x], {x, -∞, ∞}, AccuracyGoal -> 5, MaxRecursion -> 0], {k, 0, 4}]]

这意味着线性信号完全在尺度函数部分（{0}）中表示：

Wolfram Language code: dwt = LiftingWaveletTransform[ArrayPad[{1, 2, 3, 4}, 2, "Extrapolated"], DaubechiesWavelet[2], 1];
Wolfram Language code: Take[InverseWaveletTransform[dwt, Automatic, {0}], 3 ;; -3]

二次或者高次信号不是：

Wolfram Language code: dwt = LiftingWaveletTransform[{1, 4, 9, 16}, DaubechiesWavelet[2], 1]
Wolfram Language code: InverseWaveletTransform[dwt, Automatic, {0}]

满足递推方程 ：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[2]];
Wolfram Language code: a = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalLowpass"];

绘制分量以及递推和：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All], Plot[Total[scalet[x, ϕ, a]], {x, 0, 3}, PlotRange -> All]}

满足递推方程 ：

Wolfram Language code: ϕ = WaveletPhi[DaubechiesWavelet[2]];
Wolfram Language code: b = WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"];

绘制分量以及递推和：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2 Table[b[[i, 2]] ϕ[2 x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All], Plot[Total[wavelet[x, ϕ, b]], {x, -1, 2}, PlotRange -> All]}

的频率响应由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]

该滤波器是一个低通滤波器：

Wolfram Language code: Plot[Abs[h[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

阶数 n 越高，响应函数在尾端越平坦：

Wolfram Language code: Plot[{Abs[h[DaubechiesWavelet[2], ω]], Abs[h[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Underoverscript[∏, i, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[fh[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]

的频率响应由 给出：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]

该滤波器是一个高通滤波器：

Wolfram Language code: Plot[Abs[g[DaubechiesWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

阶数 n 越高，响应函数在尾端越平坦：

Wolfram Language code: Plot[{Abs[g[DaubechiesWavelet[2], ω]], Abs[g[DaubechiesWavelet[12], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Underoverscript[∑, i, Length[a]]a[[i, 2]] Exp[-I a[[i, 1]] ω]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Underoverscript[∑, i, Length[b]]b[[i, 2]] Exp[-I b[[i, 1]] ω]]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)] Underoverscript[∏, i = 2, j]h[wav, (ω/2^i)]]
Wolfram Language code: Plot[fg[DaubechiesWavelet[2], ω, 10], {ω, -10 π, 10 π}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

巧妙范例  (2)

绘制尺度函数的平移和膨胀：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2 WaveletPhi[DaubechiesWavelet[4], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]

绘制小波函数的平移和膨胀：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2 WaveletPsi[DaubechiesWavelet[4], 2^j x - k]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, j, 0], {j, 0, 4}]], {x, 0, 2}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate[Table[ψ[x, 2, k], {k, 0, 2^2 - 1}]], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010)，DaubechiesWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

文本

Wolfram Research (2010)，DaubechiesWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

CMS

Wolfram 语言. 2010. "DaubechiesWavelet." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DaubechiesWavelet.html.

APA

Wolfram 语言. (2010). DaubechiesWavelet. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DaubechiesWavelet.html 年

BibTeX

@misc{reference.wolfram_2026_daubechieswavelet, author="Wolfram Research", title="{DaubechiesWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/DaubechiesWavelet.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_daubechieswavelet, organization={Wolfram Research}, title={DaubechiesWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/DaubechiesWavelet.html}, note=[Accessed: 06-September-2026]}