WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DegreeCentrality[g]

g のもとになっている単純グラフの頂点の頂点次数のリストを与える．

DegreeCentrality[g,"In"]

頂点の入次数のリストを与える．

DegreeCentrality[g,"Out"]

頂点の出次数のリストを与える．

DegreeCentrality[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

DegreeCentrality

DegreeCentrality[g]

g のもとになっている単純グラフの頂点の頂点次数のリストを与える．

DegreeCentrality[g,"In"]

頂点の入次数のリストを与える．

DegreeCentrality[g,"Out"]

頂点の出次数のリストを与える．

DegreeCentrality[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細

  • DegreeCentralityは，頂点次数が高い頂点に高い中心性を与える．
  • 頂点 の頂点次数は に接続している辺の数である．
  • 有向グラフの場合，入次数は入ってくる辺の数，出次数は出ていく辺の数である．
  • 無向グラフの場合は，入次数と出次数は同じである．
  • DegreeCentralityは，無向グラフ，有向グラフ，多重グラフ，混合グラフに使うことができる．

例題

すべて開く すべて閉じる

例  (2)

次数中心性を計算する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: DegreeCentrality[g]

ハイライトする：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

頂点に順位を付ける．最も順位の高い頂点は接続している頂点数が最も多い：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Part[VertexList[g], Ordering[DegreeCentrality[g], All, Greater]]

スコープ  (7)

DegreeCentralityは無向グラフに使うことができる：

Wolfram Language code: DegreeCentrality[[image]]

有向グラフに使うこともできる：

Wolfram Language code: DegreeCentrality[[image]]

多重グラフ：

Wolfram Language code: DegreeCentrality[[image]]

混合グラフ：

Wolfram Language code: DegreeCentrality[[image]]

規則を使ってグラフを指定する：

Wolfram Language code: DegreeCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

入次数と出次数を計算する：

Wolfram Language code: DegreeCentrality[[image], "In"]
Wolfram Language code: DegreeCentrality[[image], "Out"]

DegreeCentralityは大きいグラフに使うことができる：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: DegreeCentrality[g]//Short//Timing

アプリケーション  (8)

直接の近傍にある他の頂点への影響力によって頂点に順位を付ける：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], DegreeCentrality[g]}, Last]//Reverse

CycleGraphの次数中心性をハイライトする：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

学校の友人関係のネットワーク．最も人気のある生徒を求める：

Wolfram Language code: g = [image];
Wolfram Language code: c = DegreeCentrality[g];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

arXiv e-PrintアーカイブのHigh Energy Physics Phenomenologyセクションからの引用ネットワーク．最も引用されている上位10本の論文を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "HighEnergyPhysicsPhenomenology"}];
Wolfram Language code: c = DegreeCentrality[g, "In"];
Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

食物連鎖の中の基本種すなわち生産者を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "SimpleFoodWeb"}]
Wolfram Language code: With[{d = DegreeCentrality[g, "In"]}, Pick[VertexList[g], d, 0]]

最上位の種すなわち最上位捕食者を求める：

Wolfram Language code: With[{d = DegreeCentrality[g, "Out"]}, Pick[VertexList[g], d, 0]]

2011年11月に MathGroup のメーリングリストに送られた電子メールのネットワーク， が少なくとも1通の返信を に送った場合に から への辺を加えることでユーザのソーシャルネットワークを構築する．質問にもっとも活発に答えたユーザを求める：

Wolfram Language code: g = [image];
Wolfram Language code: d = DegreeCentrality[g, "Out"];
Wolfram Language code: Pick[VertexList[g], d, Max[d]]

返信を受信しただけで自分からは返信を送らなかったユーザ数を数える：

Wolfram Language code: Length[Pick[VertexList[g], d, 0]]

最も頻繁に質問したユーザを求める：

Wolfram Language code: d = DegreeCentrality[g, "In"];
Wolfram Language code: Pick[VertexList[g], d, Max[d]]

返信を送るだけで自分は返信を受け取らなかったユーザを数える：

Wolfram Language code: Length[Pick[VertexList[g], d, 0]]

自立システムのレベルでのインターネット．次数中心性の頻度はベキ法則分布に従う：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Internet"}];
Wolfram Language code: c = DegreeCentrality[g];
Wolfram Language code: Histogram[c, {"Log", 30}, {"Log", "SF"}]

Zipf分布を想定して，最大尤度母数推定を求める：

Wolfram Language code: EstimatedDistribution[Tally[c][[All, -1]], ZipfDistribution[ρ]]

確率密度関数：

Wolfram Language code: PDF[%, k]

頂点数が 個のグラフの場合，最も中心性の高い頂点と他のすべての頂点との間の次数中心性の差の最大の総和はである：

Wolfram Language code: n = 10; g = StarGraph[n]; c = DegreeCentrality[g];
Wolfram Language code: {Total[Max[c] - c], (n - 1)(n - 2)}

最も中心性の高い頂点が他の頂点と比べてどの程度中心であるかを測定する：

Wolfram Language code: centralization[g_] := With[{c = DegreeCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1)(n - 2))]]

ソーシャルネットワークの集中化：

Wolfram Language code: centralization[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]
Wolfram Language code: centralization[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

特性と関係  (5)

無向グラフの頂点次数は頂点に連結された辺の数である：

Wolfram Language code: g = [image];
Wolfram Language code: DegreeCentrality[g]
Wolfram Language code: Table[EdgeCount[g, i_], {i, VertexList[g]}]

無向グラフの場合，入次数中心性と出次数中心性は等しくなる：

Wolfram Language code: g = WheelGraph[6]
Wolfram Language code: DegreeCentrality[g, "In"] == DegreeCentrality[g, "Out"]

VertexDegreeを使って特定の頂点の次数を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: VertexDegree[g, "Anna"]

DegreeCentralityは単純グラフについてはVertexDegreeに等しい：

Wolfram Language code: g = [image];
Wolfram Language code: DegreeCentrality[SimpleGraph[g]] == VertexDegree[SimpleGraph[g]]

有向グラフの場合は，頂点の入次数と出次数の和は頂点次数に等しい：

Wolfram Language code: g = Graph[{12, 23, 31, 34}]
Wolfram Language code: DegreeCentrality[g, "In"] + DegreeCentrality[g, "Out"]
Wolfram Language code: VertexDegree[g]
Wolfram Research (2010), DegreeCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/DegreeCentrality.html （2015年に更新）.

テキスト

Wolfram Research (2010), DegreeCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/DegreeCentrality.html （2015年に更新）.

CMS

Wolfram Language. 2010. "DegreeCentrality." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/DegreeCentrality.html.

APA

Wolfram Language. (2010). DegreeCentrality. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DegreeCentrality.html

BibTeX

@misc{reference.wolfram_2026_degreecentrality, author="Wolfram Research", title="{DegreeCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DegreeCentrality.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_degreecentrality, organization={Wolfram Research}, title={DegreeCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/DegreeCentrality.html}, note=[Accessed: 09-September-2026]}