WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DeconvolutionLayer[n,sz]

n 個の出力チャンネルを持ちサイズ sz のカーネルを使ってデコンボリューションを計算する，訓練可能なデコンボリューションネットの層を表す．

DeconvolutionLayer[n,{s}]

サイズ s のカーネルを使って一次元のデコンボリューションを行う層を表す．

DeconvolutionLayer[n,{h,w}]

サイズ h×w のカーネルを使って二次元のデコンボリューションを行う層を表す．

DeconvolutionLayer[n,kernel,opts]

初期カーネルとその他のパラメータについてのオプションを含む．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
引数  
ポート  
オプション  
"バイアス"  
"ChannelGroups"  
"膨張"  
Show More Show More
Interleaving  
LearningRateMultipliers  
PaddingSize  
"Stride"  
"Weights"  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DeconvolutionLayer

DeconvolutionLayer[n,sz]

n 個の出力チャンネルを持ちサイズ sz のカーネルを使ってデコンボリューションを計算する，訓練可能なデコンボリューションネットの層を表す．

DeconvolutionLayer[n,{s}]

サイズ s のカーネルを使って一次元のデコンボリューションを行う層を表す．

DeconvolutionLayer[n,{h,w}]

サイズ h×w のカーネルを使って二次元のデコンボリューションを行う層を表す．

DeconvolutionLayer[n,kernel,opts]

初期カーネルとその他のパラメータについてのオプションを含む．

詳細とオプション

  • DeconvolutionLayer[…][input]は，層を input に適用して，出力を明示的に計算する．
  • DeconvolutionLayer[…][{input1,input2,…}]は，各 inputiについて出力を明示的に計算する．
  • 次の任意パラメータを含むことができる．
  • "Biases"Automaticカーネルのバイアスの初期ベクトル
    "ChannelGroups" 1チャンネルグループ数
    "Dilation"1膨張係数
    Interleaving Falseチャンネル次元の位置
    LearningRateMultipliers Automaticカーネルの重みおよび／またはバイアスの学習率乗数
    PaddingSize 0出力から除く充填の量
    "Stride" 1使用するたたみ込みの刻み幅
    "Weights" Automaticカーネルの重みの初期行列
  • PaddingSizeの設定は，以下の形式でよい．
  • n最初と最後の n 要素ごとに各次元を切り取る
    {n1,n2,…}i 次元の先頭と末尾の n 要素を切り取る
    {{n1,m1},{n2,m2},…}i 次元を，先頭の ni要素と末尾の mi要素で切り取る
    "Same"出力サイズが入力サイズにストライドを掛けたものと等しくなるように，すべての次元を切り取る
  • "Dilation"および"Stride"の設定は，次の形式でよい．
  • n全次元に値 n を使う
    {…,ni,…}第 i 次元に値 niを使う
  • "ChannelGroups"g と設定することで，m 個の入力チャンネルと n 個の出力チャンネルが，それぞれ m/g チャンネルと n/g チャンネルの g 個のグループに分割される．m と n は g で割り切れなければならない．入力チャンネルの i 番目のグループを出力チャンネルの i 番目のグループと接続するために別々のデコンボリューションが行われる．結果は出力に連結される．入出力グループの各ペアは n/g×m/g デコンボリューションで接続されるので，"ChannelGroups"g という設定は，事実上，明確なデコンボリューションの数を n×m から n×m/g に減らす．
  • Automaticの設定のとき，NetInitializeまたはNetTrainが使われると重みとバイアスが自動的に加えられる．
  • "Biases"->Noneの設定はバイアスを使わないように指定する．
  • InterleavingFalseの設定のときは，チャンネル次元は入出力配列の最初の次元であるとみなされる．
  • InterleavingTrueの設定のときは，チャンネル次元は入出力配列の最後の次元であるとみなされる．
  • 重みとバイアスが加えられると，DeconvolutionLayer[…][input]は層を適用して明示的に出力を計算する．
  • DeconvolutionLayer[…][{input1,input2,…}]は各 inputiについて明示的に出力を計算する．
  • NumericArrayが入力として与えられると，出力はNumericArrayになる．
  • NetExtractを使ってDeconvolutionLayerオブジェクトから重みとバイアスを取り出すことができる．
  • DeconvolutionLayerはNetChainやNetGraphの中で使われることが多い．
  • DeconvolutionLayerはNetGraph等で使うために次のポートを開放する．
  • "Input"階数3の配列
    "Output"階数3の配列
  • より大きいネットの他の層から推測できない場合は，オプション"Input"->{d1,d2,d3}を使ってDeconvolutionLayerの入力次元を固定することができる．
  • 次元 d1×d2×d3の入力配列を与えられた場合，出力配列の次元は ××である．ただし，チャンネル次元は =n でサイズ d2および d3は =s(di-1)+df(k-1)+1-pb-pe従って変換される．ただし，df は膨張係数，/は軸の始まり／終りの充填サイズ，k はカーネルサイズ，s は各次元のストライドサイズである．
  • Options[DeconvolutionLayer]は層を構築する際のデフォルトオプションのリストを与える．Options[DeconvolutionLayer[…]]はデータについて層を評価する際のデフォルトオプションのリストを与える．
  • Information[DeconvolutionLayer[…]]は層についてのレポートを与える．
  • Information[DeconvolutionLayer[…],prop]はDeconvolutionLayer[…]の特性 prop の値を与える．使用可能な特性はNetGraphと同じである．

例題

すべて開く すべて閉じる

例  (3)

5つの出力チャンネルで2×2カーネルサイズのDeconvolutionLayerを作る：

Wolfram Language code: DeconvolutionLayer[5, {2, 2}]

入力次元を指定して，ランダムに初期化されたDeconvolutionLayerを作る：

Wolfram Language code: deconv = DeconvolutionLayer[1, {2, 2}, "Input" -> {1, 2, 2}]//NetInitialize

この層を入力テンソルに適用して出力テンソルを生成する：

Wolfram Language code: deconv[{{{1, 1}, {1, -2}}}]//MatrixForm

画像を取って画像を作成する，ランダムに初期化されたDeconvolutionLayerを作る：

Wolfram Language code: deconv = DeconvolutionLayer[2, {3, 3}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"]]//NetInitialize

この層を画像に適用する：

Wolfram Language code: deconv[[image]]

この層を入力バッチに縫い込む：

Wolfram Language code: deconv[{[image], [image]}]

スコープ  (6)

引数  (3)

2つの出力チャンネルでカーネルサイズが3のDeconvolutionLayerを作成する：

Wolfram Language code: DeconvolutionLayer[2, 3]

明示的な一次元カーネルを指定する：

Wolfram Language code: DeconvolutionLayer[2, {3}]

明示的な二次元カーネルを指定する：

Wolfram Language code: DeconvolutionLayer[2, {3, 3}]

ポート  (3)

層の"Input"ポートがサイズ3×64×64の配列を取るように指定する：

Wolfram Language code: DeconvolutionLayer[2, {3, 3}, "Input" -> {3, 64, 64}]

"Input"ポートと"Output"ポートを明示的に指定する：

Wolfram Language code: DeconvolutionLayer[2, {3, 3}, "Input" -> {3, 64, 64}, "Output" -> {2, 66, 66}]

画像のエンコーダ／デコーダをレイヤーの"Input"ポートと"Output"ポートに追加する：

Wolfram Language code: deconv = DeconvolutionLayer[3, {2, 2}, "Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}], "Output" -> NetDecoder[{"Image", "RGB"}]]//NetInitialize

初期化した層を入力に適用する：

Wolfram Language code: deconv[[image]]

オプション  (12)

"バイアス"  (1)

バイアスなしで，ランダムに初期化されたDeconvolutionLayerを作る：

Wolfram Language code: deconv = NetInitialize@DeconvolutionLayer[2, {4, 4}, "Input" -> {1, 40, 40}, "Biases" -> None]

バイアスはない：

Wolfram Language code: NetExtract[deconv, "Biases"]

"ChannelGroups"  (1)

一つ以上のチャンネルグループでDeconvolutionLayerを初期化する：

Wolfram Language code: deconv = NetInitialize@ DeconvolutionLayer[3, {3, 3}, "Input" -> NetEncoder["Image"], "Output" -> NetDecoder["Image"], "ChannelGroups" -> 3]

この層を画像に適用する：

Wolfram Language code: deconv[[image]]
Wolfram Language code: ```

"膨張"  (2)

指定の次元におけるサイズ n の膨張係数は，事実上，カーネルを距離 n 離れている出力配列の要素に適用する．

一次元DeconvolutionLayerを膨張係数2で作成する：

Wolfram Language code: deconv = DeconvolutionLayer["Weights" -> {{{0.5, 0.5}}}, "Biases" -> None, "Dilation" -> 2]

この層を入力に適用する：

Wolfram Language code: deconv[{{0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}}] // Normal

ランダムな二次元DeconvolutionLayerを膨張係数5で作成する：

Wolfram Language code: deconv = NetInitialize@DeconvolutionLayer[3, {3, 3}, "Dilation" -> 5, "Input" -> NetEncoder[ "Image"], "Output" -> NetDecoder["Image"]]

膨張たたみ込み層を画像に適用する：

Wolfram Language code: deconv[[image]]

Interleaving  (1)

InterleavingFalseと1つの入力チャンネルでDeconvolutionLayerを作る：

Wolfram Language code: DeconvolutionLayer[1, 5, "Input" -> {1, 25, 25}, Interleaving -> False]

InterleavingTrueと1つの入力チャンネルでDeconvolutionLayerを作る：

Wolfram Language code: DeconvolutionLayer[1, 5, "Input" -> {25, 25, 1}, Interleaving -> True]

LearningRateMultipliers  (1)

訓練中は決して変化しないDeconvolutionLayerを作成する：

Wolfram Language code: NetInitialize@DeconvolutionLayer[5, {7, 7}, "Input" -> {3, 12, 12}, LearningRateMultipliers -> 0]

PaddingSize  (4)

デフォルトで，出力には切取りは適用されない：

Wolfram Language code: DeconvolutionLayer[1, 2, "Input" -> {1, 25, 25}]

PaddingSizen を使って固定された量を切り取る：

Wolfram Language code: DeconvolutionLayer[1, 2, "Input" -> {1, 25, 25}, PaddingSize -> 1]

各次元から特定の量を切り取る：

Wolfram Language code: DeconvolutionLayer[1, 2, "Input" -> {1, 25, 25}, PaddingSize -> {1, 2}]

充填を使って出力次元が入力次元と等しくなるようにする：

Wolfram Language code: DeconvolutionLayer[1, 5, "Input" -> {1, 25, 25}, PaddingSize -> 2]

これはPaddingSize "Same"に等しい：

Wolfram Language code: deconv = DeconvolutionLayer[1, 5, "Input" -> {1, 25, 25}, PaddingSize -> "Same"]

一般に，PaddingSize "Same"は，入力サイズにスライドを掛けたものに等しい出力サイズを与える：

Wolfram Language code: DeconvolutionLayer[1, 5, "Input" -> {1, 25, 25}, PaddingSize -> "Same", "Stride" -> 2]

"Stride"  (1)

最大ストライドを使って出力の次元が大きくなるようにする：

Wolfram Language code: deconv1 = DeconvolutionLayer[3, 7, "Input" -> {3, 32, 32}, "Stride" -> 1 ]
Wolfram Language code: deconv1[["Output"]]
Wolfram Language code: deconv2 = DeconvolutionLayer[3, 7, "Input" -> {3, 32, 32}, "Stride" -> 7 ]
Wolfram Language code: deconv2[["Output"]]

"Weights"  (1)

指定の重みでバイアスのないデコンボリューション層を作る：

Wolfram Language code: deconv = DeconvolutionLayer[1, {2, 3}, "Input" -> {1, 2, 2}, "Biases" -> None, "Weights" -> RandomReal[1, {1, 1, 2, 3}]]

この層をデータについて評価する：

Wolfram Language code: deconv[RandomReal[1, {1, 2, 2}]]//MatrixForm

特性と関係  (1)

次の関数は，パラメータの入力サイズを与えられた場合に，非チャンネル次元 を計算する：

Wolfram Language code: outputSize[inputSize_List, kernSize_, stride_, pad_] := (stride * (inputSize - 1) + kernSize - 2 * pad)

入力サイズ{256,120}，カーネルサイズ3，ストライドサイズ2，充填サイズ2のときの出力サイズ：

Wolfram Language code: outputSize[{256, 120}, 5, 3, 2]

実際の層と比較する（任意のチャンネル値を使用する）：

Wolfram Language code: Information[DeconvolutionLayer[11, 5, "Input" -> {11, 256, 120}, "Stride" -> 3, "PaddingSize" -> 2], "OutputPorts"]
Wolfram Research (2016), DeconvolutionLayer, Wolfram言語関数， https://reference.wolfram.com/language/ref/DeconvolutionLayer.html （2020年に更新）.

テキスト

Wolfram Research (2016), DeconvolutionLayer, Wolfram言語関数， https://reference.wolfram.com/language/ref/DeconvolutionLayer.html （2020年に更新）.

CMS

Wolfram Language. 2016. "DeconvolutionLayer." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/DeconvolutionLayer.html.

APA

Wolfram Language. (2016). DeconvolutionLayer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DeconvolutionLayer.html

BibTeX

@misc{reference.wolfram_2026_deconvolutionlayer, author="Wolfram Research", title="{DeconvolutionLayer}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DeconvolutionLayer.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deconvolutionlayer, organization={Wolfram Research}, title={DeconvolutionLayer}, year={2020}, url={https://reference.wolfram.com/language/ref/DeconvolutionLayer.html}, note=[Accessed: 12-September-2026]}