EccentricityCentrality

グラフ g 中の頂点の離心中心性のリストを与える．

EccentricityCentrality[{vw,…}]

規則 vw を使ってグラフ g を指定する．

詳細

EccentricityCentralityは，到達可能な他のどの頂点とも最大距離が短い頂点に高い中心性を与える．
グラフ g のEccentricityCentralityはで与えられる．ただし，は頂点に連結している他のすべての頂点への，頂点からの最大距離である．
孤立した頂点の離心中心性は0であるとみなされる．
EccentricityCentralityは，無向グラフ，有向グラフ，重み付きグラフ，多重グラフ，混合グラフに使うことができる．

予備知識

EccentricityCentralityは，グラフ頂点の特定の中心性を近似する非負の機械数（離心中心性）のリストを返す．離心中心性は，ノードから他のすべての到達可能なノードまでの最大距離が短いこと（つまり，グラフの離心率）に基づいた，ネットワーク中のノードの中心性の尺度である．この尺度はソーシャルネットワーク，交通，生物学，社会科学等に応用されている．
が頂点からに接続している他のすべての頂点への最大距離である場合，離心中心性はで与えられる．孤立頂点の離心中心性は0であると解釈される．離心中心性は0から1の間にある（0と1は含まれる）．
頂点の離心中心性はその頂点のVertexEccentricityの逆数である．グラフの完全距離行列はGraphDistanceMatrixを使って計算することができる．

例題

すべて開くすべて閉じる

例 (2)

離心中心性を計算する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: EccentricityCentrality[g]

ハイライトする：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

頂点に順位を付ける．順位が最も高い頂点は，到達可能な他のどの頂点とも近距離にある頂点である：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: Part[VertexList[g], Ordering[EccentricityCentrality[g], All, Greater]]

スコープ (7)

EccentricityCentralityは無向グラフに使うことができる：

Wolfram Language code: EccentricityCentrality[[image]]

有向グラフに使うこともできる：

Wolfram Language code: EccentricityCentrality[[image]]

重み付きのグラフに使う：

Wolfram Language code: EccentricityCentrality[[image]]

多重グラフ：

Wolfram Language code: EccentricityCentrality[[image]]

混合グラフ：

Wolfram Language code: EccentricityCentrality[[image]]

規則を使ってグラフを指定する：

Wolfram Language code: EccentricityCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

EccentricityCentralityは大きいグラフに使うことができる：

Wolfram Language code: g = RandomGraph[{10000, 10005}];

Wolfram Language code: EccentricityCentrality[g]//Short//Timing

アプリケーション (5)

離心性によって頂点に順位を付ける：

Wolfram Language code: g = [image];

Wolfram Language code: SortBy[{VertexList[g], EccentricityCentrality[g]}, Last]//Reverse

CycleGraphの離心中心性をハイライトする：

Wolfram Language code:

HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];

Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];

Wolfram Language code: cc = EccentricityCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];

Wolfram Language code: cc = EccentricityCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];

Wolfram Language code: cc = EccentricityCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];

Wolfram Language code: cc = EccentricityCentrality[g];

Wolfram Language code: HighlightCentrality[g, cc]

ミクロネシア諸島の東に位置するマーシャル諸島のインフラストラクチャーネットワークに基づいて，戦略的に位置付けられた島を求める：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

これはグラフの中央値によって変わる：

Wolfram Language code: With[{d = Total[GraphDistanceMatrix[g]]}, Pick[VertexList[g], d, Min[d]]]

シカゴ郊外を結ぶ道路網から，救急車両の走行距離を最短にする病院と消防署の位置を求める：

Wolfram Language code: g = [image];

Wolfram Language code: With[{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

個の頂点を持つグラフの場合，最も中心的な頂点と他のすべての頂点との間の離心中心性における差の最大総和はの逆数である：

Wolfram Language code:

n = 10;
g = StarGraph[n];
c = EccentricityCentrality[g];

Wolfram Language code: {Total[Max[c] - c], (n - 1) / 2.}

最も中心にある頂点がどのくらい中心にあるか，他の頂点との関係から測る：

Wolfram Language code: eccentricity[g_] := With[{c = EccentricityCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1) / 2)]]

ソーシャルネットワークの集中化：

Wolfram Language code: eccentricity[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]

Wolfram Language code: eccentricity[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

特性と関係 (6)

EccentricityCentralityは他の到達可能な頂点への最大距離の逆数である：

Wolfram Language code: g = [image];

Wolfram Language code: EccentricityCentrality[g]

他の到達可能な頂点までの最大距離の逆数：

Wolfram Language code: d = GraphDistanceMatrix[g];

Wolfram Language code: 1. / Map[Max, DeleteCases[d, 0 | ∞, {2}]]

頂点の離心中心性はVertexEccentricityの逆数である：

Wolfram Language code: g = RandomGraph[{6, 9}]

Wolfram Language code: Table[1. / VertexEccentricity[g, i], {i, VertexList[g]}]

Wolfram Language code: EccentricityCentrality[g]

離心中心性は0から1までである：

Wolfram Language code: Through[{Min, Max}[EccentricityCentrality [RandomGraph[{100, 200}]]]]

無向グラフの離心中心性は各成分の中心性に等しい：

Wolfram Language code: g = [image];

Wolfram Language code: EccentricityCentrality[g]

各成分の中心性を計算しても同じ結果が得られる：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]

Wolfram Language code: {EccentricityCentrality[g1], EccentricityCentrality[g2]}

Wolfram Language code: Join@@%

GraphCenterを使って離心中心性が最も高い頂点を求める：

Wolfram Language code: g = [image];

Wolfram Language code: GraphCenter[g]

Wolfram Language code: With [{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

VertexIndexを使って特定の頂点の中心性を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];

Wolfram Language code: EccentricityCentrality[g][[VertexIndex[g, "Anna"]]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EccentricityCentrality

詳細

予備知識

例題

例 (2)

スコープ (7)

アプリケーション (5)

特性と関係 (6)

テキスト

CMS

APA

BibTeX

BibLaTeX

EccentricityCentrality

詳細

予備知識

例題

例 (2)

スコープ (7)

アプリケーション (5)

特性と関係 (6)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX