Wolfram 语言与系统参考资料中心

DiagonalizableMatrixQ

如果 m 可以对角化，给出 True，否则给出 False.

范例

打开所有单元关闭所有单元

基本范例 (2)

验证 2×2 数值矩阵是否可对角化：

Wolfram Language code: DiagonalizableMatrixQ[{{0, 1}, {0, 0}}]

验证 3×3 符号矩阵是否可对角化：

Wolfram Language code:

m = (⁠|    |    |    |
| -- | -- | -- |
| a  | b  | -a |
| -a | a  | b  |
| b  | -a | a  |⁠);

Wolfram Language code: DiagonalizableMatrixQ[m]

将矩阵的特征向量放在列中：

Wolfram Language code: p = Transpose[Eigenvectors[m]];

验证矩阵类似于对角矩阵：

Wolfram Language code: Inverse[p].m.p//FullSimplify//MatrixForm

范围 (9)

基础用法 (5)

检验一个实值的机器精度矩阵是否可对角化：

Wolfram Language code: m = {{1, 2.3}, {2.4, 4}};

Wolfram Language code: DiagonalizableMatrixQ[m]

验证结果：

Wolfram Language code: p = Transpose[Eigenvectors[m]]

Wolfram Language code: (Inverse[p].m.p)//Chop

得到矩阵的对角元素是的特征值：

Wolfram Language code: Eigenvalues[m]

检验复矩阵是否可对角化：

Wolfram Language code: m = {{1, 2 - 3I}, {3 + 4I, 4}};

Wolfram Language code: DiagonalizableMatrixQ[m]

检验精确矩阵是否可对角化：

Wolfram Language code:

m = (⁠|    |     |    |
| -- | --- | -- |
| 0  | -6  | -4 |
| 5  | -11 | -6 |
| -6 | 9   | 4  |⁠);

Wolfram Language code: DiagonalizableMatrixQ[m]

使矩阵可对角化：

Wolfram Language code: DiagonalizableMatrixQ[(m + m^/2)]

将 DiagonalizableMatrixQ 用于具有任意精度矩阵：

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

随机方形矩阵通常是可对角化矩阵：

Wolfram Language code: DiagonalizableMatrixQ[m]

将 DiagonalizableMatrixQ 用于符号矩阵：

Wolfram Language code: DiagonalizableMatrixQ[{{a, b}, {b, c}}]

特殊矩阵 (4)

将 DiagonalizableMatrixQ 用于稀疏矩阵：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

Wolfram Language code: DiagonalizableMatrixQ[%]

Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 3}, {5, 5}]

Wolfram Language code: DiagonalizableMatrixQ[%]

将 DiagonalizableMatrixQ 用于结构化矩阵：

Wolfram Language code: SymmetrizedArray[{{1, 2} -> 4, {3, 2} -> 5}, {3, 3}, Symmetric[All]]

Wolfram Language code: DiagonalizableMatrixQ[%]

用于 QuantityArray 结构化矩阵：

Wolfram Language code: QuantityArray[{{1, 2}, {2, 5}}, "Meters"]

Wolfram Language code: DiagonalizableMatrixQ[%]

单位矩阵是可对角化矩阵：

Wolfram Language code: DiagonalizableMatrixQ[IdentityMatrix[5]]

HilbertMatrix 为可对角化矩阵：

Wolfram Language code: DiagonalizableMatrixQ[HilbertMatrix[5]]

选项 (1)

Tolerance (1)

生成一个实数非对角化若尔当块矩阵，其中该矩阵具有随机扰动的阶数：

Wolfram Language code:

SeedRandom[521];
q = {{0, 1, 0}, {0, 0, 1}, {0, 0, 0}} + 10 ^ -12 * RandomReal[1, {3, 3}];

Wolfram Language code: DiagonalizableMatrixQ[q]

q 是可以对角化的：

Wolfram Language code: v = Eigenvectors[q]; MatrixForm[v]

但特征向量 v 在数值上线性相关：

Wolfram Language code: Det[v]//Abs

调整选项 Tolerance 使得特征向量的线性相关性能被检测出来：

Wolfram Language code: DiagonalizableMatrixQ[q, Tolerance -> 10 ^ -12]

应用 (6)

如果矩阵是可对角化的，则可将其分解为，其中是非奇异矩阵，是对角矩阵. 这可以通过使用其幂级数表示作为 $f(m)=p.(sum_(i=0)^inftya_i d^i).TemplateBox[{p}, Inverse]=p.f(d).TemplateBox[{p}, Inverse]$ 来计算矩阵函数，并且可以通过简单地将应用于每个对角线元素来计算 . 使用此方法计算几个不同的矩阵函数：

Wolfram Language code:

m = {{3, 2}, {1, 4}};
DiagonalizableMatrixQ[m]

计算的特征系统：

Wolfram Language code: {λ, v} = Eigensystem[m]

矩阵将特征向量作为列，对角线项是特征值：

Wolfram Language code: p = Transpose[v];

使用 MatrixPower 计算并进行验证：

Wolfram Language code: p.DiagonalMatrix[λ ^ k].Inverse[p]

Wolfram Language code: % == MatrixPower[m, k]

使用 MatrixExp 计算并进行验证：

Wolfram Language code: p.DiagonalMatrix[Exp[λ]].Inverse[p]

Wolfram Language code: % == MatrixExp[m]

使用 MatrixLog 计算并进行验证：

Wolfram Language code: p.DiagonalMatrix[Log[λ]].Inverse[p]

Wolfram Language code: % == MatrixLog[m]

使用 MatrixFunction 计算并进行验证：

Wolfram Language code: p.DiagonalMatrix[f /@ λ].Inverse[p]

Wolfram Language code: % == MatrixFunction[f, m]

求解 ODE 方程组，，. 首先，构造右侧的系数矩阵：

Wolfram Language code: a = {{0, 1, 0}, {0, 0, 1}, {-2, 1, 2}};

系数矩阵是可对角化的，因此计算矩阵指数很简单：

Wolfram Language code: DiagonalizableMatrixQ[a]

求特征值和特征向量：

Wolfram Language code: {λ, v} = Eigensystem[a]

构造一个对角矩阵，其项是的指数：

Wolfram Language code: d = DiagonalMatrix[Exp[t λ]]

构造其列是对应特征向量的矩阵：

Wolfram Language code: p = Transpose[v]

对于三个任意起始值，其通解为：

Wolfram Language code: p.d.Inverse[p] . {C[1], C[2], C[3]}

使用 DSolveValue 验证解：

Wolfram Language code: Simplify[% == DSolveValue[{x'[t] == y[t], y'[t] == z[t], z'[t] == -2x[t] + y[t] + 2z[t]}, {x[t], y[t], z[t]}, t]]

使用 Fibonacci 的递归关系可写成这样的矩阵形式这一事实，推导出的公式. 递归关系的解为，其中：

Wolfram Language code: f[1] := {1, 0};

矩阵为可对角化矩阵：

Wolfram Language code: m = {{1, 1}, {1, 0}};

Wolfram Language code: DiagonalizableMatrixQ[m]

因此，可使用 EigenvalueDecomposition[m] 简单计算矩阵幂：

Wolfram Language code: {p, λ} = EigenvalueDecomposition[m]

完成的定义：

Wolfram Language code: f[n_] := Simplify[p.λ^n - 1.Inverse[p].f[1]];

计算和：

Wolfram Language code: f[100]

使用 Fibonacci 验证结果：

Wolfram Language code: % == Fibonacci[{100, 99}]

正规矩阵是最通用的矩阵类型，可以酉对角化为，其中为对角矩阵和为酉矩阵. 所有埃尔米特矩阵都是正规矩阵，因为等式的两边都是简单的：

Wolfram Language code: TensorExpand[h.h == h.h == h.h, Assumptions -> h∈Matrices[{n, n}, Complexes, Hermitian[{1, 2}]]]

类似地，所有反埃尔米特矩阵都是正规矩阵，因为等式的两边都是简单的：

Wolfram Language code: TensorExpand[a.a == a.a == -a.a, Assumptions -> a∈Matrices[{n, n}, Complexes, Antihermitian[{1, 2}]]]

酉矩阵是正规矩阵，因为在定义中代入给出了两边的单位矩阵：

Wolfram Language code: TensorReduce[u.u == u.u /. u -> Inverse[u], Assumptions -> u∈Matrices[{n, n}, Complexes]]

证明下面的矩阵是正规矩阵，并对其进行对角化：

Wolfram Language code: (n = {{5 + I, -2I}, {2, 4 + 2I}})//MatrixForm

Wolfram Language code: n.ConjugateTranspose[n] == ConjugateTranspose[n].n

使用 NormalMatrixQ 进行验证：

Wolfram Language code: NormalMatrixQ[n]

使用 EigenvalueDecomposition 可将像这样的正规矩阵进行酉对角化：

Wolfram Language code: {v, d} = EigenvalueDecomposition[n]

对角线上的项可以是任意复数：

Wolfram Language code: d//MatrixForm

虽然这是一个对角化矩阵，但它不是酉矩阵：

Wolfram Language code: {n == v.d.Inverse[v], UnitaryMatrixQ[v]}

矩阵的列向量是正交的（这是必须的），但它们并未归一化：

Wolfram Language code: ConjugateTranspose[v].v

对的列进行归一化可得到一个酉矩阵：

Wolfram Language code:

u = Transpose[Normalize /@ Transpose[v]];
UnitaryMatrixQ[u]

确认酉对角形式：

Wolfram Language code: n == u.d.ConjugateTranspose[u]

在量子力学中，能量算子称为哈密顿量，具有能量的状态根据薛定谔方程演化. 有一个重要的假设是任何状态都可以写成特征态的总和. 证明这是方向恒定磁场中自旋 1 粒子的哈密顿量的情况：

Wolfram Language code:

ℋ = (Subscript[ω, 0]ℏ/Sqrt[2]) (|   |    |    |
| - | -- | -- |
| 0 | -I | 0  |
| I | 0  | -I |
| 0 | I  | 0  |);

矩阵是可对角化矩阵，因此其特征向量必须构成 $TemplateBox[{}, Complexes]^3$ 的基：

Wolfram Language code: DiagonalizableMatrixQ[ℋ]

计算本征系统，能级为和：

Wolfram Language code: {{Subscript[ℰ, 1], Subscript[ℰ, 2], Subscript[ℰ, 3]}, v} = Eigensystem[ℋ]

确认特征向量为线性独立，因此是一个基：

Wolfram Language code: MatrixRank[v]

正规化特征向量：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Normalize /@ v

将任意状态分解为特征向量的和：

Wolfram Language code:

Underoverscript[∑, i = 1, 3](Subscript[e, i].{Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]})Subscript[e, i] == {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]} //Simplify

许多矩阵分布产生确保可对角化的矩阵，包括 CircularRealMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[CircularRealMatrixDistribution[3], 10]

CircularSymplecticMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[CircularSymplecticMatrixDistribution[3], 10]

GaussianOrthogonalMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[GaussianOrthogonalMatrixDistribution[3], 10]

GaussianUnitaryMatrixDistribution：

Wolfram Language code: DiagonalizableMatrixQ /@ RandomVariate[GaussianUnitaryMatrixDistribution[3], 10]

属性和关系 (9)

可对角化矩阵可以使用特征分解为，其中为对角矩阵：

Wolfram Language code:

m = RandomVariate[GaussianSymplecticMatrixDistribution[2]];
DiagonalizableMatrixQ[m]

用 EigenvalueDecomposition 求相似矩阵和对角矩阵：

Wolfram Language code: {p, d} = EigenvalueDecomposition[m];

确认该分解：

Wolfram Language code: m - p.d.Inverse[p]//Chop

当且仅当矩阵具有一组完整的特征向量时该矩阵是可对角化矩阵：

Wolfram Language code:

m = {{-3, -6, 9}, {-18, -15, 27}, {-18, -18, 30}};
DiagonalizableMatrixQ[m]

虽然其有重复特征值，但有三个线性独立的特征向量：

Wolfram Language code: Eigensystem[m]

尽管具有与相同的特征值，但矩阵不可对角化：

Wolfram Language code:

n = {{42, 49, -61}, {-9, -4, 13}, {18, 26, -26}};
DiagonalizableMatrixQ[n]

该矩阵只有两个独立的特征向量，如 Eigensystem 返回的零向量所示：

Wolfram Language code: Eigensystem[n]

任何没有重复特征值的矩阵都是可对角化矩阵：

Wolfram Language code:

m = {{2, 3, 3}, {4, 6, 7}, {8, 8, 10}};
Eigenvalues[m]

Wolfram Language code: DiagonalizableMatrixQ[m]

任何实对称矩阵都是可对角化矩阵：

Wolfram Language code: m = Symmetrize[RandomReal[1, {10, 10}]]

Wolfram Language code: {SymmetricMatrixQ[m], DiagonalizableMatrixQ[m]}

与任何埃尔米特矩阵一样：

Wolfram Language code: m = Symmetrize[RandomComplex[1 + I, {10, 10}], Hermitian[All]]

Wolfram Language code: {HermitianMatrixQ[m], DiagonalizableMatrixQ[m]}

任何实反对称矩阵都是可对角化矩阵：

Wolfram Language code: m = Symmetrize[RandomReal[1, {10, 10}], Antisymmetric[All]]

Wolfram Language code: {AntisymmetricMatrixQ[m], DiagonalizableMatrixQ[m]}

与任何反埃尔米特矩阵一样：

Wolfram Language code: m = Symmetrize[RandomComplex[1 + I, {10, 10}], Antihermitian[All]]

Wolfram Language code: {AntihermitianMatrixQ[m], DiagonalizableMatrixQ[m]}

任何实正交矩阵都是可对角化矩阵：

Wolfram Language code: m = RandomVariate[CircularRealMatrixDistribution[10]];

Wolfram Language code: {OrthogonalMatrixQ[m], DiagonalizableMatrixQ[m]}

与任何酉矩阵一样：

Wolfram Language code: m = RandomVariate[CircularUnitaryMatrixDistribution[10]];

Wolfram Language code: {UnitaryMatrixQ[m], DiagonalizableMatrixQ[m]}

任何正规矩阵都是可对角化的：

Wolfram Language code:

m = {{1., 3., -1.}, {-1., 1., 3.}, {3., -1., 1.}};
{NormalMatrixQ[m], DiagonalizableMatrixQ[m]}

当且仅当 JordanDecomposition[m] 的矩阵是对角矩阵时，矩阵 m 是可对角化矩阵：

Wolfram Language code:

n = {{1, 1, 0}, {-1, 3, (1/4)}, {0, 0, 2}};
{sn, jn} = JordanDecomposition[n];

Wolfram Language code: {DiagonalizableMatrixQ[n], jn//MatrixForm}

Wolfram Language code:

d = {{2, 3, 3}, {4, 6, 7}, {8, 8, 10}};
{sd, jd} = JordanDecomposition[d];

Wolfram Language code: {DiagonalizableMatrixQ[d], jd//MatrixForm}

如果对于某些，有，则 × 矩阵是幂零的：

Wolfram Language code:

q = {{0, 1}, {0, 0}};
MatrixPower[q, 2]

考虑一个不可对角化的矩阵：

Wolfram Language code:

m = {{2, -1, 0}, {-1, 3, -1}, {-1, 2, 1}};
DiagonalizableMatrixQ[m]

使用 JordanDecomposition 将写为，其中可对角化且幂零：

Wolfram Language code:

{s, j} = JordanDecomposition[m];
d = s.DiagonalMatrix[Diagonal[j]].Inverse[s];
q = s.DiagonalMatrix[Diagonal[j, 1], 1].Inverse[s];
m == d + q

确认是可对角化矩阵：

Wolfram Language code: DiagonalizableMatrixQ[d]

矩阵是幂零的：

Wolfram Language code: MatrixPower[q, Length[q]]

此外，和可交换：

Wolfram Language code: d.q == q.d

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

DiagonalizableMatrixQ

更多信息和选项

范例

基本范例 (2)

范围 (9)

基础用法 (5)

特殊矩阵 (4)

选项 (1)

Tolerance (1)

应用 (6)

属性和关系 (9)

文本

CMS

APA

BibTeX

BibLaTeX

DiagonalizableMatrixQ

更多信息和选项

范例

基本范例 (2)

范围 (9)

基础用法 (5)

特殊矩阵 (4)

选项 (1)

Tolerance (1)

应用 (6)

属性和关系 (9)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX