DiagonalizableMatrixQ

m が対角化可能な場合はTrueを，その他の場合はFalseを返す．

詳細とオプション

行列 m は，対角行列と似ていれば，つまり，が対角であるような非特異行列が存在すれば，対角化可能である．
DiagonalizableMatrixQは，記号行列と数値行列の両方に用いることができる．
近似行列については，オプションTolerance->t を使って，Abs[Det[v]]≤t を満足する行列 m の固有ベクトル v の行列式がゼロであると考えられることを示すことができる．つまり固有ベクトル v が線形独立であり，行列 m は対角化可能ではないということである．
オプションToleranceのデフォルト値はAutomaticである．

例題

すべて開くすべて閉じる

例 (2)

2×2数値行列が対角化可能かどうかの検定を行う：

Wolfram Language code: DiagonalizableMatrixQ[{{0, 1}, {0, 0}}]

3×3記号行列が対角化可能かどうかの検定を行う：

Wolfram Language code:

m = (⁠|    |    |    |
| -- | -- | -- |
| a  | b  | -a |
| -a | a  | b  |
| b  | -a | a  |⁠);

Wolfram Language code: DiagonalizableMatrixQ[m]

行列の固有ベクトルを列に置く：

Wolfram Language code: p = Transpose[Eigenvectors[m]];

この行列が対角行列と相似であることを確かめる：

Wolfram Language code: Inverse[p].m.p//FullSimplify//MatrixForm

スコープ (9)

基本的な用法 (5)

機械精度の実行列が対角化可能かどうかの検定を行う：

Wolfram Language code: m = {{1, 2.3}, {2.4, 4}};

Wolfram Language code: DiagonalizableMatrixQ[m]

結果を確かめる：

Wolfram Language code: p = Transpose[Eigenvectors[m]]

Wolfram Language code: (Inverse[p].m.p)//Chop

入手した行列の対角要素はの固有値である：

Wolfram Language code: Eigenvalues[m]

複素行列が対角化可能かどうかの検定を行う：

Wolfram Language code: m = {{1, 2 - 3I}, {3 + 4I, 4}};

Wolfram Language code: DiagonalizableMatrixQ[m]

厳密行列が対角化可能かどうかの検定を行う：

Wolfram Language code:

m = (⁠|    |     |    |
| -- | --- | -- |
| 0  | -6  | -4 |
| 5  | -11 | -6 |
| -6 | 9   | 4  |⁠);

Wolfram Language code: DiagonalizableMatrixQ[m]

行列を対角化可能にする：

Wolfram Language code: DiagonalizableMatrixQ[(m + m^/2)]

DiagonalizableMatrixQを任意精度の行列に使う：

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

ランダムな正方行列は，通常は，対角化可能である：

Wolfram Language code: DiagonalizableMatrixQ[m]

DiagonalizableMatrixQを記号行列に使う：

Wolfram Language code: DiagonalizableMatrixQ[{{a, b}, {b, c}}]

特殊行列 (4)

DiagonalizableMatrixQを疎な配列に使う：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

Wolfram Language code: DiagonalizableMatrixQ[%]

Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 3}, {5, 5}]

Wolfram Language code: DiagonalizableMatrixQ[%]

DiagonalizableMatrixQを構造化行列に使う：

Wolfram Language code: SymmetrizedArray[{{1, 2} -> 4, {3, 2} -> 5}, {3, 3}, Symmetric[All]]

Wolfram Language code: DiagonalizableMatrixQ[%]

QuantityArrayを構造化行列に使う：

Wolfram Language code: QuantityArray[{{1, 2}, {2, 5}}, "Meters"]

Wolfram Language code: DiagonalizableMatrixQ[%]

恒等行列は対角化可能である：

Wolfram Language code: DiagonalizableMatrixQ[IdentityMatrix[5]]

HilbertMatrixは対角化可能である：

Wolfram Language code: DiagonalizableMatrixQ[HilbertMatrix[5]]

オプション (1)

Tolerance (1)

次数のランダムな摂動がある，対角化不可能な実数値ジョルダン(Jordan)ブロック行列を生成する：

Wolfram Language code:

SeedRandom[521];
q = {{0, 1, 0}, {0, 0, 1}, {0, 0, 0}} + 10 ^ -12 * RandomReal[1, {3, 3}];

Wolfram Language code: DiagonalizableMatrixQ[q]

qは対角化可能である：

Wolfram Language code: v = Eigenvectors[q]; MatrixForm[v]

しかし，固有ベクトルvは数値的に線形従属である：

Wolfram Language code: Det[v]//Abs

固有ベクトルの線形従属性が検出できるように，オプションToleranceを調整する：

Wolfram Language code: DiagonalizableMatrixQ[q, Tolerance -> 10 ^ -12]

アプリケーション (6)

行列が対角化可能な場合，これはと分解することができる．ただし，は非特異であり，は対角である，これを使い，そのベキ級数表現を使って $f(m)=p.(sum_(i=0)^inftya_i d^i).TemplateBox[{p}, Inverse]=p.f(d).TemplateBox[{p}, Inverse]$ として行列関数を計算することができる．はを各対角要素に適用することで計算できる．この方法を使っていくつかの異なる行列関数を計算する：

Wolfram Language code:

m = {{3, 2}, {1, 4}};
DiagonalizableMatrixQ[m]

の固有系を計算する：

Wolfram Language code: {λ, v} = Eigensystem[m]

行列は列に固有ベクトルを持ち，対角成分は固有値である：

Wolfram Language code: p = Transpose[v];

を計算し，MatrixPowerを使って確かめる：

Wolfram Language code: p.DiagonalMatrix[λ ^ k].Inverse[p]

Wolfram Language code: % == MatrixPower[m, k]

を計算し，MatrixExpを使って確かめる：

Wolfram Language code: p.DiagonalMatrix[Exp[λ]].Inverse[p]

Wolfram Language code: % == MatrixExp[m]

を計算し，MatrixLogを使って確かめる：

Wolfram Language code: p.DiagonalMatrix[Log[λ]].Inverse[p]

Wolfram Language code: % == MatrixLog[m]

を計算し，MatrixFunctionを使って確かめる：

Wolfram Language code: p.DiagonalMatrix[f /@ λ].Inverse[p]

Wolfram Language code: % == MatrixFunction[f, m]

常微分方程式系 , , を解く．まず，右辺について係数行列を構築する：

Wolfram Language code: a = {{0, 1, 0}, {0, 0, 1}, {-2, 1, 2}};

係数行列は対角化可能なので，行列の指数を計算するのは簡単である：

Wolfram Language code: DiagonalizableMatrixQ[a]

固有値と固有ベクトルを求める：

Wolfram Language code: {λ, v} = Eigensystem[a]

成分がの指数関数である対角行列を構築する：

Wolfram Language code: d = DiagonalMatrix[Exp[t λ]]

列が対応する固有ベクトルである行列を構築する：

Wolfram Language code: p = Transpose[v]

3つの任意の初期値についての一般解はである：

Wolfram Language code: p.d.Inverse[p] . {C[1], C[2], C[3]}

DSolveValueを使って解を確かめる：

Wolfram Language code: Simplify[% == DSolveValue[{x'[t] == y[t], y'[t] == z[t], z'[t] == -2x[t] + y[t] + 2z[t]}, {x[t], y[t], z[t]}, t]]

Fibonacciの漸化式は行列形式を使うとと書けるという事実を使ってペアについての式を導き出す．漸化式の解はである．ここで，である：

Wolfram Language code: f[1] := {1, 0};

行列は対角化可能である：

Wolfram Language code: m = {{1, 1}, {1, 0}};

Wolfram Language code: DiagonalizableMatrixQ[m]

したがって，行列のベキはEigenvalueDecomposition[m]を使って簡単に計算できる：

Wolfram Language code: {p, λ} = EigenvalueDecomposition[m]

の定義を完成させる：

Wolfram Language code: f[n_] := Simplify[p.λ^n - 1.Inverse[p].f[1]];

およびを計算する：

Wolfram Language code: f[100]

Fibonacciを使って結果を確かめる：

Wolfram Language code: % == Fibonacci[{100, 99}]

正規行列は（は対角行列ではユニタリ行列）のようにユニタリ対角化可能な最も一般的な種類の行列である．等式の両辺が単純になので，エルミート行列はどれも正規行列である：

Wolfram Language code: TensorExpand[h.h == h.h == h.h, Assumptions -> h∈Matrices[{n, n}, Complexes, Hermitian[{1, 2}]]]

同様に，等式の両辺が単純になので，反エルミート行列はどれも正規行列である：

Wolfram Language code: TensorExpand[a.a == a.a == -a.a, Assumptions -> a∈Matrices[{n, n}, Complexes, Antihermitian[{1, 2}]]]

定義に代入すると両辺が恒等行列になるので，ユニタリ行列は正規行列である：

Wolfram Language code: TensorReduce[u.u == u.u /. u -> Inverse[u], Assumptions -> u∈Matrices[{n, n}, Complexes]]

次の行列が正規行列であることを示し，次に対角化する：

Wolfram Language code: (n = {{5 + I, -2I}, {2, 4 + 2I}})//MatrixForm

Wolfram Language code: n.ConjugateTranspose[n] == ConjugateTranspose[n].n

NormalMatrixQを使って確かめる：

Wolfram Language code: NormalMatrixQ[n]

のような正規行列はEigenvalueDecompositionを使ってユニタリ対角化可能である：

Wolfram Language code: {v, d} = EigenvalueDecomposition[n]

対角上の成分は任意の複素数でよい：

Wolfram Language code: d//MatrixForm

これは対角化可能であるがユニタリ行列ではない：

Wolfram Language code: {n == v.d.Inverse[v], UnitaryMatrixQ[v]}

の列は直交する（また，そうでなければならない）が，正規化されてはいない：

Wolfram Language code: ConjugateTranspose[v].v

の列を正規化するとユニタリ行列になる：

Wolfram Language code:

u = Transpose[Normalize /@ Transpose[v]];
UnitaryMatrixQ[u]

ユニタリ対角化を確認する：

Wolfram Language code: n == u.d.ConjugateTranspose[u]

量子力学では，エネルギー演算子はハミルトニアンと呼ばれ，エネルギーを持つ状態はシュレーディンガー(Schrödinger)方程式に従って進化する．ここで重要な仮定は，どのような状態も固有状態の和として書けるということである．これが，方向に一定の磁場を持つスピン1粒子のハミルトニアンの場合に当てはまることを示す：

Wolfram Language code:

ℋ = (Subscript[ω, 0]ℏ/Sqrt[2]) (|   |    |    |
| - | -- | -- |
| 0 | -I | 0  |
| I | 0  | -I |
| 0 | I  | 0  |);

この行列は対角化可能なので，その固有ベクトルは $TemplateBox[{}, Complexes]^3$ の基底を形成しなければならない：

Wolfram Language code: DiagonalizableMatrixQ[ℋ]

固有系を計算すると，エネルギーレベルはとである：

Wolfram Language code: {{Subscript[ℰ, 1], Subscript[ℰ, 2], Subscript[ℰ, 3]}, v} = Eigensystem[ℋ]

固有ベクトルが線形独立であり，したがって基底であることを確認する：

Wolfram Language code: MatrixRank[v]

固有ベクトルを正規化する：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Normalize /@ v

任意の状態を固有ベクトルの和として分解する：

Wolfram Language code:

Underoverscript[∑, i = 1, 3](Subscript[e, i].{Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]})Subscript[e, i] == {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]} //Simplify

CircularRealMatrixDistributionを含む多くの行列分布は，対角化可能であることが保証される行列を生成する：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[CircularRealMatrixDistribution[3], 10]

CircularSymplecticMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[CircularSymplecticMatrixDistribution[3], 10]

GaussianOrthogonalMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[GaussianOrthogonalMatrixDistribution[3], 10]

GaussianUnitaryMatrixDistribution ：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[GaussianUnitaryMatrixDistribution[3], 10]

特性と関係 (9)

対角化可能な行列は固有値分解を使ってのように因子分解することができる．は対角行列である：

Wolfram Language code:

m = RandomVariate[GaussianSymplecticMatrixDistribution[2]];
DiagonalizableMatrixQ[m]

EigenvalueDecompositionを使って相似変換行列および対角行列を求める：

Wolfram Language code: {p, d} = EigenvalueDecomposition[m];

分解を確認する：

Wolfram Language code: m - p.d.Inverse[p]//Chop

行列が固有ベクトルの完全集合を持つときかつそのときに限ってその行列は対角化可能である：

Wolfram Language code:

m = {{-3, -6, 9}, {-18, -15, 27}, {-18, -18, 30}};
DiagonalizableMatrixQ[m]

繰り返される固有値を持つにもかかわらず，は3つの線形独立の固有ベクトルを持つ：

Wolfram Language code: Eigensystem[m]

と同じ固有値を持つにもかかわらず，は対角化可能である：

Wolfram Language code:

n = {{42, 49, -61}, {-9, -4, 13}, {18, 26, -26}};
DiagonalizableMatrixQ[n]

Eigensystemが返す零ベクトルが示すように，2つの独立固有ベクトルしか持たない：

Wolfram Language code: Eigensystem[n]

繰り返される固有値がない任意の行列は対角化可能である：

Wolfram Language code:

m = {{2, 3, 3}, {4, 6, 7}, {8, 8, 10}};
Eigenvalues[m]

Wolfram Language code: DiagonalizableMatrixQ[m]

任意の実対称行列は対角化可能である：

Wolfram Language code: m = Symmetrize[RandomReal[1, {10, 10}]]

Wolfram Language code: {SymmetricMatrixQ[m], DiagonalizableMatrixQ[m]}

任意のエルミート行列もそうである：

Wolfram Language code: m = Symmetrize[RandomComplex[1 + I, {10, 10}], Hermitian[All]]

Wolfram Language code: {HermitianMatrixQ[m], DiagonalizableMatrixQ[m]}

任意の実反対称行列は対角化可能である：

Wolfram Language code: m = Symmetrize[RandomReal[1, {10, 10}], Antisymmetric[All]]

Wolfram Language code: {AntisymmetricMatrixQ[m], DiagonalizableMatrixQ[m]}

任意の半エルミート行列もそうである：

Wolfram Language code: m = Symmetrize[RandomComplex[1 + I, {10, 10}], Antihermitian[All]]

Wolfram Language code: {AntihermitianMatrixQ[m], DiagonalizableMatrixQ[m]}

任意の直交行列は対角化可能である：

Wolfram Language code: m = RandomVariate[CircularRealMatrixDistribution[10]];

Wolfram Language code: {OrthogonalMatrixQ[m], DiagonalizableMatrixQ[m]}

任意のユニタリ行列もそうである：

Wolfram Language code: m = RandomVariate[CircularUnitaryMatrixDistribution[10]];

Wolfram Language code: {UnitaryMatrixQ[m], DiagonalizableMatrixQ[m]}

任意の正規行列は対角化可能である：

Wolfram Language code:

m = {{1., 3., -1.}, {-1., 1., 3.}, {3., -1., 1.}};
{NormalMatrixQ[m], DiagonalizableMatrixQ[m]}

JordanDecomposition[m]の行列が対角行列なら，行列 m は対角化可能である：

Wolfram Language code:

n = {{1, 1, 0}, {-1, 3, (1/4)}, {0, 0, 2}};
{sn, jn} = JordanDecomposition[n];

Wolfram Language code: {DiagonalizableMatrixQ[n], jn//MatrixForm}

Wolfram Language code:

d = {{2, 3, 3}, {4, 6, 7}, {8, 8, 10}};
{sd, jd} = JordanDecomposition[d];

Wolfram Language code: {DiagonalizableMatrixQ[d], jd//MatrixForm}

のときなら × 行列はベキ零である：

Wolfram Language code:

q = {{0, 1}, {0, 0}};
MatrixPower[q, 2]

対角化不可能な行列について考える：

Wolfram Language code:

m = {{2, -1, 0}, {-1, 3, -1}, {-1, 2, 1}};
DiagonalizableMatrixQ[m]

JordanDecompositionを使ってをと書く．は対角化可能ではベキ零である：

Wolfram Language code:

{s, j} = JordanDecomposition[m];
d = s.DiagonalMatrix[Diagonal[j]].Inverse[s];
q = s.DiagonalMatrix[Diagonal[j, 1], 1].Inverse[s];
m == d + q

が対角化可能であることを確認する：

Wolfram Language code: DiagonalizableMatrixQ[d]

行列はベキ零である：

Wolfram Language code: MatrixPower[q, Length[q]]

さらに，とは可換である：

Wolfram Language code: d.q == q.d

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

DiagonalizableMatrixQ

詳細とオプション

例題

例 (2)

スコープ (9)

基本的な用法 (5)

特殊行列 (4)

オプション (1)

Tolerance (1)

アプリケーション (6)

特性と関係 (9)

テキスト

CMS

APA

BibTeX

BibLaTeX

DiagonalizableMatrixQ

詳細とオプション

例題

例 (2)

スコープ (9)

基本的な用法 (5)

特殊行列 (4)

オプション (1)

Tolerance (1)

アプリケーション (6)

特性と関係 (9)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX