WOLFRAM

Wolfram 语言与系统参考资料中心

DegreeCentrality[g]

给出 g 的基本简单图中顶点的顶点度列表.

DegreeCentrality[g,"In"]

给出顶点的入度列表.

DegreeCentrality[g,"Out"]

给出顶点的出度列表.

DegreeCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DegreeCentrality

DegreeCentrality[g]

给出 g 的基本简单图中顶点的顶点度列表.

DegreeCentrality[g,"In"]

给出顶点的入度列表.

DegreeCentrality[g,"Out"]

给出顶点的出度列表.

DegreeCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息

  • DegreeCentrality 对具有较高顶点度的顶点给出高中心度.
  • 顶点 的顶点度是与 相关联的边数.
  • 对于一个有向图，入度是入边的数目，而出度是出边的数目.
  • 对于一个无向图，入度和出度一致.
  • DegreeCentrality 适用于无向图、有向图、多重图和混合图.

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算度中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: DegreeCentrality[g]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

对顶点排序. 排在最前面的顶点与其他顶点具有最多的连接数：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Part[VertexList[g], Ordering[DegreeCentrality[g], All, Greater]]

范围  (7)

DegreeCentrality 可用于无向图：

Wolfram Language code: DegreeCentrality[[image]]

有向图：

Wolfram Language code: DegreeCentrality[[image]]

多重图：

Wolfram Language code: DegreeCentrality[[image]]

混合图：

Wolfram Language code: DegreeCentrality[[image]]

用规则指定图：

Wolfram Language code: DegreeCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

计算入度和出度：

Wolfram Language code: DegreeCentrality[[image], "In"]
Wolfram Language code: DegreeCentrality[[image], "Out"]

DegreeCentrality 可用于大规模图：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: DegreeCentrality[g]//Short//Timing

应用  (8)

根据顶点对邻域内其他顶点的影响排序：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], DegreeCentrality[g]}, Last]//Reverse

突出显示 CycleGraph 的度中心度：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = DegreeCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

学校里的朋友关系网络. 求最受欢迎的学生：

Wolfram Language code: g = [image];
Wolfram Language code: c = DegreeCentrality[g];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

arXiv电子打印存档中的《高能物理现象》部分的引文网络，排名前10位被引用最多的文章：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "HighEnergyPhysicsPhenomenology"}];
Wolfram Language code: c = DegreeCentrality[g, "In"];
Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

求食物链中的基位种或者生产者:

Wolfram Language code: g = ExampleData[{"NetworkGraph", "SimpleFoodWeb"}]
Wolfram Language code: With[{d = DegreeCentrality[g, "In"]}, Pick[VertexList[g], d, 0]]

求顶级物种或顶点捕食者：

Wolfram Language code: With[{d = DegreeCentrality[g, "Out"]}, Pick[VertexList[g], d, 0]]

2011年11月发送给 MathGroup 列表的电子邮件列表网络. 构建用户的社交网络，如果 已经发送至少一条回复给 ，则构建一条从 到 的边. 求最积极回复邮件的用户：

Wolfram Language code: g = [image];
Wolfram Language code: d = DegreeCentrality[g, "Out"];
Wolfram Language code: Pick[VertexList[g], d, Max[d]]

计算接受回复但是没有回复其他人的用户数目：

Wolfram Language code: Length[Pick[VertexList[g], d, 0]]

求最经常问问题的用户：

Wolfram Language code: d = DegreeCentrality[g, "In"];
Wolfram Language code: Pick[VertexList[g], d, Max[d]]

计算只发送回复没有接受任何回复的用户数目：

Wolfram Language code: Length[Pick[VertexList[g], d, 0]]

在自治系统水平上的因特网. 度中心的频率服从幂律分布：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Internet"}];
Wolfram Language code: c = DegreeCentrality[g];
Wolfram Language code: Histogram[c, {"Log", 30}, {"Log", "SF"}]

假定齐夫分布，获得最大似然参数估计：

Wolfram Language code: EstimatedDistribution[Tally[c][[All, -1]], ZipfDistribution[ρ]]

概率密度函数：

Wolfram Language code: PDF[%, k]

对于具有 个顶点的图，最中心顶点和所有其他顶点之间的度中心度差值的最大和是 :

Wolfram Language code: n = 10; g = StarGraph[n]; c = DegreeCentrality[g];
Wolfram Language code: {Total[Max[c] - c], (n - 1)(n - 2)}

测量最中心的顶点关于其他顶点的中心度：

Wolfram Language code: centralization[g_] := With[{c = DegreeCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1)(n - 2))]]

社交网络的中心化处理：

Wolfram Language code: centralization[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]
Wolfram Language code: centralization[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

属性和关系  (5)

一个无向图的顶点度是与该顶点相关联的边数：

Wolfram Language code: g = [image];
Wolfram Language code: DegreeCentrality[g]
Wolfram Language code: Table[EdgeCount[g, i_], {i, VertexList[g]}]

对于无向图，入度中心度和出度中心度必须一致：

Wolfram Language code: g = WheelGraph[6]
Wolfram Language code: DegreeCentrality[g, "In"] == DegreeCentrality[g, "Out"]

使用 VertexDegree 来获得特定顶点的度数：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: VertexDegree[g, "Anna"]

对于简单图，DegreeCentrality 等于 VertexDegree：

Wolfram Language code: g = [image];
Wolfram Language code: DegreeCentrality[SimpleGraph[g]] == VertexDegree[SimpleGraph[g]]

对于一个有向图，入度中心度和出度中心度的和等于顶点度：

Wolfram Language code: g = Graph[{12, 23, 31, 34}]
Wolfram Language code: DegreeCentrality[g, "In"] + DegreeCentrality[g, "Out"]
Wolfram Language code: VertexDegree[g]
Wolfram Research (2010)，DegreeCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DegreeCentrality.html （更新于 2015 年）.

文本

Wolfram Research (2010)，DegreeCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DegreeCentrality.html （更新于 2015 年）.

CMS

Wolfram 语言. 2010. "DegreeCentrality." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/DegreeCentrality.html.

APA

Wolfram 语言. (2010). DegreeCentrality. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DegreeCentrality.html 年

BibTeX

@misc{reference.wolfram_2026_degreecentrality, author="Wolfram Research", title="{DegreeCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DegreeCentrality.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_degreecentrality, organization={Wolfram Research}, title={DegreeCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/DegreeCentrality.html}, note=[Accessed: 08-September-2026]}