WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DynamicImage[image]

パン，ズーム等をサポートする image の動的バージョンを表示する．

DynamicImage[file]

file に保存された画像の動的バージョンを表示する．

DynamicImage[url]

url に保存された画像の動的バージョンを表示する．

詳細とオプション
Details and Options Details and Options
例題  
例  
オプション  
AppearanceElements  
AspectRatio  
ImageSize  
ZoomCenter  
ZoomFactor  
アプリケーション  
インタラクティブな例題  
関連項目
関連するガイド
履歴
引用書式

DynamicImage

DynamicImage[image]

パン，ズーム等をサポートする image の動的バージョンを表示する．

DynamicImage[file]

file に保存された画像の動的バージョンを表示する．

DynamicImage[url]

url に保存された画像の動的バージョンを表示する．

詳細とオプション

  • DynamicImageは，大きい画像の詳細を調べるのに便利な，ズーム，パン，スクロールのためのコントロールがあるビューアを作る．
  • DynamicImageはImageオブジェクトと同様にサポートされる任意の画像形式のファイルに使うことができる．
  • DynamicImage[file]の file は，文字列あるいはFileオブジェクトとして指定することができる．
  • DynamicImage[file]は，TIFF，JPEG，PNGに対して使われた場合は，file の必要な部分だけを読み込もうとする．
  • DynamicImage[url]の url は，文字列あるいはURLオブジェクトとして指定することができる．
  • DynamicImageにはPaneと同じオプションに以下の追加・変更を加えたものが使える． [全オプションのリスト]
  • AppearanceElements Automatic動的画像に示すコントロール
    AspectRatio Automatic動的画像の縦横比を制御
    Epilog{}画像に描画するグラフィックスプリミティブ
    ImageSize Automatic画像の描画サイズ
    SaveDefinitionsFalse動的式に画像全体を保存
    ZoomCenter Automatic描画された画像の中心位置
    ZoomFactor Automatic表示された画素サイズと描画画素サイズの比
  • AppearanceElementsの使用可能な要素
  • "Pan"マウスドラッグでパンする
    "ResizeArea"右下にサイズ変更エリア
    "Scrollbars"最後に追加的なズームノブが付いたスクロールバー
    "Thumbnail"画像全体の小さいプレビュー
    "ZoomButtons"ズームインとズームアウトのためのボタン
    "Zoom"と垂直のマウスドラッグでズームする
  • 外観要素のグループは次のいずれかで選択することができる．
  • All全外観要素
    Automatic自動選択された外観要素
    None外観要素なし
  • DynamicImageの出力にSettingを使って描画された部分画像にアクセスする．

    • 全オプションのリスト

例題

すべて開く すべて閉じる

例  (2)

画像を動的に見る：

Wolfram Language code: DynamicImage[ExampleData[{"TestImage", "Apples"}]]

大きいアウトオブコアファイルを動的に見る：

Wolfram Language code: DynamicImage[ExampleData[{"TestImage", "Volubilis"}, "FilePath"]]

オプション  (6)

AppearanceElements  (1)

デフォルトで，自動設定の外観要素が表示される：

Wolfram Language code: DynamicImage[ExampleData[{"TestImage", "Man"}]]

外観要素を指定する：

Wolfram Language code: DynamicImage[ExampleData[{"TestImage", "Man"}], AppearanceElements -> {"Pan", "Zoom", "Scrollbars"}]

使用可能なすべての外観要素を示す：

Wolfram Language code: DynamicImage[ExampleData[{"TestImage", "Man"}], AppearanceElements -> All]

AspectRatio  (2)

デフォルトで，自動の縦横比が使われる：

Wolfram Language code: filename = ExampleData[{"TestImage", "Man"}, "FilePath"];
Wolfram Language code: DynamicImage[filename]

固定縦横比を指定する：

Wolfram Language code: filename = ExampleData[{"TestImage", "Man"}, "FilePath"];
Wolfram Language code: DynamicImage[filename, AspectRatio -> 1]

ビューアサイズを固定縦横比で変更すると縦横比が保存される：

Wolfram Language code: DynamicImage[filename, AspectRatio -> 1]

ImageSize  (1)

デフォルトで，自動のサイズが使われる：

Wolfram Language code: filename = ExampleData[{"TestImage", "Man"}, "FilePath"];
Wolfram Language code: DynamicImage[filename]

初期サイズを指定する：

Wolfram Language code: DynamicImage[filename, ImageSize -> {200, 200}]

ZoomCenter  (1)

デフォルトで，画像は動的画像ビューアと中心揃えになる：

Wolfram Language code: filename = ExampleData[{"TestImage", "Man"}, "FilePath"];
Wolfram Language code: DynamicImage[filename]

揃え方を指定する：

Wolfram Language code: DynamicImage[filename, ZoomCenter -> {Center, Top}]

明示的な座標をズームの中心として使う：

Wolfram Language code: DynamicImage[filename, ZoomCenter -> {450, 750}, ZoomFactor -> 2, Epilog -> {Red, AbsolutePointSize[5], Point[{450, 750}]}]

ZoomFactor  (1)

デフォルトで，画像のより大きい次元が表示サイズにフィットするようにされる：

Wolfram Language code: filename = ExampleData[{"TestImage", "Man"}, "FilePath"];
Wolfram Language code: DynamicImage[filename]

ズーム比を指定する：

Wolfram Language code: DynamicImage[filename, ZoomFactor -> .5]

ZoomFactor->1を使ってもとの画像サイズを得る：

Wolfram Language code: DynamicImage[filename, ZoomFactor -> 1]

1より大きいズーム比を使って画像を拡大する：

Wolfram Language code: DynamicImage[filename, ZoomFactor -> 5]

アプリケーション  (2)

外部コントロールをDynamicImageと結合する：

Wolfram Language code: img = ExampleData[{"TestImage", "Apples"}];
Wolfram Language code: Slider[Dynamic[s], {0.13, 1.7}]
Wolfram Language code: Slider2D[Dynamic[{x, y}]]
Wolfram Language code: DynamicImage[img, ZoomFactor -> Dynamic[s], ZoomCenter -> Dynamic[Scaled[{x, y}]], SaveDefinitions -> True]

2つの画像を並行して調べる：

Wolfram Language code: img1 = ExampleData[{"TestImage", "Apples"}]; img2 = ColorNegate@ExampleData[{"TestImage", "Apples"}];
Wolfram Language code: DynamicModule[ {s = 2, x, y}, Column[ {DynamicImage[img1, ZoomFactor -> Dynamic[s], ZoomCenter -> Scaled[Dynamic[{x, y}]]], DynamicImage[img2, ZoomFactor -> Dynamic[s], ZoomCenter -> Scaled[Dynamic[{x, y}]]]}], SaveDefinitions -> True]

インタラクティブな例題  (1)

画像の上にインタラクティブなグラフィックスプリミティブを描く：

Wolfram Language code: Manipulate[ DynamicImage[ ExampleData[{"TestImage", "Airport"}], ImageSize -> {360, 222}, Epilog -> {Orange, Thickness[0.01], Circle[{305, 574}, Dynamic[r]]} ], {{r, 100}, 24, 512}, FrameMargins -> 0 ]
Wolfram Research (2016), DynamicImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/DynamicImage.html （2017年に更新）.

テキスト

Wolfram Research (2016), DynamicImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/DynamicImage.html （2017年に更新）.

CMS

Wolfram Language. 2016. "DynamicImage." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/DynamicImage.html.

APA

Wolfram Language. (2016). DynamicImage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DynamicImage.html

BibTeX

@misc{reference.wolfram_2026_dynamicimage, author="Wolfram Research", title="{DynamicImage}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DynamicImage.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dynamicimage, organization={Wolfram Research}, title={DynamicImage}, year={2017}, url={https://reference.wolfram.com/language/ref/DynamicImage.html}, note=[Accessed: 10-September-2026]}